mirror of
https://github.com/kanaka/mal.git
synced 2024-10-27 06:40:14 +03:00
033892777a
See issue #587. * Merge eval-ast and eval into a single conditional. * Expand macros during the apply phase, removing lots of duplicate tests, and increasing the overall consistency by allowing the macro to be computed instead of referenced by name (`((defmacro! cond (...)))` is currently illegal for example). * Print "EVAL: $ast" at the top of EVAL if DEBUG-EVAL exists in the MAL environment. * Remove macroexpand and quasiquoteexpand special forms. * Use pattern-matching style in process/step*.txt. Unresolved issues: c.2: unable to reproduce with gcc 11.12.0. elm: the directory is unchanged. groovy: sometimes fail, but not on each rebuild. nasm: fails some new soft tests, but the issue is unreproducible when running the interpreter manually. objpascal: unreproducible with fpc 3.2.2. ocaml: unreproducible with 4.11.1. perl6: unreproducible with rakudo 2021.09. Unrelated changes: Reduce diff betweens steps. Prevent defmacro! from mutating functions: c forth logo miniMAL vb. dart: fix recent errors and warnings ocaml: remove metadata from symbols. Improve the logo implementation. Encapsulate all representation in types.lg and env.lg, unwrap numbers. Replace some manual iterations with logo control structures. Reduce the diff between steps. Use native iteration in env_get and env_map Rewrite the reader with less temporary strings. Reduce the number of temporary lists (for example, reverse iteration with butlast requires O(n^2) allocations). It seems possible to remove a few exceptions: GC settings (Dockerfile), NO_SELF_HOSTING (IMPLS.yml) and step5_EXCLUDES (Makefile.impls) .
86 lines
3.0 KiB
Scheme
86 lines
3.0 KiB
Scheme
(import (scheme base))
|
|
(import (scheme write))
|
|
|
|
(import (lib util))
|
|
(import (lib reader))
|
|
(import (lib printer))
|
|
(import (lib types))
|
|
(import (lib env))
|
|
|
|
(define (READ input)
|
|
(read-str input))
|
|
|
|
(define (EVAL ast env)
|
|
(let ((dbgeval (env-get env 'DEBUG-EVAL)))
|
|
(when (and (mal-object? dbgeval)
|
|
(not (memq (mal-type dbgeval) '(false nil))))
|
|
(display (str "EVAL: " (pr-str ast #t) "\n"))))
|
|
(case (and (mal-object? ast) (mal-type ast))
|
|
((symbol)
|
|
(let ((key (mal-value ast)))
|
|
(or (env-get env key) (error (str "'" key "' not found")))))
|
|
((vector)
|
|
(mal-vector (vector-map (lambda (item) (EVAL item env))
|
|
(mal-value ast))))
|
|
((map)
|
|
(mal-map (alist-map (lambda (key value) (cons key (EVAL value env)))
|
|
(mal-value ast))))
|
|
((list)
|
|
(let ((items (mal-value ast)))
|
|
(if (null? items)
|
|
ast
|
|
(case (mal-value (car items))
|
|
((def!)
|
|
(let ((symbol (mal-value (cadr items)))
|
|
(value (EVAL (list-ref items 2) env)))
|
|
(env-set env symbol value)
|
|
value))
|
|
((let*)
|
|
(let* ((env* (make-env env))
|
|
(binds (mal-value (cadr items)))
|
|
(binds (if (vector? binds) (vector->list binds) binds))
|
|
(form (list-ref items 2)))
|
|
(let loop ((binds binds))
|
|
(when (pair? binds)
|
|
(let ((key (mal-value (car binds))))
|
|
(when (null? (cdr binds))
|
|
(error "unbalanced list"))
|
|
(let ((value (EVAL (cadr binds) env*)))
|
|
(env-set env* key value)
|
|
(loop (cddr binds))))))
|
|
(EVAL form env*)))
|
|
(else
|
|
(let ((op (EVAL (car items) env))
|
|
(ops (map (lambda (item) (EVAL item env)) (cdr items))))
|
|
(apply op ops)))))))
|
|
(else ast)))
|
|
|
|
(define (PRINT ast)
|
|
(pr-str ast #t))
|
|
|
|
(define repl-env (make-env #f))
|
|
(env-set repl-env '+ (lambda (a b) (mal-number (+ (mal-value a) (mal-value b)))))
|
|
(env-set repl-env '- (lambda (a b) (mal-number (- (mal-value a) (mal-value b)))))
|
|
(env-set repl-env '* (lambda (a b) (mal-number (* (mal-value a) (mal-value b)))))
|
|
(env-set repl-env '/ (lambda (a b) (mal-number (/ (mal-value a) (mal-value b)))))
|
|
|
|
(define (rep input)
|
|
(PRINT (EVAL (READ input) repl-env)))
|
|
|
|
(define (main)
|
|
(let loop ()
|
|
(let ((input (readline "user> ")))
|
|
(when input
|
|
(guard
|
|
(ex ((error-object? ex)
|
|
(when (not (memv 'empty-input (error-object-irritants ex)))
|
|
(display "[error] ")
|
|
(display (error-object-message ex))
|
|
(newline))))
|
|
(display (rep input))
|
|
(newline))
|
|
(loop))))
|
|
(newline))
|
|
|
|
(main)
|