git.iko.soy/rowtype-yoga/purescript-native
on 79fcdf4 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript.hs
269 lines 11 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The main compiler module
13--
14-----------------------------------------------------------------------------
16module Language.PureScript (module P, compile, compile', MonadMake(..), make, preludeFilename) where
18import Language.PureScript.Types as P
19import Language.PureScript.Kinds as P
20import Language.PureScript.Declarations as P
21import Language.PureScript.Names as P
22import Language.PureScript.Parser as P
23import Language.PureScript.CodeGen as P
24import Language.PureScript.CodeGen.Common as P
25import Language.PureScript.TypeChecker as P
26import Language.PureScript.Pretty as P
27import Language.PureScript.Sugar as P
28import Language.PureScript.Options as P
29import Language.PureScript.ModuleDependencies as P
30import Language.PureScript.Environment as P
31import Language.PureScript.Errors as P
32import Language.PureScript.DeadCodeElimination as P
33import Language.PureScript.Supply as P
34import Language.PureScript.Renamer as P
36import qualified Language.PureScript.Constants as C
37import qualified Paths_purescript as Paths
39import Data.List (find, sortBy, groupBy, intercalate)
40import Data.Time.Clock
41import Data.Function (on)
42import Data.Maybe (fromJust, fromMaybe)
43import Control.Monad.Error
44import Control.Monad.State.Lazy
45import Control.Arrow ((&&&))
46import Control.Applicative
47import qualified Data.Map as M
48import qualified Data.Set as S
49import System.FilePath (pathSeparator)
51-- |
52-- Compile a collection of modules
53--
54-- The compilation pipeline proceeds as follows:
55--
56-- * Sort the modules based on module dependencies, checking for cyclic dependencies.
57--
58-- * Perform a set of desugaring passes.
59--
60-- * Type check, and elaborate values to include type annotations and type class dictionaries.
61--
62-- * Regroup values to take into account new value dependencies introduced by elaboration.
63--
64-- * Eliminate dead code.
65--
66-- * Generate Javascript, and perform optimization passes.
67--
68-- * Pretty-print the generated Javascript
69--
70compile :: Options -> [Module] -> [String] -> Either String (String, String, Environment)
71compile = compile' initEnvironment
73compile' :: Environment -> Options -> [Module] -> [String] -> Either String (String, String, Environment)
74compile' env opts ms prefix = do
75 (sorted, _) <- sortModules $ map importPrim $ if optionsNoPrelude opts then ms else (map importPrelude ms)
76 (desugared, nextVar) <- stringifyErrorStack True $ runSupplyT 0 $ desugar sorted
77 (elaborated, env') <- runCheck' opts env $ forM desugared $ typeCheckModule mainModuleIdent
78 regrouped <- stringifyErrorStack True $ createBindingGroupsModule . collapseBindingGroupsModule $ elaborated
79 let entryPoints = moduleNameFromString `map` optionsModules opts
80 let elim = if null entryPoints then regrouped else eliminateDeadCode entryPoints regrouped
81 let renamed = renameInModules elim
82 let codeGenModules = moduleNameFromString `map` optionsCodeGenModules opts
83 let modulesToCodeGen = if null codeGenModules then renamed else filter (\(Module mn _ _) -> mn `elem` codeGenModules) renamed
84 let js = evalSupply nextVar $ concat <$> mapM (\m -> moduleToJs Globals opts m env') modulesToCodeGen
85 let exts = intercalate "\n" . map (`moduleToPs` env') $ modulesToCodeGen
86 js' <- generateMain env' opts js
87 let pjs = unlines $ map ("// " ++) prefix ++ [prettyPrintJS js']
88 return (pjs, exts, env')
89 where
90 mainModuleIdent = moduleNameFromString <$> optionsMain opts
92typeCheckModule :: Maybe ModuleName -> Module -> Check Module
93typeCheckModule mainModuleName (Module mn decls exps) = do
94 modify (\s -> s { checkCurrentModule = Just mn })
95 decls' <- typeCheckAll mainModuleName mn decls
96 mapM_ checkTypesAreExported exps'
97 return $ Module mn decls' exps
98 where
100 exps' = fromMaybe (error "exports should have been elaborated") exps
102 -- Check that all the type constructors defined in the current module that appear in member types
103 -- have also been exported from the module
104 checkTypesAreExported :: DeclarationRef -> Check ()
105 checkTypesAreExported (ValueRef name) = do
106 ty <- lookupVariable mn (Qualified (Just mn) name)
107 case find isTconHidden (findTcons ty) of
108 Just hiddenType -> throwError . strMsg $
109 "Error in module '" ++ show mn ++ "':\n\
110 \Exporting declaration '" ++ show name ++ "' requires type '" ++ show hiddenType ++ "' to be exported as well"
111 Nothing -> return ()
112 checkTypesAreExported _ = return ()
114 -- Find the type constructors exported from the current module used in a type
115 findTcons :: Type -> [ProperName]
116 findTcons = everythingOnTypes (++) go
117 where
118 go (TypeConstructor (Qualified (Just mn') name)) | mn' == mn = [name]
119 go _ = []
121 -- Checks whether a type constructor is not being exported from the current module
122 isTconHidden :: ProperName -> Bool
123 isTconHidden tyName = all go exps'
124 where
125 go (TypeRef tyName' _) = tyName' /= tyName
126 go _ = True
129generateMain :: Environment -> Options -> [JS] -> Either String [JS]
130generateMain env opts js =
131 case moduleNameFromString <$> optionsMain opts of
132 Just mmi -> do
133 when ((mmi, Ident C.main) `M.notMember` names env) $
134 Left $ show mmi ++ "." ++ C.main ++ " is undefined"
135 return $ js ++ [JSApp (JSAccessor C.main (JSAccessor (moduleNameToJs mmi) (JSVar (fromJust (optionsBrowserNamespace opts))))) []]
136 _ -> return js
138-- |
139-- A type class which collects the IO actions we need to be able to run in "make" mode
140--
141class MonadMake m where
142 -- |
143 -- Get a file timestamp
144 --
145 getTimestamp :: FilePath -> m (Maybe UTCTime)
147 -- |
148 -- Read a file as a string
149 --
150 readTextFile :: FilePath -> m String
152 -- |
153 -- Write a text file
154 --
155 writeTextFile :: FilePath -> String -> m ()
157 -- |
158 -- Report an error
159 --
160 liftError :: Either String a -> m a
162 -- |
163 -- Respond to a progress update
164 --
165 progress :: String -> m ()
167-- |
168-- Compiles in "make" mode, compiling each module separately to a js files and an externs file
169--
170-- If timestamps have not changed, the externs file can be used to provide the module's types without
171-- having to typecheck the module again.
172--
173make :: (Functor m, Applicative m, Monad m, MonadMake m) => FilePath -> Options -> [(FilePath, Module)] -> [String] -> m Environment
174make outputDir opts ms prefix = do
175 let filePathMap = M.fromList (map (\(fp, Module mn _ _) -> (mn, fp)) ms)
177 (sorted, graph) <- liftError $ sortModules $ map importPrim $ if optionsNoPrelude opts then map snd ms else (map (importPrelude . snd) ms)
179 toRebuild <- foldM (\s (Module moduleName' _ _) -> do
180 let filePath = runModuleName moduleName'
182 jsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "index.js"
183 externsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "externs.purs"
184 inputFile = fromMaybe (error "Input file is undefined in make") $ M.lookup moduleName' filePathMap
186 jsTimestamp <- getTimestamp jsFile
187 externsTimestamp <- getTimestamp externsFile
188 inputTimestamp <- getTimestamp inputFile
190 return $ case (inputTimestamp, jsTimestamp, externsTimestamp) of
191 (Just t1, Just t2, Just t3) | t1 < min t2 t3 -> s
192 _ -> S.insert moduleName' s) S.empty sorted
194 marked <- rebuildIfNecessary (reverseDependencies graph) toRebuild sorted
196 (desugared, nextVar) <- liftError $ stringifyErrorStack True $ runSupplyT 0 $ zip (map fst marked) <$> desugar (map snd marked)
198 evalSupplyT nextVar (go initEnvironment desugared)
200 where
201 go :: (Functor m, Applicative m, Monad m, MonadMake m) => Environment -> [(Bool, Module)] -> SupplyT m Environment
202 go env [] = return env
203 go env ((False, m) : ms') = do
204 (_, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
206 go env' ms'
207 go env ((True, m@(Module moduleName' _ exps)) : ms') = do
208 let filePath = runModuleName moduleName'
209 jsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "index.js"
210 externsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "externs.purs"
212 lift . progress $ "Compiling " ++ runModuleName moduleName'
214 (Module _ elaborated _, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
216 regrouped <- lift . liftError . stringifyErrorStack True . createBindingGroups moduleName' . collapseBindingGroups $ elaborated
218 let mod' = Module moduleName' regrouped exps
219 let [renamed] = renameInModules [mod']
221 pjs <- prettyPrintJS <$> moduleToJs CommonJS opts renamed env'
222 let js = unlines $ map ("// " ++) prefix ++ [pjs]
223 let exts = unlines $ map ("-- " ++ ) prefix ++ [moduleToPs renamed env']
225 lift $ writeTextFile jsFile js
226 lift $ writeTextFile externsFile exts
228 go env' ms'
230 rebuildIfNecessary :: (Functor m, Monad m, MonadMake m) => M.Map ModuleName [ModuleName] -> S.Set ModuleName -> [Module] -> m [(Bool, Module)]
231 rebuildIfNecessary _ _ [] = return []
232 rebuildIfNecessary graph toRebuild (m@(Module moduleName' _ _) : ms') | moduleName' `S.member` toRebuild = do
233 let deps = fromMaybe [] $ moduleName' `M.lookup` graph
234 toRebuild' = toRebuild `S.union` S.fromList deps
235 (:) (True, m) <$> rebuildIfNecessary graph toRebuild' ms'
236 rebuildIfNecessary graph toRebuild (Module moduleName' _ _ : ms') = do
237 let externsFile = outputDir ++ pathSeparator : runModuleName moduleName' ++ pathSeparator : "externs.purs"
238 externs <- readTextFile externsFile
239 externsModules <- liftError . either (Left . show) Right $ P.runIndentParser externsFile P.parseModules externs
240 case externsModules of
241 [m'@(Module moduleName'' _ _)] | moduleName'' == moduleName' -> (:) (False, m') <$> rebuildIfNecessary graph toRebuild ms'
242 _ -> liftError . Left $ "Externs file " ++ externsFile ++ " was invalid"
244reverseDependencies :: ModuleGraph -> M.Map ModuleName [ModuleName]
245reverseDependencies g = combine [ (dep, mn) | (mn, deps) <- g, dep <- deps ]
246 where
247 combine :: (Ord a) => [(a, b)] -> M.Map a [b]
248 combine = M.fromList . map ((fst . head) &&& map snd) . groupBy ((==) `on` fst) . sortBy (compare `on` fst)
250-- |
251-- Add an import declaration for a module if it does not already explicitly import it.
252--
253addDefaultImport :: ModuleName -> Module -> Module
254addDefaultImport toImport m@(Module mn decls exps) =
255 if isExistingImport `any` decls || mn == toImport then m
256 else Module mn (ImportDeclaration toImport Unqualified Nothing : decls) exps
257 where
258 isExistingImport (ImportDeclaration mn' _ _) | mn' == toImport = True
259 isExistingImport (PositionedDeclaration _ d) = isExistingImport d
260 isExistingImport _ = False
262importPrim :: Module -> Module
263importPrim = addDefaultImport (ModuleName [ProperName C.prim])
265importPrelude :: Module -> Module
266importPrelude = addDefaultImport (ModuleName [ProperName C.prelude])
268preludeFilename :: IO FilePath
269preludeFilename = Paths.getDataFileName "prelude/prelude.purs"