git.iko.soy/rowtype-yoga/purescript-native
on 52796ae help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
249 lines 12 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
32import Data.Either (rights, lefts)
34import Language.PureScript.Types
35import Language.PureScript.Names
36import Language.PureScript.Values
37import Language.PureScript.Kinds
38import Language.PureScript.Declarations
39import Language.PureScript.Sugar.TypeClasses
41addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
42addDataType moduleName name args dctors ctorKind = do
43 env <- getEnv
44 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, Data) (types env) }
45 forM_ dctors $ \(dctor, tys) ->
46 rethrow (("Error in data constructor " ++ show dctor ++ ":\n") ++) $
47 addDataConstructor moduleName name args dctor tys
49addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
50addDataConstructor moduleName name args dctor tys = do
51 env <- getEnv
52 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
53 let dctorTy = foldr function retTy tys
54 let polyType = mkForAll args dctorTy
55 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) polyType (dataConstructors env) }
57addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
58addTypeSynonym moduleName name args ty kind = do
59 env <- getEnv
60 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
61 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
63typeIsNotDefined :: ModuleName -> ProperName -> Check ()
64typeIsNotDefined moduleName name = do
65 env <- getEnv
66 guardWith (show name ++ " is already defined") $
67 not $ M.member (Qualified (Just moduleName) name) (types env)
69valueIsNotDefined :: ModuleName -> Ident -> Check ()
70valueIsNotDefined moduleName name = do
71 env <- getEnv
72 case M.lookup (moduleName, name) (names env) of
73 Just _ -> throwError $ show name ++ " is already defined"
74 Nothing -> return ()
76addValue :: ModuleName -> Ident -> Type -> Check ()
77addValue moduleName name ty = do
78 env <- getEnv
79 putEnv (env { names = M.insert (moduleName, name) (ty, Value) (names env) })
81addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
82addTypeClassDictionaries entries =
83 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
85checkTypeClassInstance :: ModuleName -> Type -> Check ()
86checkTypeClassInstance _ (TypeVar _) = return ()
87checkTypeClassInstance m (TypeConstructor ctor) = do
88 env <- getEnv
89 when (ctor `M.member` typeSynonyms env) $ throwError "Type synonym instances are disallowed"
90 return ()
91checkTypeClassInstance m (TypeApp ty (TypeVar _)) = checkTypeClassInstance m ty
92checkTypeClassInstance _ _ = throwError "Type class instance must be of the form T a1 ... an"
94-- |
95-- Type check all declarations in a module
96--
97-- At this point, many declarations will have been desugared, but it is still necessary to
98--
99-- * Kind-check all types and add them to the @Environment@
100--
101-- * Type-check all values and add them to the @Environment@
102--
103-- * Bring type class instances into scope
104--
105-- * Process module imports
106--
107typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
108typeCheckAll _ _ [] = return []
109typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
110 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
111 typeIsNotDefined moduleName name
112 ctorKind <- kindsOf moduleName name args (concatMap snd dctors)
113 addDataType moduleName name args dctors ctorKind
114 ds <- typeCheckAll mainModuleName moduleName rest
115 return $ d : ds
116typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
117 rethrow ("Error in data binding group:\n" ++) $ do
118 let syns = mapMaybe toTypeSynonym tys
119 let dataDecls = mapMaybe toDataDecl tys
120 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
121 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) -> do
122 typeIsNotDefined moduleName name
123 addDataType moduleName name args dctors ctorKind
124 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) -> do
125 typeIsNotDefined moduleName name
126 addTypeSynonym moduleName name args ty kind
127 ds <- typeCheckAll mainModuleName moduleName rest
128 return $ d : ds
129 where
130 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
131 toTypeSynonym _ = Nothing
132 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
133 toDataDecl _ = Nothing
134typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
135 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
136 typeIsNotDefined moduleName name
137 kind <- kindsOf moduleName name args [ty]
138 addTypeSynonym moduleName name args ty kind
139 ds <- typeCheckAll mainModuleName moduleName rest
140 return $ d : ds
141typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
142typeCheckAll mainModuleName moduleName (ValueDeclaration name [] Nothing val : rest) = do
143 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
144 valueIsNotDefined moduleName name
145 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
146 addValue moduleName name ty
147 return $ ValueDeclaration name [] Nothing val'
148 ds <- typeCheckAll mainModuleName moduleName rest
149 return $ d : ds
150typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
151typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
152 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
153 forM_ (map fst vals) $ \name ->
154 valueIsNotDefined moduleName name
155 tys <- typesOf mainModuleName moduleName vals
156 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
157 addValue moduleName name ty
158 return (name, val)
159 return $ BindingGroupDeclaration vals'
160 ds <- typeCheckAll mainModuleName moduleName rest
161 return $ d : ds
162typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
163 env <- getEnv
164 guardWith (show name ++ " is already defined") $ not $ M.member (Qualified (Just moduleName) name) (types env)
165 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env) }
166 ds <- typeCheckAll mainModuleName moduleName rest
167 return $ d : ds
168typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
169 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
170 env <- getEnv
171 kind <- kindOf moduleName ty
172 guardWith "Expected kind *" $ kind == Star
173 case M.lookup (moduleName, name) (names env) of
174 Just _ -> throwError $ show name ++ " is already defined"
175 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
176 ds <- typeCheckAll mainModuleName moduleName rest
177 return $ d : ds
178typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
179 ds <- typeCheckAll mainModuleName moduleName rest
180 env <- getEnv
181 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
182 return $ d : ds
183typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
184 env <- getEnv
185 rethrow errorMessage $ do
186 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
187 case idents of
188 Nothing -> do
189 shadowIdents (map snd $ filterModule (names env)) env
190 shadowTypes (map (\(Qualified _ name) -> name) $ filterModuleQ (types env)) env
191 Just idents' -> do
192 shadowIdents (lefts idents') env
193 shadowTypes (rights idents') env
194 shadowTypeClassInstances env
195 ds <- typeCheckAll mainModuleName currentModule rest
196 return $ d : ds
197 where
198 errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
199 filterModule = filter ((== moduleName) . fst) . M.keys
200 filterModuleQ = filter (\(Qualified (Just mn) _) -> mn == moduleName) . M.keys
201 moduleExists env = not (null (filterModule (names env))) || not (null (filterModuleQ (types env)))
202 shadowIdents idents' env =
203 forM_ idents' $ \ident ->
204 case (moduleName, ident) `M.lookup` names env of
205 Just (_, Alias _ _) -> return ()
206 Just (pt, _) -> do
207 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
208 modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
209 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
210 shadowTypes pns env =
211 forM_ pns $ \pn ->
212 case (Qualified (Just moduleName) pn) `M.lookup` types env of
213 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
214 Just (_, DataAlias _ _) -> return ()
215 Just (k, _) -> do
216 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (Qualified (Just currentModule) pn) `M.notMember` types env
217 modifyEnv (\e -> e { types = M.insert (Qualified (Just currentModule) pn) (k, DataAlias moduleName pn) (types e) })
218 let keys = map fst . filter (\(_, fn) -> fn `constructs` pn) . M.toList . dataConstructors $ env
219 forM_ keys $ \dctor ->
220 case dctor `M.lookup` dataConstructors env of
221 Just ctorTy -> do
222 modifyEnv (\e -> e { dataConstructors = M.insert dctor ctorTy (dataConstructors e) })
223 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
224 shadowTypeClassInstances env = do
225 let instances = filter (\tcd ->
226 let Qualified (Just mn) _ = tcdName tcd in
227 moduleName == mn && tcdType tcd == TCDRegular
228 ) (typeClassDictionaries env)
229 forM_ instances $ \tcd -> do
230 let (Qualified _ ident) = tcdName tcd
231 addTypeClassDictionaries [tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (tcdName tcd) }]
232 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
233 = mn == moduleName && pn' == pn
234 constructs (ForAll _ ty _) pn = ty `constructs` pn
235 constructs (TypeApp (TypeApp t _) ty) pn | t == tyFunction = ty `constructs` pn
236 constructs (TypeApp ty _) pn = ty `constructs` pn
237 constructs fn _ = error $ "Invalid arguments to constructs: " ++ show fn
238typeCheckAll mainModuleName moduleName (d@TypeClassDeclaration{} : rest) = do
239 env <- getEnv
240 ds <- typeCheckAll mainModuleName moduleName rest
241 return $ d : ds
242typeCheckAll mainModuleName moduleName (d@(TypeInstanceDeclaration deps className tys _) : rest) = do
243 env <- getEnv
244 dictName <- Check . lift $ mkDictionaryValueName moduleName className tys
245 mapM_ (checkTypeClassInstance moduleName) tys
246 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
247 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
248 ds <- typeCheckAll mainModuleName moduleName rest
249 return $ d : ds