git.iko.soy/rel8
on fab5b4e help sign in
rel8/src/Rel8/Query/Maybe.hs
87 lines 3.3 kB history raw
1module Rel8.Query.Maybe
2 ( optional
3 , catMaybeTable
4 , bindMaybeTable
5 , traverseMaybeTable
6 )
7where
9-- base
10import Prelude
12-- opaleye
13import qualified Opaleye.Internal.PackMap as Opaleye
14import qualified Opaleye.Internal.PrimQuery as Opaleye
15import qualified Opaleye.Internal.QueryArr as Opaleye
16import qualified Opaleye.Internal.Tag as Opaleye
17import qualified Opaleye.Internal.Unpackspec as Opaleye
19-- rel8
20import Rel8.Expr.Bool ( true )
21import Rel8.Expr.Eq ( (==.) )
22import Rel8.Expr.Opaleye ( toPrimExpr )
23import Rel8.Query ( Query )
24import Rel8.Query.Filter ( where_ )
25import Rel8.Query.Opaleye ( mapOpaleye )
26import Rel8.Table.Maybe ( MaybeTable( MaybeTable ), isJustTable )
27import Rel8.Table.Opaleye ( unpackspec )
28import Rel8.Table.Tag ( Tag(..), fromExpr )
31-- | Convert a query that might return zero rows to a query that always returns
32-- at least one row.
33--
34-- To speak in more concrete terms, 'optional' is most useful to write @LEFT
35-- JOIN@s.
36optional :: Query a -> Query (MaybeTable a)
37optional = mapOpaleye $ Opaleye.QueryArr . go
38 where
39 go query (i, left, tag) =
40 (MaybeTable (fromExpr t') a, join, Opaleye.next tag')
41 where
42 (MaybeTable Tag {expr = t} a, right, tag') =
43 Opaleye.runSimpleQueryArr (pure <$> query) (i, tag)
44 (t', bindings) = Opaleye.run $
45 Opaleye.runUnpackspec unpackspec (Opaleye.extractAttr "maybe" tag') t
46 join = Opaleye.Join Opaleye.LeftJoin condition [] bindings left right
47 condition = toPrimExpr true
50-- | Filter out 'MaybeTable's, returning only the tables that are not-null.
51--
52-- This operation can be used to "undo" the effect of 'optional', which
53-- operationally is like turning a @LEFT JOIN@ back into a full @JOIN@. You
54-- can think of this as analogous to 'Data.Maybe.catMaybes'.
55catMaybeTable :: MaybeTable a -> Query a
56catMaybeTable ma@(MaybeTable _ a) = do
57 where_ $ isJustTable ma
58 pure a
61-- | @bindMaybeTable f x@ is similar to the monadic bind (@>>=@) operation. It
62-- allows you to "extend" an optional query with another query. If either the
63-- input or output are 'Rel8.nothingTable', then the result is
64-- 'Rel8.nothingTable'.
65--
66-- This is similar to 'traverseMaybeTable', followed by a @join@ on the
67-- resulting @MaybeTable@s.
68bindMaybeTable :: Monad m
69 => (a -> m (MaybeTable b)) -> MaybeTable a -> m (MaybeTable b)
70bindMaybeTable query (MaybeTable input a) = do
71 MaybeTable output b <- query a
72 pure $ MaybeTable (input <> output) b
75-- | Extend an optional query with another query. This is useful if you want
76-- to step through multiple @LEFT JOINs@.
77--
78-- Note that @traverseMaybeTable@ takes a @a -> Query b@ function, which means
79-- you also have the ability to "expand" one row into multiple rows. If the
80-- @a -> Query b@ function returns no rows, then the resulting query will also
81-- have no rows. However, regardless of the given @a -> Query b@ function, if
82-- the input is @noTable@, you will always get exactly one @noTable@ back.
83traverseMaybeTable :: (a -> Query b) -> MaybeTable a -> Query (MaybeTable b)
84traverseMaybeTable query ma@(MaybeTable input _) = do
85 MaybeTable output b <- optional (query =<< catMaybeTable ma)
86 where_ $ expr output ==. expr input
87 pure $ MaybeTable input b