git.iko.soy/rel8
on fce7213 help sign in
rel8/src/Rel8/Expr/Function.hs
93 lines 2.5 kB history raw
1{-# language FlexibleContexts #-}
2{-# language FlexibleInstances #-}
3{-# language MultiParamTypeClasses #-}
4{-# language StandaloneKindSignatures #-}
5{-# language TypeFamilies #-}
6{-# language UndecidableInstances #-}
8module Rel8.Expr.Function
9 ( Function, function
10 , nullaryFunction
11 , binaryOperator
12 )
13where
15-- base
16import Data.Kind ( Constraint, Type )
17import Prelude
19-- opaleye
20import qualified Opaleye.Internal.HaskellDB.PrimQuery as Opaleye
22-- rel8
23import Rel8.Expr ( Expr( Expr ) )
24import Rel8.Expr.Opaleye
25 ( castExpr
26 , fromPrimExpr, toPrimExpr, zipPrimExprsWith
27 )
28import Rel8.Schema.Nullability ( Nullabilizes )
29import Rel8.Type ( DBType )
32type Function :: Type -> Type -> Constraint
33class Function arg res where
34 applyArgument :: ([Opaleye.PrimExpr] -> Opaleye.PrimExpr) -> arg -> res
37instance (arg ~ Expr a, DBType db, Nullabilizes db b) => Function arg (Expr b)
38 where
39 applyArgument f a = castExpr $ fromPrimExpr $ f [toPrimExpr a]
42instance (arg ~ Expr a, Function args res) => Function arg (args -> res) where
43 applyArgument f a = applyArgument (f . (toPrimExpr a :))
46-- | Construct an n-ary function that produces an 'Expr' that when called runs
47-- a SQL function.
48--
49-- For example, here's how we can wrap PostgreSQL's @factorial@ function:
50--
51-- >>> :{
52-- factorial :: Expr Int64 -> Expr Data.Scientific.Scientific
53-- factorial = function "factorial"
54-- :}
55--
56-- >>> select c $ pure $ factorial 5
57-- [120.0]
58--
59-- The same approach works for any number of arguments:
60--
61-- >>> :{
62-- power :: Expr Float -> Expr Float -> Expr Double
63-- power = function "power"
64-- :}
65--
66-- >>> select c $ pure $ power 9 3
67-- [729.0]
68function :: Function args result => String -> args -> result
69function = applyArgument . Opaleye.FunExpr
72-- | Construct a function call for functions with no arguments.
73--
74-- For example, we can call the database function @pi()@ by using
75-- @nullaryFunction@:
76--
77-- >>> :{
78-- sqlPi :: Expr Double
79-- sqlPi = nullaryFunction "pi"
80-- :}
81--
82-- >>> select c $ pure $ sqlPi
83-- [3.141592653589793]
84nullaryFunction :: (DBType db, Nullabilizes db a) => String -> Expr a
85nullaryFunction name = castExpr $ Expr (Opaleye.FunExpr name [])
88-- | Construct an expression by applying an infix binary operator to two
89-- operands.
90binaryOperator :: (DBType db, Nullabilizes db c)
91 => String -> Expr a -> Expr b -> Expr c
92binaryOperator operator a b =
93 castExpr $ zipPrimExprsWith (Opaleye.BinExpr (Opaleye.OpOther operator)) a b