git.iko.soy/rel8
on 75d7b32 help sign in
rel8/src/Rel8/Table/Aggregate.hs
80 lines 2.6 kB history raw
1{-# language FlexibleContexts #-}
2{-# language NamedFieldPuns #-}
3{-# language ScopedTypeVariables #-}
4{-# language TypeApplications #-}
5{-# language TypeFamilies #-}
6{-# language ViewPatterns #-}
8module Rel8.Table.Aggregate
9 ( groupBy, hgroupBy
10 , listAgg, nonEmptyAgg
11 )
12where
14-- base
15import Data.Functor.Identity ( Identity( Identity ) )
16import Prelude
18-- rel8
19import Rel8.Aggregate ( Aggregate, Aggregates )
20import Rel8.Expr ( Expr )
21import Rel8.Expr.Aggregate
22 ( groupByExpr
23 , slistAggExpr
24 , snonEmptyAggExpr
25 )
26import Rel8.Schema.Dict ( Dict( Dict ) )
27import Rel8.Schema.HTable ( HTable, hfield, htabulate )
28import Rel8.Schema.HTable.Vectorize ( hvectorize )
29import Rel8.Schema.Null ( Sql )
30import Rel8.Schema.Spec ( Spec( Spec, info ) )
31import Rel8.Table ( toColumns, fromColumns )
32import Rel8.Table.Eq ( EqTable, eqTable )
33import Rel8.Table.List ( ListTable )
34import Rel8.Table.NonEmpty ( NonEmptyTable )
35import Rel8.Type.Eq ( DBEq )
38-- | Group equal tables together. This works by aggregating each column in the
39-- given table with 'groupByExpr'.
40groupBy :: forall exprs aggregates. (EqTable exprs, Aggregates aggregates exprs)
41 => exprs -> aggregates
42groupBy = fromColumns . hgroupBy (eqTable @exprs) . toColumns
45hgroupBy :: HTable t => t (Dict (Sql DBEq)) -> t Expr -> t Aggregate
46hgroupBy eqs exprs = htabulate $ \field ->
47 case hfield eqs field of
48 Dict -> case hfield exprs field of
49 expr -> groupByExpr expr
52-- | Aggregate rows into a single row containing an array of all aggregated
53-- rows. This can be used to associate multiple rows with a single row, without
54-- changing the over cardinality of the query. This allows you to essentially
55-- return a tree-like structure from queries.
56--
57-- For example, if we have a table of orders and each orders contains multiple
58-- items, we could aggregate the table of orders, pairing each order with its
59-- items:
60--
61-- @
62-- ordersWithItems :: Query (Order Expr, ListTable Expr (Item Expr))
63-- ordersWithItems = do
64-- order <- each orderSchema
65-- items <- aggregate $ listAgg <$> itemsFromOrder order
66-- return (order, items)
67-- @
68listAgg :: Aggregates aggregates exprs => exprs -> ListTable Aggregate aggregates
69listAgg (toColumns -> exprs) = fromColumns $
70 hvectorize
71 (\Spec {info} (Identity a) -> slistAggExpr info a)
72 (pure exprs)
75-- | Like 'listAgg', but the result is guaranteed to be a non-empty list.
76nonEmptyAgg :: Aggregates aggregates exprs => exprs -> NonEmptyTable Aggregate aggregates
77nonEmptyAgg (toColumns -> exprs) = fromColumns $
78 hvectorize
79 (\Spec {info} (Identity a) -> snonEmptyAggExpr info a)
80 (pure exprs)