git.iko.soy/rel8
on 707a36a help sign in
rel8/src/Rel8/Query/Maybe.hs
62 lines 2.1 kB history raw
1{-# language GADTs #-}
3module Rel8.Query.Maybe
4 ( optional
5 , catMaybeTable
6 , traverseMaybeTable
7 )
8where
10-- base
11import Prelude
13-- opaleye
14import qualified Opaleye.Internal.MaybeFields as Opaleye
16-- rel8
17import Rel8.Expr ( Col( E ), Expr )
18import Rel8.Expr.Eq ( (==.) )
19import Rel8.Expr.Opaleye ( fromColumn, fromPrimExpr )
20import Rel8.Query ( Query )
21import Rel8.Query.Filter ( where_ )
22import Rel8.Query.Opaleye ( mapOpaleye )
23import Rel8.Table.Maybe ( MaybeTable( MaybeTable ), isJustTable )
26-- | Convert a query that might return zero rows to a query that always returns
27-- at least one row.
28--
29-- To speak in more concrete terms, 'optional' is most useful to write @LEFT
30-- JOIN@s.
31optional :: Query a -> Query (MaybeTable Expr a)
32optional =
33 mapOpaleye $
34 Opaleye.optionalInternal $
35 MaybeTable . E . fromPrimExpr . fromColumn
38-- | Filter out 'MaybeTable's, returning only the tables that are not-null.
39--
40-- This operation can be used to "undo" the effect of 'optional', which
41-- operationally is like turning a @LEFT JOIN@ back into a full @JOIN@. You
42-- can think of this as analogous to 'Data.Maybe.catMaybes'.
43catMaybeTable :: MaybeTable Expr a -> Query a
44catMaybeTable ma@(MaybeTable _ a) = do
45 where_ $ isJustTable ma
46 pure a
49-- | Extend an optional query with another query. This is useful if you want
50-- to step through multiple @LEFT JOINs@.
51--
52-- Note that @traverseMaybeTable@ takes a @a -> Query b@ function, which means
53-- you also have the ability to "expand" one row into multiple rows. If the
54-- @a -> Query b@ function returns no rows, then the resulting query will also
55-- have no rows. However, regardless of the given @a -> Query b@ function, if
56-- the input is @nothingTable@, you will always get exactly one @nothingTable@
57-- back.
58traverseMaybeTable :: (a -> Query b) -> MaybeTable Expr a -> Query (MaybeTable Expr b)
59traverseMaybeTable query ma@(MaybeTable (E input) _) = do
60 MaybeTable (E output) b <- optional (query =<< catMaybeTable ma)
61 where_ $ output ==. input
62 pure $ MaybeTable (E input) b