git.iko.soy/rowtype-yoga/purescript-native
on 9994812 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
161 lines 8.6 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12--
13-----------------------------------------------------------------------------
15{-# LANGUAGE FlexibleInstances #-}
17module Language.PureScript.TypeChecker (
18 module T,
19 typeCheckAll
20) where
22import Language.PureScript.TypeChecker.Monad as T
23import Language.PureScript.TypeChecker.Kinds as T
24import Language.PureScript.TypeChecker.Types as T
25import Language.PureScript.TypeChecker.Synonyms as T
27import Data.Maybe
28import qualified Data.Map as M
29import Control.Monad.State
30import Control.Monad.Error
31import Data.Either (rights, lefts)
33import Language.PureScript.Types
34import Language.PureScript.Names
35import Language.PureScript.Kinds
36import Language.PureScript.Declarations
38typeCheckAll :: ModuleName -> [Declaration] -> Check ()
39typeCheckAll _ [] = return ()
40typeCheckAll moduleName (DataDeclaration name args dctors : rest) = do
41 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
42 env <- getEnv
43 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
44 ctorKind <- kindsOf moduleName (Just name) args (mapMaybe snd dctors)
45 putEnv $ env { types = M.insert (moduleName, name) (ctorKind, Data) (types env) }
46 forM_ dctors $ \(dctor, maybeTy) ->
47 rethrow (("Error in data constructor " ++ show name ++ ":\n") ++) $ do
48 env' <- getEnv
49 guardWith (show dctor ++ " is already defined") $ not $ M.member (moduleName, dctor) (dataConstructors env')
50 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
51 let dctorTy = maybe retTy (\ty -> Function [ty] retTy) maybeTy
52 let polyType = mkForAll args dctorTy
53 putEnv $ env' { dataConstructors = M.insert (moduleName, dctor) polyType (dataConstructors env') }
54 typeCheckAll moduleName rest
55typeCheckAll moduleName (DataBindingGroupDeclaration tys : rest) = error (show tys)
56typeCheckAll moduleName (TypeSynonymDeclaration name args ty : rest) = do
57 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
58 env <- getEnv
59 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
60 kind <- kindsOf moduleName (Just name) args [ty]
61 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env)
62 , typeSynonyms = M.insert (moduleName, name) (args, ty) (typeSynonyms env) }
63 typeCheckAll moduleName rest
64typeCheckAll _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
65typeCheckAll moduleName (ValueDeclaration name [] Nothing val : rest) = do
66 rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
67 env <- getEnv
68 case M.lookup (moduleName, name) (names env) of
69 Just _ -> throwError $ show name ++ " is already defined"
70 Nothing -> do
71 [ty] <- typesOf moduleName [(name, val)]
72 putEnv (env { names = M.insert (moduleName, name) (ty, Value) (names env) })
73 typeCheckAll moduleName rest
74typeCheckAll _ (ValueDeclaration _ _ _ _ : _) = error "Binders were not desugared"
75typeCheckAll moduleName (BindingGroupDeclaration vals : rest) = do
76 rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
77 forM_ (map fst vals) $ \name -> do
78 env <- getEnv
79 case M.lookup (moduleName, name) (names env) of
80 Just _ -> throwError $ show name ++ " is already defined"
81 Nothing -> return ()
82 tys <- typesOf moduleName vals
83 forM (zip (map fst vals) tys) $ \(name, ty) ->
84 modifyEnv $ \env -> env { names = M.insert (moduleName, name) (ty, Value) (names env) }
85 typeCheckAll moduleName rest
86typeCheckAll moduleName (ExternDataDeclaration name kind : rest) = do
87 env <- getEnv
88 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
89 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env) }
90 typeCheckAll moduleName rest
91typeCheckAll moduleName (ExternMemberDeclaration member name ty : rest) = do
92 rethrow (("Error in foreign import member declaration " ++ show name ++ ":\n") ++) $ do
93 env <- getEnv
94 kind <- kindOf moduleName ty
95 guardWith "Expected kind *" $ kind == Star
96 case M.lookup (moduleName, name) (names env) of
97 Just _ -> throwError $ show name ++ " is already defined"
98 Nothing -> case ty of
99 _ | isSingleArgumentFunction ty -> do
100 putEnv (env { names = M.insert (moduleName, name) (ty, Extern) (names env)
101 , members = M.insert (moduleName, name) member (members env) })
102 | otherwise -> throwError "Foreign member declarations must have function types, with an single argument."
103 typeCheckAll moduleName rest
104 where
105 isSingleArgumentFunction (Function [_] _) = True
106 isSingleArgumentFunction (ForAll _ t) = isSingleArgumentFunction t
107 isSingleArgumentFunction _ = False
108typeCheckAll moduleName (ExternDeclaration name ty : rest) = do
109 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
110 env <- getEnv
111 kind <- kindOf moduleName ty
112 guardWith "Expected kind *" $ kind == Star
113 case M.lookup (moduleName, name) (names env) of
114 Just _ -> throwError $ show name ++ " is already defined"
115 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern) (names env) })
116 typeCheckAll moduleName rest
117typeCheckAll moduleName (FixityDeclaration _ name : rest) = do
118 typeCheckAll moduleName rest
119 env <- getEnv
120 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
121typeCheckAll currentModule (ImportDeclaration moduleName idents : rest) = do
122 env <- getEnv
123 rethrow errorMessage $ do
124 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
125 case idents of
126 Nothing -> do
127 bindIdents (map snd $ filterModule (names env)) env
128 bindTypes (map snd $ filterModule (types env)) env
129 Just idents' -> do
130 bindIdents (lefts idents') env
131 bindTypes (rights idents') env
132 typeCheckAll currentModule rest
133 where errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
134 filterModule = filter ((== moduleName) . fst) . M.keys
135 moduleExists env = not (null (filterModule (names env))) || not (null (filterModule (types env)))
136 bindIdents idents' env =
137 forM_ idents' $ \ident -> do
138 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
139 case (moduleName, ident) `M.lookup` names env of
140 Just (pt, _) -> modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
141 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
142 bindTypes pns env =
143 forM_ pns $ \pn -> do
144 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (currentModule, pn) `M.notMember` types env
145 case (moduleName, pn) `M.lookup` types env of
146 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
147 Just (k, _) -> do
148 modifyEnv (\e -> e { types = M.insert (currentModule, pn) (k, DataAlias moduleName pn) (types e) })
149 let keys = map (snd . fst) . filter (\(_, fn) -> fn `constructs` pn) . M.toList . dataConstructors $ env
150 forM_ keys $ \dctor -> do
151 guardWith (show currentModule ++ "." ++ show dctor ++ " is already defined") $ (currentModule, dctor) `M.notMember` dataConstructors env
152 case (moduleName, dctor) `M.lookup` dataConstructors env of
153 Just ctorTy -> modifyEnv (\e -> e { dataConstructors = M.insert (currentModule, dctor) ctorTy (dataConstructors e) })
154 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
155 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
156 = mn == moduleName && pn' == pn
157 constructs (ForAll _ ty) pn = ty `constructs` pn
158 constructs (Function _ ty) pn = ty `constructs` pn
159 constructs (TypeApp ty _) pn = ty `constructs` pn
160 constructs fn _ = error $ "Invalid arguments to construct" ++ show fn