git.iko.soy/rowtype-yoga/purescript-native
on 7f7abde help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/ModuleDependencies.hs
62 lines 1.9 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.ModuleDependencies
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- | Provides the ability to sort modules based on module dependencies
12--
13-----------------------------------------------------------------------------
15module Language.PureScript.ModuleDependencies (
16 sortModules
17) where
19import Data.Data
20import Data.Graph
21import Data.Generics
22import Data.List (nub)
24import Language.PureScript.Declarations
25import Language.PureScript.Names
27-- |
28-- Sort a collection of modules based on module dependencies.
29--
30-- Reports an error if the module graph contains a cycle.
31--
32sortModules :: [Module] -> Either String [Module]
33sortModules ms = do
34 let verts = map (\m -> (m, getModuleName m, usedModules m)) ms
35 mapM toModule $ stronglyConnComp verts
37-- |
38-- Calculate a list of used modules based on explicit imports and qualified names
39--
40usedModules :: (Data d) => d -> [ModuleName]
41usedModules = nub . everything (++) (mkQ [] qualifiedIdents `extQ` qualifiedProperNames `extQ` imports)
42 where
43 qualifiedIdents :: Qualified Ident -> [ModuleName]
44 qualifiedIdents (Qualified (Just mn) _) = [mn]
45 qualifiedIdents _ = []
46 qualifiedProperNames :: Qualified ProperName -> [ModuleName]
47 qualifiedProperNames (Qualified (Just mn) _) = [mn]
48 qualifiedProperNames _ = []
49 imports :: Declaration -> [ModuleName]
50 imports (ImportDeclaration mn _) = [mn]
51 imports _ = []
53getModuleName :: Module -> ModuleName
54getModuleName (Module mn _ _) = mn
56-- |
57-- Convert a strongly connected component of the module graph to a module
58--
59toModule :: SCC Module -> Either String Module
60toModule (AcyclicSCC m) = return m
61toModule (CyclicSCC [m]) = return m
62toModule (CyclicSCC _) = Left "Cycle in module dependencies"