git.iko.soy/rel8
on da76712 help sign in
rel8/src/Rel8/Expr/Function.hs
63 lines 1.9 kB history raw
1{-# language FlexibleContexts #-}
2{-# language FlexibleInstances #-}
3{-# language MultiParamTypeClasses #-}
4{-# language StandaloneKindSignatures #-}
5{-# language TypeFamilies #-}
6{-# language UndecidableInstances #-}
8module Rel8.Expr.Function
9 ( Function, function
10 , nullaryFunction
11 , binaryOperator
12 )
13where
15-- base
16import Data.Kind ( Constraint, Type )
17import Prelude
19-- opaleye
20import qualified Opaleye.Internal.HaskellDB.PrimQuery as Opaleye
22-- rel8
23import {-# SOURCE #-} Rel8.Expr ( Expr( Expr ) )
24import Rel8.Expr.Opaleye
25 ( castExpr
26 , fromPrimExpr, toPrimExpr, zipPrimExprsWith
27 )
28import Rel8.Schema.Null ( Sql )
29import Rel8.Type ( DBType )
32-- | This type class exists to allow 'function' to have arbitrary arity. It's
33-- mostly an implementation detail, and typical uses of 'Function' shouldn't
34-- need this to be specified.
35type Function :: Type -> Type -> Constraint
36class Function arg res where
37 applyArgument :: ([Opaleye.PrimExpr] -> Opaleye.PrimExpr) -> arg -> res
40instance (arg ~ Expr a, Sql DBType b) => Function arg (Expr b) where
41 applyArgument f a = castExpr $ fromPrimExpr $ f [toPrimExpr a]
44instance (arg ~ Expr a, Function args res) => Function arg (args -> res) where
45 applyArgument f a = applyArgument (f . (toPrimExpr a :))
48-- | Construct an n-ary function that produces an 'Expr' that when called runs
49-- a SQL function.
50function :: Function args result => String -> args -> result
51function = applyArgument . Opaleye.FunExpr
54-- | Construct a function call for functions with no arguments.
55nullaryFunction :: Sql DBType a => String -> Expr a
56nullaryFunction name = castExpr $ Expr (Opaleye.FunExpr name [])
59-- | Construct an expression by applying an infix binary operator to two
60-- operands.
61binaryOperator :: Sql DBType c => String -> Expr a -> Expr b -> Expr c
62binaryOperator operator a b =
63 castExpr $ zipPrimExprsWith (Opaleye.BinExpr (Opaleye.OpOther operator)) a b