git.iko.soy/rowtype-yoga/purescript-native
on 5ce8345 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
233 lines 12 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12--
13-----------------------------------------------------------------------------
15{-# LANGUAGE FlexibleInstances #-}
17module Language.PureScript.TypeChecker (
18 module T,
19 typeCheckAll
20) where
22import Language.PureScript.TypeChecker.Monad as T
23import Language.PureScript.TypeChecker.Kinds as T
24import Language.PureScript.TypeChecker.Types as T
25import Language.PureScript.TypeChecker.Synonyms as T
27import Data.Maybe
28import qualified Data.Map as M
29import Control.Monad.State
30import Control.Monad.Error
31import Data.Either (rights, lefts)
33import Language.PureScript.Types
34import Language.PureScript.Names
35import Language.PureScript.Values
36import Language.PureScript.Kinds
37import Language.PureScript.Declarations
38import Language.PureScript.Sugar.TypeClasses
40addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, Maybe Type)] -> Kind -> Check ()
41addDataType moduleName name args dctors ctorKind = do
42 env <- getEnv
43 putEnv $ env { types = M.insert (moduleName, name) (ctorKind, Data) (types env) }
44 forM_ dctors $ \(dctor, maybeTy) ->
45 rethrow (("Error in data constructor " ++ show name ++ ":\n") ++) $
46 addDataConstructor moduleName name args dctor maybeTy
48addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> Maybe Type -> Check ()
49addDataConstructor moduleName name args dctor maybeTy = do
50 env <- getEnv
51 dataConstructorIsNotDefined moduleName dctor
52 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
53 let dctorTy = maybe retTy (\ty -> Function [ty] retTy) maybeTy
54 let polyType = mkForAll args dctorTy
55 putEnv $ env { dataConstructors = M.insert (moduleName, dctor) (qualifyAllUnqualifiedNames moduleName env polyType, DataConstructor) (dataConstructors env) }
57addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
58addTypeSynonym moduleName name args ty kind = do
59 env <- getEnv
60 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env)
61 , typeSynonyms = M.insert (moduleName, name) (args, qualifyAllUnqualifiedNames moduleName env ty) (typeSynonyms env) }
63typeIsNotDefined :: ModuleName -> ProperName -> Check ()
64typeIsNotDefined moduleName name = do
65 env <- getEnv
66 guardWith (show name ++ " is already defined") $
67 not $ M.member (moduleName, name) (types env)
69dataConstructorIsNotDefined :: ModuleName -> ProperName -> Check ()
70dataConstructorIsNotDefined moduleName dctor = do
71 env <- getEnv
72 guardWith (show dctor ++ " is already defined") $
73 not $ M.member (moduleName, dctor) (dataConstructors env)
75valueIsNotDefined :: ModuleName -> Ident -> Check ()
76valueIsNotDefined moduleName name = do
77 env <- getEnv
78 case M.lookup (moduleName, name) (names env) of
79 Just _ -> throwError $ show name ++ " is already defined"
80 Nothing -> return ()
82addValue :: ModuleName -> Ident -> Type -> Check ()
83addValue moduleName name ty = do
84 env <- getEnv
85 putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Value) (names env) })
87addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
88addTypeClassDictionaries entries = do
89 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
91typeCheckAll :: ModuleName -> [Declaration] -> Check [Declaration]
92typeCheckAll _ [] = return []
93typeCheckAll moduleName (d@(DataDeclaration name args dctors) : rest) = do
94 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
95 typeIsNotDefined moduleName name
96 ctorKind <- kindsOf moduleName name args (mapMaybe snd dctors)
97 addDataType moduleName name args dctors ctorKind
98 ds <- typeCheckAll moduleName rest
99 return $ d : ds
100typeCheckAll moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
101 rethrow ("Error in data binding group:\n" ++) $ do
102 let syns = mapMaybe toTypeSynonym tys
103 let dataDecls = mapMaybe toDataDecl tys
104 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, mapMaybe snd dctors)) dataDecls)
105 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) -> do
106 typeIsNotDefined moduleName name
107 addDataType moduleName name args dctors ctorKind
108 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) -> do
109 typeIsNotDefined moduleName name
110 addTypeSynonym moduleName name args ty kind
111 ds <- typeCheckAll moduleName rest
112 return $ d : ds
113 where
114 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
115 toTypeSynonym _ = Nothing
116 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
117 toDataDecl _ = Nothing
118typeCheckAll moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
119 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
120 typeIsNotDefined moduleName name
121 kind <- kindsOf moduleName name args [ty]
122 addTypeSynonym moduleName name args ty kind
123 ds <- typeCheckAll moduleName rest
124 return $ d : ds
125typeCheckAll _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
126typeCheckAll moduleName (ValueDeclaration name [] Nothing val : rest) = do
127 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
128 valueIsNotDefined moduleName name
129 [(_, (val', ty))] <- typesOf moduleName [(name, val)]
130 addValue moduleName name ty
131 return $ ValueDeclaration name [] Nothing val'
132 ds <- typeCheckAll moduleName rest
133 return $ d : ds
134typeCheckAll _ (ValueDeclaration _ _ _ _ : _) = error "Binders were not desugared"
135typeCheckAll moduleName (BindingGroupDeclaration vals : rest) = do
136 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
137 forM_ (map fst vals) $ \name ->
138 valueIsNotDefined moduleName name
139 tys <- typesOf moduleName vals
140 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
141 addValue moduleName name ty
142 return (name, val)
143 return $ BindingGroupDeclaration vals'
144 ds <- typeCheckAll moduleName rest
145 return $ d : ds
146typeCheckAll moduleName (d@(ExternDataDeclaration name kind) : rest) = do
147 env <- getEnv
148 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
149 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env) }
150 ds <- typeCheckAll moduleName rest
151 return $ d : ds
152typeCheckAll moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
153 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
154 env <- getEnv
155 kind <- kindOf moduleName ty
156 guardWith "Expected kind *" $ kind == Star
157 case M.lookup (moduleName, name) (names env) of
158 Just _ -> throwError $ show name ++ " is already defined"
159 Nothing -> putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Extern importTy) (names env) })
160 ds <- typeCheckAll moduleName rest
161 return $ d : ds
162typeCheckAll moduleName (d@(FixityDeclaration _ name) : rest) = do
163 ds <- typeCheckAll moduleName rest
164 env <- getEnv
165 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
166 return $ d : ds
167typeCheckAll currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
168 env <- getEnv
169 rethrow errorMessage $ do
170 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
171 case idents of
172 Nothing -> do
173 shadowIdents (map snd $ filterModule (names env)) env
174 shadowTypes (map snd $ filterModule (types env)) env
175 Just idents' -> do
176 shadowIdents (lefts idents') env
177 shadowTypes (rights idents') env
178 shadowTypeClassInstances env
179 ds <- typeCheckAll currentModule rest
180 return $ d : ds
181 where
182 errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
183 filterModule = filter ((== moduleName) . fst) . M.keys
184 moduleExists env = not (null (filterModule (names env))) || not (null (filterModule (types env)))
185 shadowIdents idents' env =
186 forM_ idents' $ \ident -> do
187 case (moduleName, ident) `M.lookup` names env of
188 Just (_, Alias _ _) -> return ()
189 Just (pt, _) -> do
190 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
191 modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
192 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
193 shadowTypes pns env =
194 forM_ pns $ \pn -> do
195 case (moduleName, pn) `M.lookup` types env of
196 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
197 Just (_, DataAlias _ _) -> return ()
198 Just (k, _) -> do
199 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (currentModule, pn) `M.notMember` types env
200 modifyEnv (\e -> e { types = M.insert (currentModule, pn) (k, DataAlias moduleName pn) (types e) })
201 let keys = map (snd . fst) . filter (\(_, (fn, _)) -> fn `constructs` pn) . M.toList . dataConstructors $ env
202 forM_ keys $ \dctor -> do
203 case (moduleName, dctor) `M.lookup` dataConstructors env of
204 Just (_, Alias _ _) -> return ()
205 Just (ctorTy, _) -> do
206 guardWith (show currentModule ++ "." ++ show dctor ++ " is already defined") $ (currentModule, dctor) `M.notMember` dataConstructors env
207 modifyEnv (\e -> e { dataConstructors = M.insert (currentModule, dctor) (ctorTy, Alias moduleName (Ident (runProperName dctor))) (dataConstructors e) })
208 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
209 shadowTypeClassInstances env = do
210 let instances = filter (\tcd ->
211 let Qualified (Just mn) _ = tcdName tcd in
212 moduleName == mn && tcdType tcd == TCDRegular
213 ) (typeClassDictionaries env)
214 forM_ instances $ \tcd -> do
215 let (Qualified _ ident) = tcdName tcd
216 addTypeClassDictionaries [tcd { tcdName = (Qualified (Just currentModule) ident), tcdType = TCDAlias (tcdName tcd) }]
217 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
218 = mn == moduleName && pn' == pn
219 constructs (ForAll _ ty) pn = ty `constructs` pn
220 constructs (Function _ ty) pn = ty `constructs` pn
221 constructs (TypeApp ty _) pn = ty `constructs` pn
222 constructs fn _ = error $ "Invalid arguments to constructs: " ++ show fn
223typeCheckAll moduleName (d@(TypeClassDeclaration _ _ _) : rest) = do
224 env <- getEnv
225 ds <- typeCheckAll moduleName rest
226 return $ qualifyAllUnqualifiedNames moduleName env d : ds
227typeCheckAll moduleName (d@(TypeInstanceDeclaration deps className ty _) : rest) = do
228 env <- getEnv
229 dictName <- Check . lift $ mkDictionaryValueName moduleName className ty
230 addTypeClassDictionaries (qualifyAllUnqualifiedNames moduleName env
231 [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className ty (Just deps) TCDRegular])
232 ds <- typeCheckAll moduleName rest
233 return $ qualifyAllUnqualifiedNames moduleName env d : ds