git.iko.soy/rowtype-yoga/purescript-native
on 856ca36 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
247 lines 12 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
32import Data.Either (rights, lefts)
34import Language.PureScript.Types
35import Language.PureScript.Names
36import Language.PureScript.Values
37import Language.PureScript.Kinds
38import Language.PureScript.Declarations
39import Language.PureScript.Sugar.TypeClasses
41addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, Maybe Type)] -> Kind -> Check ()
42addDataType moduleName name args dctors ctorKind = do
43 env <- getEnv
44 putEnv $ env { types = M.insert (moduleName, name) (ctorKind, Data) (types env) }
45 forM_ dctors $ \(dctor, maybeTy) ->
46 rethrow (("Error in data constructor " ++ show name ++ ":\n") ++) $
47 addDataConstructor moduleName name args dctor maybeTy
49addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> Maybe Type -> Check ()
50addDataConstructor moduleName name args dctor maybeTy = do
51 env <- getEnv
52 dataConstructorIsNotDefined moduleName dctor
53 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
54 let dctorTy = maybe retTy (\ty -> Function [ty] retTy) maybeTy
55 let polyType = mkForAll args dctorTy
56 putEnv $ env { dataConstructors = M.insert (moduleName, dctor) (qualifyAllUnqualifiedNames moduleName env polyType, DataConstructor) (dataConstructors env) }
58addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
59addTypeSynonym moduleName name args ty kind = do
60 env <- getEnv
61 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env)
62 , typeSynonyms = M.insert (moduleName, name) (args, qualifyAllUnqualifiedNames moduleName env ty) (typeSynonyms env) }
64typeIsNotDefined :: ModuleName -> ProperName -> Check ()
65typeIsNotDefined moduleName name = do
66 env <- getEnv
67 guardWith (show name ++ " is already defined") $
68 not $ M.member (moduleName, name) (types env)
70dataConstructorIsNotDefined :: ModuleName -> ProperName -> Check ()
71dataConstructorIsNotDefined moduleName dctor = do
72 env <- getEnv
73 guardWith (show dctor ++ " is already defined") $
74 not $ M.member (moduleName, dctor) (dataConstructors env)
76valueIsNotDefined :: ModuleName -> Ident -> Check ()
77valueIsNotDefined moduleName name = do
78 env <- getEnv
79 case M.lookup (moduleName, name) (names env) of
80 Just _ -> throwError $ show name ++ " is already defined"
81 Nothing -> return ()
83addValue :: ModuleName -> Ident -> Type -> Check ()
84addValue moduleName name ty = do
85 env <- getEnv
86 putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Value) (names env) })
88addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
89addTypeClassDictionaries entries = do
90 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
92-- |
93-- Type check all declarations in a module
94--
95-- At this point, many declarations will have been desugared, but it is still necessary to
96--
97-- * Kind-check all types and add them to the @Environment@
98--
99-- * Type-check all values and add them to the @Environment@
100--
101-- * Bring type class instances into scope
102--
103-- * Process module imports
104--
105typeCheckAll :: ModuleName -> [Declaration] -> Check [Declaration]
106typeCheckAll _ [] = return []
107typeCheckAll moduleName (d@(DataDeclaration name args dctors) : rest) = do
108 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
109 typeIsNotDefined moduleName name
110 ctorKind <- kindsOf moduleName name args (mapMaybe snd dctors)
111 addDataType moduleName name args dctors ctorKind
112 ds <- typeCheckAll moduleName rest
113 return $ d : ds
114typeCheckAll moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
115 rethrow ("Error in data binding group:\n" ++) $ do
116 let syns = mapMaybe toTypeSynonym tys
117 let dataDecls = mapMaybe toDataDecl tys
118 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, mapMaybe snd dctors)) dataDecls)
119 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) -> do
120 typeIsNotDefined moduleName name
121 addDataType moduleName name args dctors ctorKind
122 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) -> do
123 typeIsNotDefined moduleName name
124 addTypeSynonym moduleName name args ty kind
125 ds <- typeCheckAll moduleName rest
126 return $ d : ds
127 where
128 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
129 toTypeSynonym _ = Nothing
130 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
131 toDataDecl _ = Nothing
132typeCheckAll moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
133 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
134 typeIsNotDefined moduleName name
135 kind <- kindsOf moduleName name args [ty]
136 addTypeSynonym moduleName name args ty kind
137 ds <- typeCheckAll moduleName rest
138 return $ d : ds
139typeCheckAll _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
140typeCheckAll moduleName (ValueDeclaration name [] Nothing val : rest) = do
141 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
142 valueIsNotDefined moduleName name
143 [(_, (val', ty))] <- typesOf moduleName [(name, val)]
144 addValue moduleName name ty
145 return $ ValueDeclaration name [] Nothing val'
146 ds <- typeCheckAll moduleName rest
147 return $ d : ds
148typeCheckAll _ (ValueDeclaration _ _ _ _ : _) = error "Binders were not desugared"
149typeCheckAll moduleName (BindingGroupDeclaration vals : rest) = do
150 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
151 forM_ (map fst vals) $ \name ->
152 valueIsNotDefined moduleName name
153 tys <- typesOf moduleName vals
154 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
155 addValue moduleName name ty
156 return (name, val)
157 return $ BindingGroupDeclaration vals'
158 ds <- typeCheckAll moduleName rest
159 return $ d : ds
160typeCheckAll moduleName (d@(ExternDataDeclaration name kind) : rest) = do
161 env <- getEnv
162 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
163 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env) }
164 ds <- typeCheckAll moduleName rest
165 return $ d : ds
166typeCheckAll moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
167 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
168 env <- getEnv
169 kind <- kindOf moduleName ty
170 guardWith "Expected kind *" $ kind == Star
171 case M.lookup (moduleName, name) (names env) of
172 Just _ -> throwError $ show name ++ " is already defined"
173 Nothing -> putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Extern importTy) (names env) })
174 ds <- typeCheckAll moduleName rest
175 return $ d : ds
176typeCheckAll moduleName (d@(FixityDeclaration _ name) : rest) = do
177 ds <- typeCheckAll moduleName rest
178 env <- getEnv
179 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
180 return $ d : ds
181typeCheckAll currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
182 env <- getEnv
183 rethrow errorMessage $ do
184 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
185 case idents of
186 Nothing -> do
187 shadowIdents (map snd $ filterModule (names env)) env
188 shadowTypes (map snd $ filterModule (types env)) env
189 Just idents' -> do
190 shadowIdents (lefts idents') env
191 shadowTypes (rights idents') env
192 shadowTypeClassInstances env
193 ds <- typeCheckAll currentModule rest
194 return $ d : ds
195 where
196 errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
197 filterModule = filter ((== moduleName) . fst) . M.keys
198 moduleExists env = not (null (filterModule (names env))) || not (null (filterModule (types env)))
199 shadowIdents idents' env =
200 forM_ idents' $ \ident -> do
201 case (moduleName, ident) `M.lookup` names env of
202 Just (_, Alias _ _) -> return ()
203 Just (pt, _) -> do
204 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
205 modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
206 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
207 shadowTypes pns env =
208 forM_ pns $ \pn -> do
209 case (moduleName, pn) `M.lookup` types env of
210 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
211 Just (_, DataAlias _ _) -> return ()
212 Just (k, _) -> do
213 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (currentModule, pn) `M.notMember` types env
214 modifyEnv (\e -> e { types = M.insert (currentModule, pn) (k, DataAlias moduleName pn) (types e) })
215 let keys = map (snd . fst) . filter (\(_, (fn, _)) -> fn `constructs` pn) . M.toList . dataConstructors $ env
216 forM_ keys $ \dctor -> do
217 case (moduleName, dctor) `M.lookup` dataConstructors env of
218 Just (_, Alias _ _) -> return ()
219 Just (ctorTy, _) -> do
220 guardWith (show currentModule ++ "." ++ show dctor ++ " is already defined") $ (currentModule, dctor) `M.notMember` dataConstructors env
221 modifyEnv (\e -> e { dataConstructors = M.insert (currentModule, dctor) (ctorTy, Alias moduleName (Ident (runProperName dctor))) (dataConstructors e) })
222 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
223 shadowTypeClassInstances env = do
224 let instances = filter (\tcd ->
225 let Qualified (Just mn) _ = tcdName tcd in
226 moduleName == mn && tcdType tcd == TCDRegular
227 ) (typeClassDictionaries env)
228 forM_ instances $ \tcd -> do
229 let (Qualified _ ident) = tcdName tcd
230 addTypeClassDictionaries [tcd { tcdName = (Qualified (Just currentModule) ident), tcdType = TCDAlias (tcdName tcd) }]
231 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
232 = mn == moduleName && pn' == pn
233 constructs (ForAll _ ty) pn = ty `constructs` pn
234 constructs (Function _ ty) pn = ty `constructs` pn
235 constructs (TypeApp ty _) pn = ty `constructs` pn
236 constructs fn _ = error $ "Invalid arguments to constructs: " ++ show fn
237typeCheckAll moduleName (d@(TypeClassDeclaration _ _ _) : rest) = do
238 env <- getEnv
239 ds <- typeCheckAll moduleName rest
240 return $ qualifyAllUnqualifiedNames moduleName env d : ds
241typeCheckAll moduleName (d@(TypeInstanceDeclaration deps className ty _) : rest) = do
242 env <- getEnv
243 dictName <- Check . lift $ mkDictionaryValueName moduleName className ty
244 addTypeClassDictionaries (qualifyAllUnqualifiedNames moduleName env
245 [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className ty (Just deps) TCDRegular])
246 ds <- typeCheckAll moduleName rest
247 return $ qualifyAllUnqualifiedNames moduleName env d : ds