git.iko.soy/rowtype-yoga/purescript-native
on 8df45c5 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript.hs
253 lines 10.0 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript
4-- Copyright : (c) 2013-14 Phil Freeman, (c) 2014 Gary Burgess, and other contributors
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The main compiler module
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DataKinds #-}
17{-# LANGUAGE FlexibleContexts #-}
18{-# LANGUAGE RecordWildCards #-}
19{-# LANGUAGE ScopedTypeVariables #-}
21module Language.PureScript
22 ( module P
23 , compile
24 , compile'
25 , RebuildPolicy(..)
26 , MakeActions(..)
27 , make
28 , version
29 ) where
31import Data.Function (on)
32import Data.List (sortBy, groupBy, intercalate)
33import Data.Maybe (fromMaybe)
34import Data.Time.Clock
35import Data.Version (Version)
36import qualified Data.Map as M
37import qualified Data.Set as S
39import Control.Applicative
40import Control.Arrow ((&&&))
41import Control.Monad
42import Control.Monad.Error.Class (MonadError(..))
43import Control.Monad.Reader
44import Control.Monad.Writer
45import Control.Monad.Supply.Class (fresh)
47import Language.PureScript.AST as P
48import Language.PureScript.Comments as P
49import Language.PureScript.CodeGen
50import Language.PureScript.DeadCodeElimination as P
51import Language.PureScript.Environment as P
52import Language.PureScript.Errors as P
53import Language.PureScript.Kinds as P
54import Language.PureScript.Linter as P
55import Language.PureScript.ModuleDependencies as P
56import Language.PureScript.Names as P
57import Language.PureScript.Options as P
58import Language.PureScript.Parser as P
59import Language.PureScript.Pretty as P
60import Language.PureScript.Renamer as P
61import Language.PureScript.Sugar as P
62import Control.Monad.Supply as P
63import Language.PureScript.TypeChecker as P
64import Language.PureScript.Types as P
65import qualified Language.PureScript.CoreFn as CoreFn
66import qualified Language.PureScript.Constants as C
68import qualified Paths_purescript as Paths
70-- |
71-- Compile a collection of modules
72--
73-- The compilation pipeline proceeds as follows:
74--
75-- * Sort the modules based on module dependencies, checking for cyclic dependencies.
76--
77-- * Perform a set of desugaring passes.
78--
79-- * Type check, and elaborate values to include type annotations and type class dictionaries.
80--
81-- * Regroup values to take into account new value dependencies introduced by elaboration.
82--
83-- * Eliminate dead code.
84--
85-- * Generate Javascript, and perform optimization passes.
86--
87-- * Pretty-print the generated Javascript
88--
89compile :: (Functor m, Applicative m, MonadError MultipleErrors m, MonadWriter MultipleErrors m, MonadReader (Options Compile) m)
90 => [Module] -> m ([CoreFn.Module CoreFn.Ann], String, Environment, Integer)
91compile = compile' initEnvironment
93compile' :: (Functor m, Applicative m, MonadError MultipleErrors m, MonadWriter MultipleErrors m, MonadReader (Options Compile) m)
94 => Environment -> [Module] -> m ([CoreFn.Module CoreFn.Ann], String, Environment, Integer)
95compile' env ms = do
96 noPrelude <- asks optionsNoPrelude
97 unless noPrelude (checkPreludeIsDefined ms)
98 additional <- asks optionsAdditional
99 mainModuleIdent <- asks (fmap moduleNameFromString . optionsMain)
100 (sorted, _) <- sortModules $ map importPrim $ if noPrelude then ms else map importPrelude ms
101 mapM_ lint sorted
102 (desugared, nextVar) <- runSupplyT 0 $ desugar sorted
103 (elaborated, env') <- runCheck' env $ forM desugared $ typeCheckModule mainModuleIdent
104 regrouped <- createBindingGroupsModule . collapseBindingGroupsModule $ elaborated
105 let corefn = map (CoreFn.moduleToCoreFn env') regrouped
106 entryPoints = moduleNameFromString `map` entryPointModules additional
107 elim = if null entryPoints then corefn else eliminateDeadCode entryPoints corefn
108 renamed = renameInModules elim
109 codeGenModuleNames = moduleNameFromString `map` codeGenModules additional
110 modulesToCodeGen = if null codeGenModuleNames then renamed else filter (\(CoreFn.Module _ mn _ _ _ _) -> mn `elem` codeGenModuleNames) renamed
111 let exts = intercalate "\n" . map (`moduleToPs` env') $ regrouped
112 return (modulesToCodeGen, exts, env', nextVar)
114-- |
115-- A type class which collects the IO actions we need to be able to run in "make" mode
116--
117--class (MonadReader (P.Options P.Make) m, MonadError MultipleErrors m, MonadWriter MultipleErrors m) => MonadMake m where
118-- -- |
119-- -- Get a file timestamp
120-- --
121-- getTimestamp :: FilePath -> m (Maybe UTCTime)
123-- -- |
124-- -- Read a file as a string
125-- --
126-- readTextFile :: FilePath -> m String
128-- -- |
129-- -- Write a text file
130-- --
131-- writeTextFile :: FilePath -> String -> m ()
133-- -- |
134-- -- Respond to a progress update
135-- --
136-- progress :: String -> m ()
138data MakeActions m = MakeActions
139 { getInputTimestamp :: ModuleName -> m (Either RebuildPolicy (Maybe UTCTime))
140 , getOutputTimestamp :: ModuleName -> m (Maybe UTCTime)
141 , readExterns :: ModuleName -> m (FilePath, String)
142 , codegen :: CoreFn.Module CoreFn.Ann -> String -> Environment -> Integer -> m ()
143 , progress :: String -> m ()
144 }
146-- |
147-- Determines when to rebuild a module
148--
149data RebuildPolicy
150 -- | Never rebuild this module
151 = RebuildNever
152 -- | Always rebuild this module
153 | RebuildAlways deriving (Show, Eq, Ord)
155-- |
156-- Compiles in "make" mode, compiling each module separately to a js files and an externs file
157--
158-- If timestamps have not changed, the externs file can be used to provide the module's types without
159-- having to typecheck the module again.
160--
161make :: forall m. (Functor m, Applicative m, Monad m, MonadReader (P.Options P.Make) m, MonadError MultipleErrors m, MonadWriter MultipleErrors m)
162 => MakeActions m
163 -> [(Either RebuildPolicy FilePath, Module)]
164 -> m Environment
165make MakeActions{..} ms = do
166 noPrelude <- asks optionsNoPrelude
167 unless noPrelude (checkPreludeIsDefined (map snd ms))
168 (sorted, graph) <- sortModules $ map importPrim $ if noPrelude then map snd ms else map (importPrelude . snd) ms
169 mapM_ lint sorted
170 toRebuild <- foldM (\s (Module _ moduleName' _ _) -> do
171 inputTimestamp <- getInputTimestamp moduleName'
172 outputTimestamp <- getOutputTimestamp moduleName'
173 return $ case (inputTimestamp, outputTimestamp) of
174 (Right (Just t1), Just t2) | t1 < t2 -> s
175 (Left RebuildNever, Just _) -> s
176 _ -> S.insert moduleName' s) S.empty sorted
178 marked <- rebuildIfNecessary (reverseDependencies graph) toRebuild sorted
179 (desugared, nextVar) <- runSupplyT 0 $ zip (map fst marked) <$> desugar (map snd marked)
180 evalSupplyT nextVar $ go initEnvironment desugared
181 where
183 go :: Environment -> [(Bool, Module)] -> SupplyT m Environment
184 go env [] = return env
185 go env ((False, m) : ms') = do
186 (_, env') <- lift . runCheck' env $ typeCheckModule Nothing m
187 go env' ms'
188 go env ((True, m@(Module coms moduleName' _ exps)) : ms') = do
190 lift $ progress $ "Compiling " ++ runModuleName moduleName'
191 (Module _ _ elaborated _, env') <- lift . runCheck' env $ typeCheckModule Nothing m
192 regrouped <- createBindingGroups moduleName' . collapseBindingGroups $ elaborated
193 let mod' = Module coms moduleName' regrouped exps
194 corefn = CoreFn.moduleToCoreFn env' mod'
195 [renamed] = renameInModules [corefn]
196 let exts = moduleToPs mod' env'
197 nextVar <- fresh
198 lift $ codegen renamed exts env' nextVar
199 go env' ms'
201 rebuildIfNecessary :: M.Map ModuleName [ModuleName] -> S.Set ModuleName -> [Module] -> m [(Bool, Module)]
202 rebuildIfNecessary _ _ [] = return []
203 rebuildIfNecessary graph toRebuild (m@(Module _ moduleName' _ _) : ms') | moduleName' `S.member` toRebuild = do
204 let deps = fromMaybe [] $ moduleName' `M.lookup` graph
205 toRebuild' = toRebuild `S.union` S.fromList deps
206 (:) (True, m) <$> rebuildIfNecessary graph toRebuild' ms'
207 rebuildIfNecessary graph toRebuild (Module _ moduleName' _ _ : ms') = do
208 (path, externs) <- readExterns moduleName'
209 externsModules <- fmap (map snd) . alterErrors $ P.parseModulesFromFiles id [(path, externs)]
210 case externsModules of
211 [m'@(Module _ moduleName'' _ _)] | moduleName'' == moduleName' -> (:) (False, m') <$> rebuildIfNecessary graph toRebuild ms'
212 _ -> throwError . errorMessage . InvalidExternsFile $ path
213 where
214 alterErrors = flip catchError $ \(MultipleErrors errs) ->
215 throwError . MultipleErrors $ flip map errs $ \e -> case e of
216 SimpleErrorWrapper (ErrorParsingModule err) -> SimpleErrorWrapper (ErrorParsingExterns err)
217 _ -> e
219checkPreludeIsDefined :: (MonadWriter MultipleErrors m) => [Module] -> m ()
220checkPreludeIsDefined ms = do
221 let mns = map getModuleName ms
222 unless (preludeModuleName `elem` mns) $
223 tell (errorMessage PreludeNotPresent)
225reverseDependencies :: ModuleGraph -> M.Map ModuleName [ModuleName]
226reverseDependencies g = combine [ (dep, mn) | (mn, deps) <- g, dep <- deps ]
227 where
228 combine :: (Ord a) => [(a, b)] -> M.Map a [b]
229 combine = M.fromList . map ((fst . head) &&& map snd) . groupBy ((==) `on` fst) . sortBy (compare `on` fst)
231-- |
232-- Add an import declaration for a module if it does not already explicitly import it.
233--
234addDefaultImport :: ModuleName -> Module -> Module
235addDefaultImport toImport m@(Module coms mn decls exps) =
236 if isExistingImport `any` decls || mn == toImport then m
237 else Module coms mn (ImportDeclaration toImport Implicit Nothing : decls) exps
238 where
239 isExistingImport (ImportDeclaration mn' _ _) | mn' == toImport = True
240 isExistingImport (PositionedDeclaration _ _ d) = isExistingImport d
241 isExistingImport _ = False
243importPrim :: Module -> Module
244importPrim = addDefaultImport (ModuleName [ProperName C.prim])
246preludeModuleName :: ModuleName
247preludeModuleName = ModuleName [ProperName C.prelude]
249importPrelude :: Module -> Module
250importPrelude = addDefaultImport preludeModuleName
252version :: Version
253version = Paths.version