mirror of
https://github.com/kanaka/mal.git
synced 2024-09-19 09:38:28 +03:00
8185fe141c
Makefile: Drop OPT and -gnat2020, not used anymore. Simplify file list now that each unit has a body. README: Remove obsolete items. Global: Restrict most pointers to a provable non-null value. Types: merge intermediate Types.Mal into the Types package. (the intermediate package was created in order to prevent a circular dependency, but is not needed anymore). Most of the noise in the diff is caused by this change. This allows to remove most Elaboration pragmas. Declare most types abstract in the visible part, enforcing the use of the constructor outside the declaring package. Envs: Replace the Get recursion with a more efficient loop. Use MAL objects as key, string pointers do not change speed. This delegates some checks from the step files. Split the constructor and Set_Binds, so that an existing environment can be reused during TCO. Err: Attempt to group the calls. Avoid computing the message when the assertion holds. Fns: Declare and use the eval callback only here. Separate function and macro interfaces. Keep a reference to the provided parameter list instead of copying them. Garbage_Collected: Make explicit that Keep is not inherited. Printer: Remove obsolete inline indications and redundant Print_Function helper. Maps: Provide a cleaner interface copied from standard library. Sequences: stop encapsulating the implementation because of the performance hit. Steps: Move map and vector evaluations into separate functions for readability. Replace return blocks with normal blocks (MAL values are not finalized anymore). Rename standard arrays instead of sequence_ptr when possible. Remove some duplication and indentation from the apply phase. Move the frequent special forms in front of the test cascade. When an environment has been created in the same Eval, reuse it. Strings: Use the same garbage-collected storage model for all strings. This seems faster than the default (mutable) string types. Hide most of the implementation to avoid leaks. Symbols: stop ensuring unique allocation of symbols. The reduced garbage collection and comparison time was compensed by the maintainance of a global hash.
47 lines
1.6 KiB
Ada
47 lines
1.6 KiB
Ada
package Garbage_Collected is
|
|
|
|
-- A generic would not be convenient for lists. We want the
|
|
-- extended type to be able to have a discriminant.
|
|
|
|
-- However, we keep the dispatching in a single enumeration for
|
|
-- efficiency and clarity of the source.
|
|
|
|
type Instance is abstract tagged limited private;
|
|
subtype Class is Instance'Class;
|
|
type Link is access all Class;
|
|
subtype Pointer is not null Link;
|
|
|
|
procedure Keep_References (Object : in out Instance) is null with Inline;
|
|
-- A dispatching call in Keep allows subclasses to override this
|
|
-- in order to Keep each of the internal reference they maintain.
|
|
|
|
-- The following methods have no reason to be overridden.
|
|
|
|
procedure Keep (Object : in out Class) with Inline;
|
|
-- Mark this object so that it is not deleted by next clean,
|
|
-- then make a dispatching call to Keep_References.
|
|
-- Does nothing if it has already been called for this object
|
|
-- since startup or last Clean.
|
|
|
|
procedure Register (Ref : in Pointer) with Inline;
|
|
-- Each subclass defines its own allocation pool, but every call
|
|
-- to new must be followed by a call to Register.
|
|
|
|
procedure Clean;
|
|
-- For each object for which Keep has not been called since
|
|
-- startup or last clean, make a dispatching call to Finalize,
|
|
-- then deallocate the memory for the object.
|
|
|
|
-- Debug.
|
|
procedure Check_Allocations;
|
|
-- Does nothing if assertions are disabled.
|
|
|
|
private
|
|
|
|
type Instance is abstract tagged limited record
|
|
Kept : Boolean := False;
|
|
Next : Link := null;
|
|
end record;
|
|
|
|
end Garbage_Collected;
|