git.iko.soy/rowtype-yoga/purescript-native
on 3b6c4bd help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
214 lines 11 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12--
13-----------------------------------------------------------------------------
15{-# LANGUAGE FlexibleInstances #-}
17module Language.PureScript.TypeChecker (
18 module T,
19 typeCheckAll
20) where
22import Language.PureScript.TypeChecker.Monad as T
23import Language.PureScript.TypeChecker.Kinds as T
24import Language.PureScript.TypeChecker.Types as T
25import Language.PureScript.TypeChecker.Synonyms as T
27import Data.Data
28import Data.Generics (mkT, everywhere)
29import Data.Maybe
30import qualified Data.Map as M
31import Control.Monad.State
32import Control.Monad.Error
33import Data.Either (rights, lefts)
35import Language.PureScript.Types
36import Language.PureScript.Names
37import Language.PureScript.Kinds
38import Language.PureScript.Declarations
40addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, Maybe Type)] -> Kind -> Check ()
41addDataType moduleName name args dctors ctorKind = do
42 env <- getEnv
43 putEnv $ env { types = M.insert (moduleName, name) (ctorKind, Data) (types env) }
44 forM_ dctors $ \(dctor, maybeTy) ->
45 rethrow (("Error in data constructor " ++ show name ++ ":\n") ++) $
46 addDataConstructor moduleName name args dctor maybeTy
48addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> Maybe Type -> Check ()
49addDataConstructor moduleName name args dctor maybeTy = do
50 env <- getEnv
51 dataConstructorIsNotDefined moduleName dctor
52 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
53 let dctorTy = maybe retTy (\ty -> Function [ty] retTy) maybeTy
54 let polyType = mkForAll args dctorTy
55 putEnv $ env { dataConstructors = M.insert (moduleName, dctor) (qualifyAllUnqualifiedNames moduleName env polyType, DataConstructor) (dataConstructors env) }
57addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
58addTypeSynonym moduleName name args ty kind = do
59 env <- getEnv
60 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env)
61 , typeSynonyms = M.insert (moduleName, name) (args, qualifyAllUnqualifiedNames moduleName env ty) (typeSynonyms env) }
63typeIsNotDefined :: ModuleName -> ProperName -> Check ()
64typeIsNotDefined moduleName name = do
65 env <- getEnv
66 guardWith (show name ++ " is already defined") $
67 not $ M.member (moduleName, name) (types env)
69dataConstructorIsNotDefined :: ModuleName -> ProperName -> Check ()
70dataConstructorIsNotDefined moduleName dctor = do
71 env <- getEnv
72 guardWith (show dctor ++ " is already defined") $
73 not $ M.member (moduleName, dctor) (dataConstructors env)
75valueIsNotDefined :: ModuleName -> Ident -> Check ()
76valueIsNotDefined moduleName name = do
77 env <- getEnv
78 case M.lookup (moduleName, name) (names env) of
79 Just _ -> throwError $ show name ++ " is already defined"
80 Nothing -> return ()
82addValue :: ModuleName -> Ident -> Type -> Check ()
83addValue moduleName name ty = do
84 env <- getEnv
85 putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Value) (names env) })
87typeCheckAll :: ModuleName -> [Declaration] -> Check [Declaration]
88typeCheckAll _ [] = return []
89typeCheckAll moduleName (d@(DataDeclaration name args dctors) : rest) = do
90 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
91 typeIsNotDefined moduleName name
92 ctorKind <- kindsOf moduleName name args (mapMaybe snd dctors)
93 addDataType moduleName name args dctors ctorKind
94 ds <- typeCheckAll moduleName rest
95 return $ d : ds
96typeCheckAll moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
97 rethrow (("Error in data binding group " ++ show (map (\(name, _, _) -> name) tys) ++ ":\n") ++) $ do
98 forM_ tys $ \(name, _, _) ->
99 typeIsNotDefined moduleName name
100 ks <- kindsOfAll moduleName (map (\(name, args, dctors) -> (name, args, mapMaybe snd dctors)) tys)
101 forM_ (zip tys ks) $ \((name, args, dctors), ctorKind) ->
102 addDataType moduleName name args dctors ctorKind
103 ds <- typeCheckAll moduleName rest
104 return $ d : ds
105typeCheckAll moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
106 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
107 typeIsNotDefined moduleName name
108 kind <- kindsOf moduleName name args [ty]
109 addTypeSynonym moduleName name args ty kind
110 ds <- typeCheckAll moduleName rest
111 return $ d : ds
112typeCheckAll _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
113typeCheckAll moduleName (ValueDeclaration name [] Nothing val : rest) = do
114 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
115 valueIsNotDefined moduleName name
116 [(_, (val', ty))] <- typesOf moduleName [(name, val)]
117 addValue moduleName name ty
118 return $ ValueDeclaration name [] Nothing val'
119 ds <- typeCheckAll moduleName rest
120 return $ d : ds
121typeCheckAll _ (ValueDeclaration _ _ _ _ : _) = error "Binders were not desugared"
122typeCheckAll moduleName (BindingGroupDeclaration vals : rest) = do
123 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
124 forM_ (map fst vals) $ \name ->
125 valueIsNotDefined moduleName name
126 tys <- typesOf moduleName vals
127 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
128 addValue moduleName name ty
129 return (name, val)
130 return $ BindingGroupDeclaration vals'
131 ds <- typeCheckAll moduleName rest
132 return $ d : ds
133typeCheckAll moduleName (d@(ExternDataDeclaration name kind) : rest) = do
134 env <- getEnv
135 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
136 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env) }
137 ds <- typeCheckAll moduleName rest
138 return $ d : ds
139typeCheckAll moduleName (d@(ExternDeclaration name _ ty) : rest) = do
140 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
141 env <- getEnv
142 kind <- kindOf moduleName ty
143 guardWith "Expected kind *" $ kind == Star
144 case M.lookup (moduleName, name) (names env) of
145 Just _ -> throwError $ show name ++ " is already defined"
146 Nothing -> putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Extern) (names env) })
147 ds <- typeCheckAll moduleName rest
148 return $ d : ds
149typeCheckAll moduleName (d@(FixityDeclaration _ name) : rest) = do
150 ds <- typeCheckAll moduleName rest
151 env <- getEnv
152 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
153 return $ d : ds
154typeCheckAll currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
155 env <- getEnv
156 rethrow errorMessage $ do
157 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
158 case idents of
159 Nothing -> do
160 shadowIdents (map snd $ filterModule (names env)) env
161 shadowTypes (map snd $ filterModule (types env)) env
162 Just idents' -> do
163 shadowIdents (lefts idents') env
164 shadowTypes (rights idents') env
165 ds <- typeCheckAll currentModule rest
166 return $ d : ds
167 where errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
168 filterModule = filter ((== moduleName) . fst) . M.keys
169 moduleExists env = not (null (filterModule (names env))) || not (null (filterModule (types env)))
170 shadowIdents idents' env =
171 forM_ idents' $ \ident -> do
172 case (moduleName, ident) `M.lookup` names env of
173 Just (_, Alias _ _) -> return ()
174 Just (pt, _) -> do
175 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
176 modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
177 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
178 shadowTypes pns env =
179 forM_ pns $ \pn -> do
180 case (moduleName, pn) `M.lookup` types env of
181 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
182 Just (_, DataAlias _ _) -> return ()
183 Just (k, _) -> do
184 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (currentModule, pn) `M.notMember` types env
185 modifyEnv (\e -> e { types = M.insert (currentModule, pn) (k, DataAlias moduleName pn) (types e) })
186 let keys = map (snd . fst) . filter (\(_, (fn, _)) -> fn `constructs` pn) . M.toList . dataConstructors $ env
187 forM_ keys $ \dctor -> do
188 case (moduleName, dctor) `M.lookup` dataConstructors env of
189 Just (_, Alias _ _) -> return ()
190 Just (ctorTy, _) -> do
191 guardWith (show currentModule ++ "." ++ show dctor ++ " is already defined") $ (currentModule, dctor) `M.notMember` dataConstructors env
192 modifyEnv (\e -> e { dataConstructors = M.insert (currentModule, dctor) (ctorTy, Alias moduleName (Ident (runProperName dctor))) (dataConstructors e) })
193 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
194 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
195 = mn == moduleName && pn' == pn
196 constructs (ForAll _ ty) pn = ty `constructs` pn
197 constructs (Function _ ty) pn = ty `constructs` pn
198 constructs (TypeApp ty _) pn = ty `constructs` pn
199 constructs fn _ = error $ "Invalid arguments to constructs: " ++ show fn
200typeCheckAll moduleName (d@(TypeClassDeclaration _ _ _) : rest) = do
201 ds <- typeCheckAll moduleName rest
202 return $ d : ds
203typeCheckAll moduleName (d@(TypeInstanceDeclaration deps className ty _) : rest) = do
204 ds <- withTypeClassDictionaries [(Ident "__TODO", deps, className, ty)] $
205 typeCheckAll moduleName rest
206 return $ d : ds
208qualifyAllUnqualifiedNames :: (Data d) => ModuleName -> Environment -> d -> d
209qualifyAllUnqualifiedNames mn env = everywhere (mkT go)
210 where
211 go :: Qualified ProperName -> Qualified ProperName
212 go qual = let (mn', pn') = canonicalizeType mn env qual
213 in Qualified (Just mn') pn'