git.iko.soy/rowtype-yoga/purescript-native
on 55e092d help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/Scope.hs
62 lines 1.8 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.Scope
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- Utility functions for working with names in scope
13--
14-----------------------------------------------------------------------------
16module Language.PureScript.Scope (
17 usedNames,
18 unusedNames
19) where
21import Control.Applicative ((<$>))
23import Data.Data
24import Data.List ((\\), nub)
25import Data.Generics (extQ, mkQ, everything)
27import Language.PureScript.Values
28import Language.PureScript.Names
29import Language.PureScript.CodeGen.JS.AST
31-- |
32-- Gather all used names appearing inside a value
33--
34usedNames :: (Data d) => d -> [Ident]
35usedNames val = nub $ everything (++) (mkQ [] namesV `extQ` namesB `extQ` namesJS) val
36 where
37 namesV :: Value -> [Ident]
38 namesV (Abs (Left arg) _) = [arg]
39 namesV (Var (Qualified Nothing name)) = [name]
40 namesV _ = []
41 namesB :: Binder -> [Ident]
42 namesB (VarBinder name) = [name]
43 namesB _ = []
44 namesJS :: JS -> [Ident]
45 namesJS (JSVar name) = [Ident name]
46 namesJS (JSFunction (Just name) args _) = Ident name : (Ident <$> args)
47 namesJS (JSFunction Nothing args _) = Ident <$> args
48 namesJS (JSVariableIntroduction name _) = [Ident name]
49 namesJS (JSFor name _ _ _) = [Ident name]
50 namesJS (JSForIn name _ _) = [Ident name]
51 namesJS _ = []
53-- |
54-- Generate a set of names which are unused inside a value, of the form @_{n}@ for an integer @n@
55--
56unusedNames :: (Data d) => d -> [Ident]
57unusedNames val =
58 let
59 allNames = usedNames val
60 varNames = map (Ident . ('_' :) . show) ([1..] :: [Int])
61 in
62 varNames \\ allNames