git.iko.soy/rowtype-yoga/purescript-native
on 39a3a3d help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
194 lines 9.0 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
32import Data.Either (rights, lefts)
34import Language.PureScript.Types
35import Language.PureScript.Names
36import Language.PureScript.Values
37import Language.PureScript.Kinds
38import Language.PureScript.Declarations
39import Language.PureScript.Sugar.TypeClasses
40import Language.PureScript.Prim
42addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
43addDataType moduleName name args dctors ctorKind = do
44 env <- getEnv
45 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) ctorKind (types env) }
46 forM_ dctors $ \(dctor, tys) ->
47 rethrow (("Error in data constructor " ++ show dctor ++ ":\n") ++) $
48 addDataConstructor moduleName name args dctor tys
50addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
51addDataConstructor moduleName name args dctor tys = do
52 env <- getEnv
53 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
54 let dctorTy = foldr function retTy tys
55 let polyType = mkForAll args dctorTy
56 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) polyType (dataConstructors env) }
58addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
59addTypeSynonym moduleName name args ty kind = do
60 env <- getEnv
61 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) kind (types env)
62 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
64valueIsNotDefined :: ModuleName -> Ident -> Check ()
65valueIsNotDefined moduleName name = do
66 env <- getEnv
67 case M.lookup (moduleName, name) (names env) of
68 Just _ -> throwError $ show name ++ " is already defined"
69 Nothing -> return ()
71addValue :: ModuleName -> Ident -> Type -> Check ()
72addValue moduleName name ty = do
73 env <- getEnv
74 putEnv (env { names = M.insert (moduleName, name) (ty, Value) (names env) })
76addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
77addTypeClassDictionaries entries =
78 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
80checkTypeClassInstance :: ModuleName -> Type -> Check ()
81checkTypeClassInstance _ (TypeVar _) = return ()
82checkTypeClassInstance m (TypeConstructor ctor) = do
83 env <- getEnv
84 when (ctor `M.member` typeSynonyms env) $ throwError "Type synonym instances are disallowed"
85 return ()
86checkTypeClassInstance m (TypeApp ty (TypeVar _)) = checkTypeClassInstance m ty
87checkTypeClassInstance _ _ = throwError "Type class instance must be of the form T a1 ... an"
89-- |
90-- Type check all declarations in a module
91--
92-- At this point, many declarations will have been desugared, but it is still necessary to
93--
94-- * Kind-check all types and add them to the @Environment@
95--
96-- * Type-check all values and add them to the @Environment@
97--
98-- * Bring type class instances into scope
99--
100-- * Process module imports
101--
102typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
103typeCheckAll _ _ [] = return []
104typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
105 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
106 ctorKind <- kindsOf moduleName name args (concatMap snd dctors)
107 addDataType moduleName name args dctors ctorKind
108 ds <- typeCheckAll mainModuleName moduleName rest
109 return $ d : ds
110typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
111 rethrow ("Error in data binding group:\n" ++) $ do
112 let syns = mapMaybe toTypeSynonym tys
113 let dataDecls = mapMaybe toDataDecl tys
114 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
115 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) ->
116 addDataType moduleName name args dctors ctorKind
117 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) ->
118 addTypeSynonym moduleName name args ty kind
119 ds <- typeCheckAll mainModuleName moduleName rest
120 return $ d : ds
121 where
122 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
123 toTypeSynonym _ = Nothing
124 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
125 toDataDecl _ = Nothing
126typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
127 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
128 kind <- kindsOf moduleName name args [ty]
129 addTypeSynonym moduleName name args ty kind
130 ds <- typeCheckAll mainModuleName moduleName rest
131 return $ d : ds
132typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
133typeCheckAll mainModuleName moduleName (ValueDeclaration name [] Nothing val : rest) = do
134 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
135 valueIsNotDefined moduleName name
136 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
137 addValue moduleName name ty
138 return $ ValueDeclaration name [] Nothing val'
139 ds <- typeCheckAll mainModuleName moduleName rest
140 return $ d : ds
141typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
142typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
143 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
144 forM_ (map fst vals) $ \name ->
145 valueIsNotDefined moduleName name
146 tys <- typesOf mainModuleName moduleName vals
147 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
148 addValue moduleName name ty
149 return (name, val)
150 return $ BindingGroupDeclaration vals'
151 ds <- typeCheckAll mainModuleName moduleName rest
152 return $ d : ds
153typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
154 env <- getEnv
155 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) kind (types env) }
156 ds <- typeCheckAll mainModuleName moduleName rest
157 return $ d : ds
158typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
159 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
160 env <- getEnv
161 kind <- kindOf moduleName ty
162 guardWith "Expected kind *" $ kind == Star
163 case M.lookup (moduleName, name) (names env) of
164 Just _ -> throwError $ show name ++ " is already defined"
165 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
166 ds <- typeCheckAll mainModuleName moduleName rest
167 return $ d : ds
168typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
169 ds <- typeCheckAll mainModuleName moduleName rest
170 env <- getEnv
171 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
172 return $ d : ds
173typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
174 env <- getEnv
175 let instances = filter (\tcd ->
176 let Qualified (Just mn) _ = tcdName tcd in
177 moduleName == mn && tcdType tcd == TCDRegular
178 ) (typeClassDictionaries env)
179 forM_ instances $ \tcd -> do
180 let (Qualified _ ident) = tcdName tcd
181 addTypeClassDictionaries [tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (tcdName tcd) }]
182 ds <- typeCheckAll mainModuleName currentModule rest
183 return $ d : ds
184typeCheckAll mainModuleName moduleName (d@TypeClassDeclaration{} : rest) = do
185 env <- getEnv
186 ds <- typeCheckAll mainModuleName moduleName rest
187 return $ d : ds
188typeCheckAll mainModuleName moduleName (d@(TypeInstanceDeclaration dictName deps className tys _) : rest) = do
189 env <- getEnv
190 mapM_ (checkTypeClassInstance moduleName) tys
191 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
192 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
193 ds <- typeCheckAll mainModuleName moduleName rest
194 return $ d : ds