git.iko.soy/rel8
on 716d9f1 help sign in
rel8/src/Rel8/Table/Rel8able.hs
146 lines 3.7 kB history raw
1{-# language DataKinds #-}
2{-# language FlexibleInstances #-}
3{-# language FunctionalDependencies #-}
4{-# language ScopedTypeVariables #-}
5{-# language StandaloneKindSignatures #-}
6{-# language TypeApplications #-}
7{-# language TypeFamilies #-}
8{-# language UndecidableInstances #-}
10{-# options_ghc -fno-warn-orphans #-}
12module Rel8.Table.Rel8able
13 (
14 )
15where
17-- base
18import Data.Kind ( Constraint, Type )
19import Data.Type.Equality ( (:~:)( Refl ) )
20import Prelude
22-- rel8
23import Rel8.Expr ( Expr )
24import qualified Rel8.Kind.Algebra as K
25import Rel8.Kind.Context
26 ( SContext( SReify )
27 , Reifiable, contextSing
28 , sReifiable
29 )
30import Rel8.Generic.Rel8able
31 ( Rel8able, Algebra
32 , GColumns, gfromColumns, gtoColumns
33 , greify, gunreify
34 )
35import Rel8.Schema.Context ( Col )
36import Rel8.Schema.Dict ( Dict( Dict ) )
37import qualified Rel8.Schema.Kind as K
38import Rel8.Schema.HTable ( HConstrainTable, hdicts )
39import Rel8.Schema.Null ( Sql )
40import Rel8.Schema.Reify ( hreify, hunreify, UnwrapReify )
41import Rel8.Schema.Result ( Result )
42import Rel8.Table
43 ( Table, Columns, Context, Congruent, fromColumns, toColumns
44 , Unreify, reify, unreify
45 )
46import Rel8.Schema.Spec.Constrain ( ConstrainSpec )
47import Rel8.Table.ADT ( ADT( ADT ), ADTable, fromADT, toADT )
48import Rel8.Table.Eq ( EqTable, eqTable )
49import Rel8.Table.HKD ( HKD )
50import Rel8.Table.Ord ( OrdTable, ordTable )
51import Rel8.Table.Recontextualize ( Recontextualize )
52import Rel8.Table.Serialize ( FromExprs, ToExprs, fromResult, toResult )
53import Rel8.Type.Eq ( DBEq )
54import Rel8.Type.Ord ( DBOrd )
57instance (Rel8able t, Reifiable context) =>
58 Table context (t context)
59 where
60 type Columns (t context) = GColumns t
61 type Context (t context) = context
62 type Unreify (t context) = t (UnwrapReify context)
64 fromColumns = gunreify . gfromColumns . hreify
65 toColumns = hunreify . gtoColumns . greify
67 reify Refl = case contextSing @context of
68 SReify context -> case sReifiable context of
69 Dict -> greify
71 unreify Refl = case contextSing @context of
72 SReify context -> case sReifiable context of
73 Dict -> gunreify
76instance
77 ( Rel8able t
78 , Reifiable from
79 , Reifiable to
80 , Congruent (t from) (t to)
81 )
82 => Recontextualize from to (t from) (t to)
85instance
86 ( context ~ Expr
87 , Rel8able t
88 , HConstrainTable (Columns (t context)) (ConstrainSpec (Sql DBEq))
89 )
90 => EqTable (t context)
91 where
92 eqTable = hdicts @(Columns (t context)) @(ConstrainSpec (Sql DBEq))
95instance
96 ( context ~ Expr
97 , Rel8able t
98 , HConstrainTable (Columns (t context)) (ConstrainSpec (Sql DBEq))
99 , HConstrainTable (Columns (t context)) (ConstrainSpec (Sql DBOrd))
100 )
101 => OrdTable (t context)
102 where
103 ordTable = hdicts @(Columns (t context)) @(ConstrainSpec (Sql DBOrd))
106type instance FromExprs (t Expr) = FromExprs' t
109instance
110 ( x ~ t' Expr
111 , result ~ Result
112 , ToExprs' (Algebra t) t' t
113 )
114 => ToExprs x (t result)
115 where
116 fromResult = fromResult' @(Algebra t) @t'
117 toResult = toResult' @(Algebra t) @t'
120type FromExprs' :: K.Rel8able -> Type
121type family FromExprs' t where
122 FromExprs' (ADT t) = t Result
123 FromExprs' (HKD a) = a
124 FromExprs' t = t Result
127type ToExprs' :: K.Algebra -> K.Rel8able -> K.Rel8able -> Constraint
128class (algebra ~ Algebra t, Rel8able t') =>
129 ToExprs' algebra t' t | algebra t -> t'
130 where
131 fromResult' :: GColumns t' (Col Result) -> t Result
132 toResult' :: t Result -> GColumns t' (Col Result)
135instance (Algebra t ~ 'K.Product, Rel8able t, t ~ t') =>
136 ToExprs' 'K.Product t' t
137 where
138 fromResult' = fromColumns
139 toResult' = toColumns
142instance (Algebra t ~ 'K.Sum, ADTable t, t' ~ ADT t) =>
143 ToExprs' 'K.Sum t' t
144 where
145 fromResult' = fromADT . ADT
146 toResult' = (\(ADT a) -> a) . toADT