git.iko.soy/rel8
on 26ccab3 help sign in
rel8/src/Rel8/Table/Serialize.hs
369 lines 11 kB history raw
1{-# language AllowAmbiguousTypes #-}
2{-# language DataKinds #-}
3{-# language DefaultSignatures #-}
4{-# language DisambiguateRecordFields #-}
5{-# language FlexibleContexts #-}
6{-# language FlexibleInstances #-}
7{-# language FunctionalDependencies #-}
8{-# language NamedFieldPuns #-}
9{-# language ScopedTypeVariables #-}
10{-# language StandaloneKindSignatures #-}
11{-# language TypeApplications #-}
12{-# language TypeFamilies #-}
13{-# language TypeOperators #-}
14{-# language UndecidableInstances #-}
16module Rel8.Table.Serialize
17 ( Serializable, lit, parse
18 , Encodes, litTable
19 , ToExprs(..)
20 , FromExprs
21 )
22where
24-- base
25import Data.Bifunctor ( bimap )
26import Data.Kind ( Constraint, Type )
27import Data.List.NonEmpty ( NonEmpty )
28import GHC.Generics
29 ( Generic, Rep, from, to
30 , (:*:)( (:*:) ), K1( K1 ), M1( M1 ), Meta( MetaSel ), D, C, S
31 )
32import GHC.TypeLits ( KnownSymbol )
33import Prelude
35-- hasql
36import qualified Hasql.Decoders as Hasql
38-- rel8
39import Rel8.Expr ( Expr, Col(..) )
40import Rel8.Expr.Serialize ( slitExpr, sparseValue )
41import Rel8.Generic.Record ( Record(..) )
42import Rel8.Schema.Context ( Col(..) )
43import Rel8.Schema.Context.Label ( labeler, unlabeler )
44import Rel8.Schema.HTable ( HTable, htabulate, htabulateA, hfield, hspecs )
45import Rel8.Schema.HTable.Label ( HLabel, hlabel, hunlabel )
46import Rel8.Schema.HTable.Product ( HProduct(..) )
47import Rel8.Schema.HTable.Type ( HType(..) )
48import Rel8.Schema.Null ( NotNull, Sql )
49import Rel8.Schema.Result ( Result )
50import Rel8.Schema.Spec ( SSpec(..), KnownSpec )
51import Rel8.Table ( Table, Columns, fromColumns, toColumns, GColumns )
52import Rel8.Table.Either ( EitherTable )
53import Rel8.Table.List ( ListTable )
54import Rel8.Table.Maybe ( MaybeTable )
55import Rel8.Table.NonEmpty ( NonEmptyTable )
56import Rel8.Table.Recontextualize ( Recontextualize )
57import Rel8.Table.These ( TheseTable )
58import Rel8.Type ( DBType )
60-- semigroupoids
61import Data.Functor.Apply ( WrappedApplicative(..) )
63-- these
64import Data.These ( These )
67type ToExprs :: Type -> Type -> Constraint
68class Table Expr exprs => ToExprs exprs a where
69 fromResult :: Columns exprs (Col Result) -> a
70 toResult :: a -> Columns exprs (Col Result)
72 default fromResult ::
73 ( Generic (Record a)
74 , GToExprs (Rep (Record exprs)) (Rep (Record a))
75 , Columns exprs ~ GColumns (Rep (Record exprs))
76 )
77 => Columns exprs (Col Result) -> a
78 fromResult = unrecord . to . gfromResult @(Rep (Record exprs))
80 default toResult ::
81 ( Generic (Record a)
82 , GToExprs (Rep (Record exprs)) (Rep (Record a))
83 , Columns exprs ~ GColumns (Rep (Record exprs))
84 )
85 => a -> Columns exprs (Col Result)
86 toResult = gtoResult @(Rep (Record exprs)) . from . Record
89type GToExprs :: (Type -> Type) -> (Type -> Type) -> Constraint
90class GToExprs exprs rep where
91 gfromResult :: GColumns exprs (Col Result) -> rep x
92 gtoResult :: rep x -> GColumns exprs (Col Result)
95instance GToExprs exprs rep => GToExprs (M1 D c exprs) (M1 D c rep) where
96 gfromResult = M1 . gfromResult @exprs
97 gtoResult (M1 a) = gtoResult @exprs a
100instance GToExprs exprs rep => GToExprs (M1 C c exprs) (M1 C c rep) where
101 gfromResult = M1 . gfromResult @exprs
102 gtoResult (M1 a) = gtoResult @exprs a
105instance (GToExprs exprs1 rep1, GToExprs exprs2 rep2) =>
106 GToExprs (exprs1 :*: exprs2) (rep1 :*: rep2)
107 where
108 gfromResult (HProduct a b) = gfromResult @exprs1 a :*: gfromResult @exprs2 b
109 gtoResult (a :*: b) = HProduct (gtoResult @exprs1 a) (gtoResult @exprs2 b)
112instance
113 ( ToExprs exprs a
114 , KnownSymbol label
115 , GColumns (M1 S meta k1) ~ HLabel label (Columns exprs)
116 , meta ~ 'MetaSel ('Just label) _su _ss _ds
117 , k1 ~ K1 i exprs
118 , k1' ~ K1 i a
119 )
120 => GToExprs (M1 S meta k1) (M1 S meta k1')
121 where
122 gfromResult = M1 . K1 . fromResult @exprs . hunlabel unlabeler
123 gtoResult (M1 (K1 a)) = hlabel labeler (toResult @exprs a)
126instance {-# OVERLAPPABLE #-} (Sql DBType a, x ~ Expr a) => ToExprs x a where
127 fromResult (HType (Result a)) = a
128 toResult = HType . Result
131instance (Sql DBType a, x ~ [a]) => ToExprs (Expr x) [a] where
132 fromResult (HType (Result a)) = a
133 toResult = HType . Result
136instance (Sql DBType a, NotNull a, x ~ Maybe a) => ToExprs (Expr x) (Maybe a)
137 where
138 fromResult (HType (Result a)) = a
139 toResult = HType . Result
142instance (Sql DBType a, NotNull a, x ~ NonEmpty a) => ToExprs (Expr x) (NonEmpty a)
143 where
144 fromResult (HType (Result a)) = a
145 toResult = HType . Result
148instance (ToExprs exprs1 a, ToExprs exprs2 b, x ~ EitherTable exprs1 exprs2) =>
149 ToExprs x (Either a b)
150 where
151 fromResult =
152 bimap (fromResult @exprs1) (fromResult @exprs2) .
153 fromColumns
154 toResult =
155 toColumns .
156 bimap (toResult @exprs1) (toResult @exprs2)
159instance ToExprs exprs a => ToExprs (ListTable exprs) [a] where
160 fromResult = fmap (fromResult @exprs) . fromColumns
161 toResult = toColumns . fmap (toResult @exprs)
164instance ToExprs exprs a => ToExprs (MaybeTable exprs) (Maybe a) where
165 fromResult = fmap (fromResult @exprs) . fromColumns
166 toResult = toColumns . fmap (toResult @exprs)
169instance ToExprs exprs a => ToExprs (NonEmptyTable exprs) (NonEmpty a)
170 where
171 fromResult = fmap (fromResult @exprs) . fromColumns
172 toResult = toColumns . fmap (toResult @exprs)
175instance (ToExprs exprs1 a, ToExprs exprs2 b, x ~ TheseTable exprs1 exprs2) =>
176 ToExprs x (These a b)
177 where
178 fromResult =
179 bimap (fromResult @exprs1) (fromResult @exprs2) .
180 fromColumns
181 toResult =
182 toColumns .
183 bimap (toResult @exprs1) (toResult @exprs2)
186instance (ToExprs exprs1 a, ToExprs exprs2 b, x ~ (exprs1, exprs2)) =>
187 ToExprs x (a, b)
190instance
191 ( ToExprs exprs1 a
192 , ToExprs exprs2 b
193 , ToExprs exprs3 c
194 , x ~ (exprs1, exprs2, exprs3)
195 )
196 => ToExprs x (a, b, c)
199instance
200 ( ToExprs exprs1 a
201 , ToExprs exprs2 b
202 , ToExprs exprs3 c
203 , ToExprs exprs4 d
204 , x ~ (exprs1, exprs2, exprs3, exprs4)
205 )
206 => ToExprs x (a, b, c, d)
209instance
210 ( ToExprs exprs1 a
211 , ToExprs exprs2 b
212 , ToExprs exprs3 c
213 , ToExprs exprs4 d
214 , ToExprs exprs5 e
215 , x ~ (exprs1, exprs2, exprs3, exprs4, exprs5)
216 )
217 => ToExprs x (a, b, c, d, e)
220instance
221 ( ToExprs exprs1 a
222 , ToExprs exprs2 b
223 , ToExprs exprs3 c
224 , ToExprs exprs4 d
225 , ToExprs exprs5 e
226 , ToExprs exprs6 f
227 , x ~ (exprs1, exprs2, exprs3, exprs4, exprs5, exprs6)
228 )
229 => ToExprs x (a, b, c, d, e, f)
232instance
233 ( ToExprs exprs1 a
234 , ToExprs exprs2 b
235 , ToExprs exprs3 c
236 , ToExprs exprs4 d
237 , ToExprs exprs5 e
238 , ToExprs exprs6 f
239 , ToExprs exprs7 g
240 , x ~ (exprs1, exprs2, exprs3, exprs4, exprs5, exprs6, exprs7)
241 )
242 => ToExprs x (a, b, c, d, e, f, g)
245instance (HTable t, result ~ Col Result, x ~ t (Col Expr)) =>
246 ToExprs x (t result)
247 where
248 fromResult = id
249 toResult = id
252instance (Recontextualize Result Expr (t Result) (t Expr), result ~ Result, x ~ t Expr) =>
253 ToExprs x (t result)
254 where
255 fromResult = fromColumns
256 toResult = toColumns
259instance (KnownSpec spec, x ~ Col Expr spec) =>
260 ToExprs x (Col Result spec)
261 where
262 fromResult = fromColumns
263 toResult = toColumns
266type FromExprs :: Type -> Type
267type family FromExprs a
268type instance FromExprs (Expr a) = a
269type instance FromExprs (Col Expr spec) = Col Result spec
270type instance FromExprs (EitherTable a b) = Either (FromExprs a) (FromExprs b)
271type instance FromExprs (ListTable a) = [FromExprs a]
272type instance FromExprs (MaybeTable a) = Maybe (FromExprs a)
273type instance FromExprs (NonEmptyTable a) = NonEmpty (FromExprs a)
274type instance FromExprs (TheseTable a b) = These (FromExprs a) (FromExprs b)
275type instance FromExprs (a, b) = (FromExprs a, FromExprs b)
276type instance FromExprs (a, b, c) = (FromExprs a, FromExprs b, FromExprs c)
277type instance FromExprs (a, b, c, d) =
278 (FromExprs a, FromExprs b, FromExprs c, FromExprs d)
279type instance FromExprs (a, b, c, d, e) =
280 (FromExprs a, FromExprs b, FromExprs c, FromExprs d, FromExprs e)
281type instance FromExprs (a, b, c, d, e, f) =
282 ( FromExprs a, FromExprs b, FromExprs c, FromExprs d, FromExprs e
283 , FromExprs f
284 )
285type instance FromExprs (a, b, c, d, e, f, g) =
286 ( FromExprs a, FromExprs b, FromExprs c, FromExprs d, FromExprs e
287 , FromExprs f, FromExprs g
288 )
289type instance FromExprs (t Expr) = t Result
290type instance FromExprs (t (Col Expr)) = t (Col Result)
293-- | @Serializable@ witnesses the one-to-one correspondence between the type
294-- @sql@, which contains SQL expressions, and the type @haskell@, which
295-- contains the Haskell decoding of rows containing @sql@ SQL expressions.
296type Serializable :: Type -> Type -> Constraint
297class (ToExprs exprs a, a ~ FromExprs exprs) => Serializable exprs a | exprs -> a
298instance (ToExprs exprs a, a ~ FromExprs exprs) => Serializable exprs a
299instance {-# OVERLAPPING #-} Sql DBType a => Serializable (Expr a) a
302-- | Use @lit@ to turn literal Haskell values into expressions. @lit@ is
303-- capable of lifting single @Expr@s to full tables.
304lit :: forall exprs a. Serializable exprs a => a -> exprs
305lit = fromColumns . litHTable . toResult @exprs
308parse :: forall exprs a. Serializable exprs a => Hasql.Row a
309parse = fromResult @exprs <$> parseHTable
312type Encodes :: Type -> Type -> Constraint
313class Serializable exprs a => Encodes a exprs | a -> exprs, exprs -> a
316instance KnownSpec spec => Encodes (Col Result spec) (Col Expr spec)
319instance Serializable (t Result) (t Expr) => Encodes (t Expr) (t Result)
322instance HTable t => Encodes (t (Col Result)) (t (Col Expr))
325instance (Encodes a x, Encodes b y) => Encodes (Either a b) (EitherTable x y)
328instance Encodes a x => Encodes [a] (ListTable x)
331instance Encodes a x => Encodes (Maybe a) (MaybeTable x)
334instance Encodes a x => Encodes (NonEmpty a) (NonEmptyTable x)
337instance (Encodes a x, Encodes b y) => Encodes (These a b) (TheseTable x y)
340instance (Encodes a x, Encodes b y) => Encodes (a, b) (x, y)
343instance (Encodes a x, Encodes b y, Encodes c z) =>
344 Encodes (a, b, c) (x, y, z)
347instance (Encodes a w, Encodes b x, Encodes c y, Encodes d z) =>
348 Encodes (a, b, c, d) (w, x, y, z)
351instance (Encodes a v, Encodes b w, Encodes c x, Encodes d y, Encodes e z) =>
352 Encodes (a, b, c, d, e) (v, w, x, y, z)
355litTable :: Encodes a exprs => a -> exprs
356litTable = lit
359litHTable :: HTable t => t (Col Result) -> t (Col Expr)
360litHTable as = htabulate $ \field ->
361 case hfield hspecs field of
362 SSpec {nullity, info} -> case hfield as field of
363 Result value -> DB (slitExpr nullity info value)
366parseHTable :: HTable t => Hasql.Row (t (Col Result))
367parseHTable = unwrapApplicative $ htabulateA $ \field ->
368 WrapApplicative $ case hfield hspecs field of
369 SSpec {nullity, info} -> Result <$> sparseValue nullity info