1
1
mirror of https://github.com/kanaka/mal.git synced 2024-09-21 10:37:58 +03:00
mal/groovy/step3_env.groovy
Joel Martin dd7a4f55f3 Test uncaught throw, catchless try* . Fix 46 impls.
Fixes made to: ada, c, chuck, clojure, coffee, common-lisp, cpp,
crystal, d, dart, elm, erlang, es6, factor, fsharp, gnu-smalltalk,
groovy, guile, haxe, hy, js, livescript, matlab, miniMAL, nasm, nim,
objc, objpascal, ocaml, perl, perl6, php, plsql, ps, python, r,
rpython, ruby, scheme, swift3, tcl, ts, vb, vimscript, wasm, yorick.

Catchless try* test is an optional test. Not all implementations
support catchless try* but a number were fixed so they at least don't
crash on catchless try*.
2018-12-12 14:18:26 -06:00

79 lines
2.0 KiB
Groovy

import reader
import printer
import types
import types.MalException
import types.MalSymbol
import env.Env
// READ
READ = { str ->
reader.read_str str
}
// EVAL
eval_ast = { ast, env ->
switch (ast) {
case MalSymbol: return env.get(ast);
case List: return types.vector_Q(ast) ?
types.vector(ast.collect { EVAL(it,env) }) :
ast.collect { EVAL(it,env) }
case Map: def new_hm = [:]
ast.each { k,v ->
new_hm[EVAL(k, env)] = EVAL(v, env)
}
return new_hm
default: return ast
}
}
EVAL = { ast, env ->
//println("EVAL: ${printer.pr_str(ast,true)}")
if (! types.list_Q(ast)) return eval_ast(ast, env)
if (ast.size() == 0) return ast
switch (ast[0]) {
case { it instanceof MalSymbol && it.value == "def!" }:
return env.set(ast[1], EVAL(ast[2], env))
case { it instanceof MalSymbol && it.value == "let*" }:
def let_env = new Env(env)
for (int i=0; i < ast[1].size(); i += 2) {
let_env.set(ast[1][i], EVAL(ast[1][i+1], let_env))
}
return EVAL(ast[2], let_env)
default:
def el = eval_ast(ast, env)
def (f, args) = [el[0], el[1..-1]]
f(args)
}
}
// PRINT
PRINT = { exp ->
printer.pr_str exp, true
}
// REPL
repl_env = new Env();
repl_env.set(new MalSymbol("+"), { a -> a[0]+a[1]});
repl_env.set(new MalSymbol("-"), { a -> a[0]-a[1]});
repl_env.set(new MalSymbol("*"), { a -> a[0]*a[1]});
repl_env.set(new MalSymbol("/"), { a -> a[0]/a[1]}); // /
REP = { str ->
PRINT(EVAL(READ(str), repl_env))
}
while (true) {
line = System.console().readLine 'user> '
if (line == null) {
break;
}
try {
println REP(line)
} catch(MalException ex) {
println "Error: ${printer.pr_str(ex.obj, true)}"
} catch(ex) {
println "Error: $ex"
ex.printStackTrace()
}
}