git.iko.soy/rowtype-yoga/purescript-native
on 31f8958 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
204 lines 10 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import Data.Monoid ((<>))
30import qualified Data.Map as M
31import Control.Monad.State
32import Control.Monad.Error
34import Language.PureScript.Types
35import Language.PureScript.Names
36import Language.PureScript.Kinds
37import Language.PureScript.Declarations
38import Language.PureScript.TypeClassDictionaries
39import Language.PureScript.Environment
40import Language.PureScript.Errors
42addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
43addDataType moduleName name args dctors ctorKind = do
44 env <- getEnv
45 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, DataType args dctors) (types env) }
46 forM_ dctors $ \(dctor, tys) ->
47 rethrow (strMsg ("Error in data constructor " ++ show dctor) <>) $
48 addDataConstructor moduleName name args dctor tys
50addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
51addDataConstructor moduleName name args dctor tys = do
52 env <- getEnv
53 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
54 let dctorTy = foldr function retTy tys
55 let polyType = mkForAll args dctorTy
56 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (name, polyType) (dataConstructors env) }
58addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
59addTypeSynonym moduleName name args ty kind = do
60 env <- getEnv
61 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
62 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
64valueIsNotDefined :: ModuleName -> Ident -> Check ()
65valueIsNotDefined moduleName name = do
66 env <- getEnv
67 case M.lookup (moduleName, name) (names env) of
68 Just _ -> throwError . strMsg $ show name ++ " is already defined"
69 Nothing -> return ()
71addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
72addValue moduleName name ty nameKind = do
73 env <- getEnv
74 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind) (names env) })
76addTypeClass :: ModuleName -> ProperName -> [String] -> [Declaration] -> Check ()
77addTypeClass moduleName pn args ds =
78 let members = map (\(TypeDeclaration ident ty) -> (ident, ty)) ds in
79 modify $ \st -> st { checkEnv = (checkEnv st) { typeClasses = M.insert (Qualified (Just moduleName) pn) (args, members) (typeClasses . checkEnv $ st) } }
81addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
82addTypeClassDictionaries entries =
83 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
85checkTypeClassInstance :: ModuleName -> Type -> Check ()
86checkTypeClassInstance _ (TypeVar _) = return ()
87checkTypeClassInstance _ (TypeConstructor ctor) = do
88 env <- getEnv
89 when (ctor `M.member` typeSynonyms env) . throwError . strMsg $ "Type synonym instances are disallowed"
90 return ()
91checkTypeClassInstance m (TypeApp t1 t2) = checkTypeClassInstance m t1 >> checkTypeClassInstance m t2
92checkTypeClassInstance _ ty = throwError $ mkErrorStack "Type class instance head is invalid." (Just (TypeError ty))
94-- |
95-- Type check all declarations in a module
96--
97-- At this point, many declarations will have been desugared, but it is still necessary to
98--
99-- * Kind-check all types and add them to the @Environment@
100--
101-- * Type-check all values and add them to the @Environment@
102--
103-- * Bring type class instances into scope
104--
105-- * Process module imports
106--
107typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
108typeCheckAll _ _ [] = return []
109typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
110 rethrow (strMsg ("Error in type constructor " ++ show name) <>) $ do
111 ctorKind <- kindsOf True moduleName name args (concatMap snd dctors)
112 addDataType moduleName name args dctors ctorKind
113 ds <- typeCheckAll mainModuleName moduleName rest
114 return $ d : ds
115typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
116 rethrow (strMsg "Error in data binding group" <>) $ do
117 let syns = mapMaybe toTypeSynonym tys
118 let dataDecls = mapMaybe toDataDecl tys
119 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
120 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) ->
121 addDataType moduleName name args dctors ctorKind
122 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) ->
123 addTypeSynonym moduleName name args ty kind
124 ds <- typeCheckAll mainModuleName moduleName rest
125 return $ d : ds
126 where
127 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
128 toTypeSynonym (PositionedDeclaration _ d') = toTypeSynonym d'
129 toTypeSynonym _ = Nothing
130 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
131 toDataDecl (PositionedDeclaration _ d') = toDataDecl d'
132 toDataDecl _ = Nothing
133typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
134 rethrow (strMsg ("Error in type synonym " ++ show name) <>) $ do
135 kind <- kindsOf False moduleName name args [ty]
136 addTypeSynonym moduleName name args ty kind
137 ds <- typeCheckAll mainModuleName moduleName rest
138 return $ d : ds
139typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
140typeCheckAll mainModuleName moduleName (ValueDeclaration name nameKind [] Nothing val : rest) = do
141 d <- rethrow (strMsg ("Error in declaration " ++ show name) <>) $ do
142 valueIsNotDefined moduleName name
143 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
144 addValue moduleName name ty nameKind
145 return $ ValueDeclaration name nameKind [] Nothing val'
146 ds <- typeCheckAll mainModuleName moduleName rest
147 return $ d : ds
148typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
149typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
150 d <- rethrow (strMsg ("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals)) <>) $ do
151 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
152 valueIsNotDefined moduleName name
153 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
154 vals' <- forM (zipWith (\(name, nameKind, _) (_, (val, ty)) -> (name, val, nameKind, ty)) vals tys) $ \(name, val, nameKind, ty) -> do
155 addValue moduleName name ty nameKind
156 return (name, nameKind, val)
157 return $ BindingGroupDeclaration vals'
158 ds <- typeCheckAll mainModuleName moduleName rest
159 return $ d : ds
160typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
161 env <- getEnv
162 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, ExternData) (types env) }
163 ds <- typeCheckAll mainModuleName moduleName rest
164 return $ d : ds
165typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
166 rethrow (strMsg ("Error in foreign import declaration " ++ show name) <>) $ do
167 env <- getEnv
168 kind <- kindOf moduleName ty
169 guardWith (strMsg "Expected kind *") $ kind == Star
170 case M.lookup (moduleName, name) (names env) of
171 Just _ -> throwError . strMsg $ show name ++ " is already defined"
172 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
173 ds <- typeCheckAll mainModuleName moduleName rest
174 return $ d : ds
175typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
176 ds <- typeCheckAll mainModuleName moduleName rest
177 env <- getEnv
178 guardWith (strMsg ("Fixity declaration with no binding: " ++ name)) $ M.member (moduleName, Op name) $ names env
179 return $ d : ds
180typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName _ _) : rest) = do
181 env <- getEnv
182 let instances = filter (\tcd -> let Qualified (Just mn) _ = tcdName tcd in moduleName == mn) (typeClassDictionaries env)
183 addTypeClassDictionaries [ tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (canonicalizeDictionary tcd) }
184 | tcd <- instances
185 , let (Qualified _ ident) = tcdName tcd
186 ]
187 ds <- typeCheckAll mainModuleName currentModule rest
188 return $ d : ds
189typeCheckAll mainModuleName moduleName (d@(TypeClassDeclaration pn args tys) : rest) = do
190 addTypeClass moduleName pn args tys
191 ds <- typeCheckAll mainModuleName moduleName rest
192 return $ d : ds
193typeCheckAll mainModuleName moduleName (TypeInstanceDeclaration dictName deps className tys _ : rest) = do
194 typeCheckAll mainModuleName moduleName (ExternInstanceDeclaration dictName deps className tys : rest)
195typeCheckAll mainModuleName moduleName (d@(ExternInstanceDeclaration dictName deps className tys) : rest) = do
196 mapM_ (checkTypeClassInstance moduleName) tys
197 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
198 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
199 ds <- typeCheckAll mainModuleName moduleName rest
200 return $ d : ds
201typeCheckAll mainModuleName moduleName (PositionedDeclaration pos d : rest) =
202 rethrowWithPosition pos $ do
203 (d' : rest') <- typeCheckAll mainModuleName moduleName (d : rest)
204 return (PositionedDeclaration pos d' : rest')