git.iko.soy/rowtype-yoga/purescript-native
on 5df930c help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
190 lines 9.1 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
33import Language.PureScript.Types
34import Language.PureScript.Names
35import Language.PureScript.Values
36import Language.PureScript.Kinds
37import Language.PureScript.Declarations
38import Language.PureScript.Prim
40addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
41addDataType moduleName name args dctors ctorKind = do
42 env <- getEnv
43 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) ctorKind (types env) }
44 forM_ dctors $ \(dctor, tys) ->
45 rethrow (("Error in data constructor " ++ show dctor ++ ":\n") ++) $
46 addDataConstructor moduleName name args dctor tys
48addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
49addDataConstructor moduleName name args dctor tys = do
50 env <- getEnv
51 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
52 let dctorTy = foldr function retTy tys
53 let polyType = mkForAll args dctorTy
54 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (name, polyType) (dataConstructors env) }
56addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
57addTypeSynonym moduleName name args ty kind = do
58 env <- getEnv
59 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) kind (types env)
60 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
62valueIsNotDefined :: ModuleName -> Ident -> Check ()
63valueIsNotDefined moduleName name = do
64 env <- getEnv
65 case M.lookup (moduleName, name) (names env) of
66 Just _ -> throwError $ show name ++ " is already defined"
67 Nothing -> return ()
69addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
70addValue moduleName name ty nameKind = do
71 env <- getEnv
72 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind) (names env) })
74addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
75addTypeClassDictionaries entries =
76 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
78checkTypeClassInstance :: ModuleName -> Type -> Check ()
79checkTypeClassInstance _ (TypeVar _) = return ()
80checkTypeClassInstance _ (TypeConstructor ctor) = do
81 env <- getEnv
82 when (ctor `M.member` typeSynonyms env) $ throwError "Type synonym instances are disallowed"
83 return ()
84checkTypeClassInstance m (TypeApp ty (TypeVar _)) = checkTypeClassInstance m ty
85checkTypeClassInstance _ _ = throwError "Type class instance must be of the form T a1 ... an"
87-- |
88-- Type check all declarations in a module
89--
90-- At this point, many declarations will have been desugared, but it is still necessary to
91--
92-- * Kind-check all types and add them to the @Environment@
93--
94-- * Type-check all values and add them to the @Environment@
95--
96-- * Bring type class instances into scope
97--
98-- * Process module imports
99--
100typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
101typeCheckAll _ _ [] = return []
102typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
103 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
104 ctorKind <- kindsOf moduleName name args (concatMap snd dctors)
105 addDataType moduleName name args dctors ctorKind
106 ds <- typeCheckAll mainModuleName moduleName rest
107 return $ d : ds
108typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
109 rethrow ("Error in data binding group:\n" ++) $ do
110 let syns = mapMaybe toTypeSynonym tys
111 let dataDecls = mapMaybe toDataDecl tys
112 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
113 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) ->
114 addDataType moduleName name args dctors ctorKind
115 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) ->
116 addTypeSynonym moduleName name args ty kind
117 ds <- typeCheckAll mainModuleName moduleName rest
118 return $ d : ds
119 where
120 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
121 toTypeSynonym _ = Nothing
122 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
123 toDataDecl _ = Nothing
124typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
125 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
126 kind <- kindsOf moduleName name args [ty]
127 addTypeSynonym moduleName name args ty kind
128 ds <- typeCheckAll mainModuleName moduleName rest
129 return $ d : ds
130typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
131typeCheckAll mainModuleName moduleName (ValueDeclaration name nameKind [] Nothing val : rest) = do
132 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
133 valueIsNotDefined moduleName name
134 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
135 addValue moduleName name ty nameKind
136 return $ ValueDeclaration name nameKind [] Nothing val'
137 ds <- typeCheckAll mainModuleName moduleName rest
138 return $ d : ds
139typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
140typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
141 d <- rethrow (("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals) ++ ":\n") ++) $ do
142 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
143 valueIsNotDefined moduleName name
144 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
145 vals' <- forM (zipWith (\(name, nameKind, _) (_, (val, ty)) -> (name, val, nameKind, ty)) vals tys) $ \(name, val, nameKind, ty) -> do
146 addValue moduleName name ty nameKind
147 return (name, nameKind, val)
148 return $ BindingGroupDeclaration vals'
149 ds <- typeCheckAll mainModuleName moduleName rest
150 return $ d : ds
151typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
152 env <- getEnv
153 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) kind (types env) }
154 ds <- typeCheckAll mainModuleName moduleName rest
155 return $ d : ds
156typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
157 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
158 env <- getEnv
159 kind <- kindOf moduleName ty
160 guardWith "Expected kind *" $ kind == Star
161 case M.lookup (moduleName, name) (names env) of
162 Just _ -> throwError $ show name ++ " is already defined"
163 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
164 ds <- typeCheckAll mainModuleName moduleName rest
165 return $ d : ds
166typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
167 ds <- typeCheckAll mainModuleName moduleName rest
168 env <- getEnv
169 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
170 return $ d : ds
171typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName _) : rest) = do
172 env <- getEnv
173 let instances = filter (\tcd ->
174 let Qualified (Just mn) _ = tcdName tcd in
175 moduleName == mn && tcdType tcd == TCDRegular
176 ) (typeClassDictionaries env)
177 forM_ instances $ \tcd -> do
178 let (Qualified _ ident) = tcdName tcd
179 addTypeClassDictionaries [tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (tcdName tcd) }]
180 ds <- typeCheckAll mainModuleName currentModule rest
181 return $ d : ds
182typeCheckAll mainModuleName moduleName (d@TypeClassDeclaration{} : rest) = do
183 ds <- typeCheckAll mainModuleName moduleName rest
184 return $ d : ds
185typeCheckAll mainModuleName moduleName (d@(TypeInstanceDeclaration dictName deps className tys _) : rest) = do
186 mapM_ (checkTypeClassInstance moduleName) tys
187 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
188 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
189 ds <- typeCheckAll mainModuleName moduleName rest
190 return $ d : ds