mirror of
https://github.com/kanaka/mal.git
synced 2024-10-27 14:52:16 +03:00
033892777a
See issue #587. * Merge eval-ast and eval into a single conditional. * Expand macros during the apply phase, removing lots of duplicate tests, and increasing the overall consistency by allowing the macro to be computed instead of referenced by name (`((defmacro! cond (...)))` is currently illegal for example). * Print "EVAL: $ast" at the top of EVAL if DEBUG-EVAL exists in the MAL environment. * Remove macroexpand and quasiquoteexpand special forms. * Use pattern-matching style in process/step*.txt. Unresolved issues: c.2: unable to reproduce with gcc 11.12.0. elm: the directory is unchanged. groovy: sometimes fail, but not on each rebuild. nasm: fails some new soft tests, but the issue is unreproducible when running the interpreter manually. objpascal: unreproducible with fpc 3.2.2. ocaml: unreproducible with 4.11.1. perl6: unreproducible with rakudo 2021.09. Unrelated changes: Reduce diff betweens steps. Prevent defmacro! from mutating functions: c forth logo miniMAL vb. dart: fix recent errors and warnings ocaml: remove metadata from symbols. Improve the logo implementation. Encapsulate all representation in types.lg and env.lg, unwrap numbers. Replace some manual iterations with logo control structures. Reduce the diff between steps. Use native iteration in env_get and env_map Rewrite the reader with less temporary strings. Reduce the number of temporary lists (for example, reverse iteration with butlast requires O(n^2) allocations). It seems possible to remove a few exceptions: GC settings (Dockerfile), NO_SELF_HOSTING (IMPLS.yml) and step5_EXCLUDES (Makefile.impls) .
126 lines
4.0 KiB
Fennel
126 lines
4.0 KiB
Fennel
(local printer (require :printer))
|
|
(local reader (require :reader))
|
|
(local t (require :types))
|
|
(local e (require :env))
|
|
(local core (require :core))
|
|
(local u (require :utils))
|
|
|
|
(local repl_env
|
|
(let [env (e.make-env)]
|
|
(each [name func (pairs core)]
|
|
(e.env-set env
|
|
(t.make-symbol name)
|
|
func))
|
|
env))
|
|
|
|
(fn READ
|
|
[code-str]
|
|
(reader.read_str code-str))
|
|
|
|
(fn EVAL
|
|
[ast env]
|
|
(let [dbgeval (e.env-get env "DEBUG-EVAL")]
|
|
(when (and dbgeval
|
|
(not (t.nil?* dbgeval))
|
|
(not (t.false?* dbgeval)))
|
|
(print (.. "EVAL: " (printer.pr_str ast true)))))
|
|
(if (t.symbol?* ast)
|
|
(let [key (t.get-value ast)]
|
|
(or (e.env-get env key)
|
|
(u.throw* (t.make-string (.. "'" key "' not found")))))
|
|
;;
|
|
(t.vector?* ast)
|
|
(t.make-vector (u.map (fn [elt-ast]
|
|
(EVAL elt-ast env))
|
|
(t.get-value ast)))
|
|
;;
|
|
(t.hash-map?* ast)
|
|
(t.make-hash-map (u.map (fn [elt-ast]
|
|
(EVAL elt-ast env))
|
|
(t.get-value ast)))
|
|
;;
|
|
(or (not (t.list?* ast)) (t.empty?* ast))
|
|
ast
|
|
;;
|
|
(let [ast-elts (t.get-value ast)
|
|
head-name (t.get-value (. ast-elts 1))]
|
|
;; XXX: want to check for symbol, but that screws up logic below
|
|
(if (= "def!" head-name)
|
|
(let [def-name (. ast-elts 2)
|
|
def-val (EVAL (. ast-elts 3) env)]
|
|
(e.env-set env
|
|
def-name def-val)
|
|
def-val)
|
|
;;
|
|
(= "let*" head-name)
|
|
(let [new-env (e.make-env env)
|
|
bindings (t.get-value (. ast-elts 2))
|
|
stop (/ (length bindings) 2)]
|
|
(for [idx 1 stop]
|
|
(let [b-name (. bindings (- (* 2 idx) 1))
|
|
b-val (EVAL (. bindings (* 2 idx)) new-env)]
|
|
(e.env-set new-env
|
|
b-name b-val)))
|
|
(EVAL (. ast-elts 3) new-env))
|
|
;;
|
|
(= "do" head-name)
|
|
(u.last (u.map (fn [x] (EVAL x env)) (u.slice ast-elts 2 -1)))
|
|
;;
|
|
(= "if" head-name)
|
|
(let [cond-res (EVAL (. ast-elts 2) env)]
|
|
(if (or (t.nil?* cond-res)
|
|
(t.false?* cond-res))
|
|
(let [else-ast (. ast-elts 4)]
|
|
(if (not else-ast)
|
|
t.mal-nil
|
|
(EVAL else-ast env)))
|
|
(EVAL (. ast-elts 3) env)))
|
|
;;
|
|
(= "fn*" head-name)
|
|
(let [args (t.get-value (. ast-elts 2))
|
|
body (. ast-elts 3)]
|
|
(t.make-fn (fn [params]
|
|
(EVAL body
|
|
(e.make-env env args params)))))
|
|
;;
|
|
(let [eval-list (u.map (fn [x] (EVAL x env)) ast-elts)
|
|
f (. eval-list 1)
|
|
args (u.slice eval-list 2 -1)]
|
|
((t.get-value f) args))))))
|
|
|
|
(fn PRINT
|
|
[ast]
|
|
(printer.pr_str ast true))
|
|
|
|
(fn rep
|
|
[code-str]
|
|
(PRINT (EVAL (READ code-str) repl_env)))
|
|
|
|
(rep "(def! not (fn* (a) (if a false true)))")
|
|
|
|
(fn handle-error
|
|
[err]
|
|
(if (t.nil?* err)
|
|
(print)
|
|
(= "string" (type err))
|
|
(print err)
|
|
(print (.. "Error: " (PRINT err)))))
|
|
|
|
(var done false)
|
|
|
|
(while (not done)
|
|
(io.write "user> ")
|
|
(io.flush)
|
|
(let [input (io.read)]
|
|
(if (not input)
|
|
(set done true)
|
|
(xpcall (fn []
|
|
(print (rep input)))
|
|
handle-error))))
|
|
;; (fn [exc]
|
|
;; (if (t.nil?* exc)
|
|
;; (print)
|
|
;; (= "string" (type exc))
|
|
;; (print exc)
|
|
;; (print (PRINT exc))))))))
|