git.iko.soy/rowtype-yoga/purescript-native
on 53359aa help sign in
rowtype-yoga/purescript-native/src/Language/PureScript.hs
276 lines 11 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript
4-- Copyright : (c) 2013-14 Phil Freeman, (c) 2014 Gary Burgess, and other contributors
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The main compiler module
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DataKinds #-}
17{-# LANGUAGE QuasiQuotes #-}
18{-# LANGUAGE TemplateHaskell #-}
19{-# LANGUAGE FlexibleContexts #-}
20{-# LANGUAGE ScopedTypeVariables #-}
22module Language.PureScript
23 ( module P
24 , compile
25 , compile'
26 , RebuildPolicy(..)
27 , MonadMake(..)
28 , make
29 , prelude
30 , version
31 ) where
33import Data.FileEmbed (embedFile)
34import Data.Function (on)
35import Data.List (sortBy, groupBy, intercalate)
36import Data.Maybe (fromMaybe)
37import Data.Time.Clock
38import Data.Version (Version)
39import qualified Data.Traversable as T (traverse)
40import qualified Data.ByteString.UTF8 as BU
41import qualified Data.Map as M
42import qualified Data.Set as S
44import Control.Applicative
45import Control.Arrow ((&&&))
46import Control.Monad.Except
47import Control.Monad.Reader
49import System.FilePath ((</>))
51import Language.PureScript.AST as P
52import Language.PureScript.Comments as P
53import Language.PureScript.CodeGen as P
54import Language.PureScript.DeadCodeElimination as P
55import Language.PureScript.Environment as P
56import Language.PureScript.Errors as P
57import Language.PureScript.Kinds as P
58import Language.PureScript.ModuleDependencies as P
59import Language.PureScript.Names as P
60import Language.PureScript.Options as P
61import Language.PureScript.Parser as P
62import Language.PureScript.Pretty as P
63import Language.PureScript.Renamer as P
64import Language.PureScript.Sugar as P
65import Control.Monad.Supply as P
66import Language.PureScript.TypeChecker as P
67import Language.PureScript.Types as P
68import qualified Language.PureScript.CoreFn as CoreFn
69import qualified Language.PureScript.Constants as C
71import qualified Paths_purescript as Paths
73-- |
74-- Compile a collection of modules
75--
76-- The compilation pipeline proceeds as follows:
77--
78-- * Sort the modules based on module dependencies, checking for cyclic dependencies.
79--
80-- * Perform a set of desugaring passes.
81--
82-- * Type check, and elaborate values to include type annotations and type class dictionaries.
83--
84-- * Regroup values to take into account new value dependencies introduced by elaboration.
85--
86-- * Eliminate dead code.
87--
88-- * Generate Javascript, and perform optimization passes.
89--
90-- * Pretty-print the generated Javascript
91--
92compile :: (Functor m, Applicative m, MonadError MultipleErrors m, MonadReader (Options Compile) m)
93 => [Module] -> [String] -> m (String, String, Environment)
94compile = compile' initEnvironment
96compile' :: (Functor m, Applicative m, MonadError MultipleErrors m, MonadReader (Options Compile) m)
97 => Environment -> [Module] -> [String] -> m (String, String, Environment)
98compile' env ms prefix = do
99 noPrelude <- asks optionsNoPrelude
100 additional <- asks optionsAdditional
101 mainModuleIdent <- asks (fmap moduleNameFromString . optionsMain)
102 (sorted, _) <- sortModules $ map importPrim $ if noPrelude then ms else map importPrelude ms
103 (desugared, nextVar) <- runSupplyT 0 $ desugar sorted
104 (elaborated, env') <- runCheck' env $ forM desugared $ typeCheckModule mainModuleIdent
105 regrouped <- createBindingGroupsModule . collapseBindingGroupsModule $ elaborated
106 let corefn = map (CoreFn.moduleToCoreFn env') regrouped
107 let entryPoints = moduleNameFromString `map` entryPointModules additional
108 let elim = if null entryPoints then corefn else eliminateDeadCode entryPoints corefn
109 let renamed = renameInModules elim
110 let codeGenModuleNames = moduleNameFromString `map` codeGenModules additional
111 let modulesToCodeGen = if null codeGenModuleNames then renamed else filter (\(CoreFn.Module _ mn _ _ _ _) -> mn `elem` codeGenModuleNames) renamed
112 js <- concat <$> (evalSupplyT nextVar $ T.traverse moduleToJs modulesToCodeGen)
113 let exts = intercalate "\n" . map (`moduleToPs` env') $ regrouped
114 js' <- generateMain env' js
115 let pjs = unlines $ map ("// " ++) prefix ++ [prettyPrintJS js']
116 return (pjs, exts, env')
118generateMain :: (MonadError MultipleErrors m, MonadReader (Options Compile) m) => Environment -> [JS] -> m [JS]
119generateMain env js = do
120 main <- asks optionsMain
121 additional <- asks optionsAdditional
122 case moduleNameFromString <$> main of
123 Just mmi -> do
124 when ((mmi, Ident C.main) `M.notMember` names env) $
125 throwError . errorMessage $ NameIsUndefined (Ident C.main)
126 return $ js ++ [JSApp (JSAccessor C.main (JSAccessor (moduleNameToJs mmi) (JSVar (browserNamespace additional)))) []]
127 _ -> return js
129-- |
130-- A type class which collects the IO actions we need to be able to run in "make" mode
131--
132class (MonadReader (P.Options P.Make) m, MonadError MultipleErrors m) => MonadMake m where
133 -- |
134 -- Get a file timestamp
135 --
136 getTimestamp :: FilePath -> m (Maybe UTCTime)
138 -- |
139 -- Read a file as a string
140 --
141 readTextFile :: FilePath -> m String
143 -- |
144 -- Write a text file
145 --
146 writeTextFile :: FilePath -> String -> m ()
148 -- |
149 -- Respond to a progress update
150 --
151 progress :: String -> m ()
153-- |
154-- Determines when to rebuild a module
155--
156data RebuildPolicy
157 -- | Never rebuild this module
158 = RebuildNever
159 -- | Always rebuild this module
160 | RebuildAlways deriving (Show, Eq, Ord)
162-- Traverse (Either e) instance (base 4.7)
163traverseEither :: Applicative f => (a -> f b) -> Either e a -> f (Either e b)
164traverseEither _ (Left x) = pure (Left x)
165traverseEither f (Right y) = Right <$> f y
167-- |
168-- Compiles in "make" mode, compiling each module separately to a js files and an externs file
169--
170-- If timestamps have not changed, the externs file can be used to provide the module's types without
171-- having to typecheck the module again.
172--
173make :: forall m. (Functor m, Applicative m, Monad m, MonadMake m)
174 => FilePath -> [(Either RebuildPolicy FilePath, Module)] -> [String] -> m Environment
175make outputDir ms prefix = do
176 noPrelude <- asks optionsNoPrelude
177 let filePathMap = M.fromList (map (\(fp, Module _ mn _ _) -> (mn, fp)) ms)
179 (sorted, graph) <- sortModules $ map importPrim $ if noPrelude then map snd ms else map (importPrelude . snd) ms
181 toRebuild <- foldM (\s (Module _ moduleName' _ _) -> do
182 let filePath = runModuleName moduleName'
184 jsFile = outputDir </> filePath </> "index.js"
185 externsFile = outputDir </> filePath </> "externs.purs"
186 inputFile = fromMaybe (error "Module has no filename in 'make'") $ M.lookup moduleName' filePathMap
188 jsTimestamp <- getTimestamp jsFile
189 externsTimestamp <- getTimestamp externsFile
190 inputTimestamp <- traverseEither getTimestamp inputFile
192 return $ case (inputTimestamp, jsTimestamp, externsTimestamp) of
193 (Right (Just t1), Just t2, Just t3) | t1 < min t2 t3 -> s
194 (Left RebuildNever, Just _, Just _) -> s
195 _ -> S.insert moduleName' s) S.empty sorted
197 marked <- rebuildIfNecessary (reverseDependencies graph) toRebuild sorted
199 (desugared, nextVar) <- runSupplyT 0 $ zip (map fst marked) <$> desugar (map snd marked)
201 evalSupplyT nextVar $ go initEnvironment desugared
203 where
204 go :: Environment -> [(Bool, Module)] -> SupplyT m Environment
205 go env [] = return env
206 go env ((False, m) : ms') = do
207 (_, env') <- lift . runCheck' env $ typeCheckModule Nothing m
209 go env' ms'
210 go env ((True, m@(Module coms moduleName' _ exps)) : ms') = do
211 let filePath = runModuleName moduleName'
212 jsFile = outputDir </> filePath </> "index.js"
213 externsFile = outputDir </> filePath </> "externs.purs"
215 lift . progress $ "Compiling " ++ runModuleName moduleName'
217 (Module _ _ elaborated _, env') <- lift . runCheck' env $ typeCheckModule Nothing m
219 regrouped <- createBindingGroups moduleName' . collapseBindingGroups $ elaborated
221 let mod' = Module coms moduleName' regrouped exps
222 let corefn = CoreFn.moduleToCoreFn env' mod'
223 let [renamed] = renameInModules [corefn]
225 pjs <- prettyPrintJS <$> moduleToJs renamed
226 let js = unlines $ map ("// " ++) prefix ++ [pjs]
227 let exts = unlines $ map ("-- " ++) prefix ++ [moduleToPs mod' env']
229 lift $ writeTextFile jsFile js
230 lift $ writeTextFile externsFile exts
232 go env' ms'
234 rebuildIfNecessary :: M.Map ModuleName [ModuleName] -> S.Set ModuleName -> [Module] -> m [(Bool, Module)]
235 rebuildIfNecessary _ _ [] = return []
236 rebuildIfNecessary graph toRebuild (m@(Module _ moduleName' _ _) : ms') | moduleName' `S.member` toRebuild = do
237 let deps = fromMaybe [] $ moduleName' `M.lookup` graph
238 toRebuild' = toRebuild `S.union` S.fromList deps
239 (:) (True, m) <$> rebuildIfNecessary graph toRebuild' ms'
240 rebuildIfNecessary graph toRebuild (Module _ moduleName' _ _ : ms') = do
241 let externsFile = outputDir </> runModuleName moduleName' </> "externs.purs"
242 externs <- readTextFile externsFile
243 externsModules <- fmap (map snd) . either (throwError . errorMessage . ErrorParsingExterns) return $ P.parseModulesFromFiles id [(externsFile, externs)]
244 case externsModules of
245 [m'@(Module _ moduleName'' _ _)] | moduleName'' == moduleName' -> (:) (False, m') <$> rebuildIfNecessary graph toRebuild ms'
246 _ -> throwError . errorMessage . InvalidExternsFile $ externsFile
248reverseDependencies :: ModuleGraph -> M.Map ModuleName [ModuleName]
249reverseDependencies g = combine [ (dep, mn) | (mn, deps) <- g, dep <- deps ]
250 where
251 combine :: (Ord a) => [(a, b)] -> M.Map a [b]
252 combine = M.fromList . map ((fst . head) &&& map snd) . groupBy ((==) `on` fst) . sortBy (compare `on` fst)
254-- |
255-- Add an import declaration for a module if it does not already explicitly import it.
256--
257addDefaultImport :: ModuleName -> Module -> Module
258addDefaultImport toImport m@(Module coms mn decls exps) =
259 if isExistingImport `any` decls || mn == toImport then m
260 else Module coms mn (ImportDeclaration toImport Implicit Nothing : decls) exps
261 where
262 isExistingImport (ImportDeclaration mn' _ _) | mn' == toImport = True
263 isExistingImport (PositionedDeclaration _ _ d) = isExistingImport d
264 isExistingImport _ = False
266importPrim :: Module -> Module
267importPrim = addDefaultImport (ModuleName [ProperName C.prim])
269importPrelude :: Module -> Module
270importPrelude = addDefaultImport (ModuleName [ProperName C.prelude])
272prelude :: String
273prelude = BU.toString $(embedFile "prelude/prelude.purs")
275version :: Version
276version = Paths.version