git.iko.soy/rowtype-yoga/purescript-native
on a64cb50 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/Types.hs
314 lines 10 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.Types
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- Data types for types
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DeriveDataTypeable #-}
18module Language.PureScript.Types where
20import Data.Data
21import Data.List (nub)
23import Control.Monad.Unify
24import Control.Arrow (second)
25import Control.Applicative
26import Control.Monad ((<=<))
28import Language.PureScript.Names
29import Language.PureScript.Kinds
30import Language.PureScript.Traversals
32-- |
33-- An identifier for the scope of a skolem variable
34--
35newtype SkolemScope = SkolemScope { runSkolemScope :: Int } deriving (Show, Eq, Ord, Data, Typeable)
37-- |
38-- The type of types
39--
40data Type
41 -- |
42 -- A unification variable of type Type
43 --
44 = TUnknown Unknown
45 -- |
46 -- A named type variable
47 --
48 | TypeVar String
49 -- |
50 -- A type wildcard, as would appear in a partial type synonym
51 --
52 | TypeWildcard
53 -- |
54 -- A type constructor
55 --
56 | TypeConstructor (Qualified ProperName)
57 -- |
58 -- A type application
59 --
60 | TypeApp Type Type
61 -- |
62 -- A type synonym which is \"saturated\", i.e. fully applied
63 --
64 | SaturatedTypeSynonym (Qualified ProperName) [Type]
65 -- |
66 -- Forall quantifier
67 --
68 | ForAll String Type (Maybe SkolemScope)
69 -- |
70 -- A type with a set of type class constraints
71 --
72 | ConstrainedType [Constraint] Type
73 -- |
74 -- A skolem constant
75 --
76 | Skolem String Int SkolemScope
77 -- |
78 -- An empty row
79 --
80 | REmpty
81 -- |
82 -- A non-empty row
83 --
84 | RCons String Type Type
85 -- |
86 -- A type with a kind annotation
87 --
88 | KindedType Type Kind
89 --
90 -- |
91 -- A placeholder used in pretty printing
92 --
93 | PrettyPrintFunction Type Type
94 -- |
95 -- A placeholder used in pretty printing
96 --
97 | PrettyPrintArray Type
98 -- |
99 -- A placeholder used in pretty printing
100 --
101 | PrettyPrintObject Type
102 -- |
103 -- A placeholder used in pretty printing
104 --
105 | PrettyPrintForAll [String] Type deriving (Show, Eq, Data, Typeable)
107-- |
108-- A typeclass constraint
109--
110type Constraint = (Qualified ProperName, [Type])
112-- |
113-- Convert a row to a list of pairs of labels and types
114--
115rowToList :: Type -> ([(String, Type)], Type)
116rowToList (RCons name ty row) = let (tys, rest) = rowToList row
117 in ((name, ty):tys, rest)
118rowToList r = ([], r)
120-- |
121-- Convert a list of labels and types to a row
122--
123rowFromList :: ([(String, Type)], Type) -> Type
124rowFromList ([], r) = r
125rowFromList ((name, t):ts, r) = RCons name t (rowFromList (ts, r))
127-- |
128-- Check whether a type is a monotype
129--
130isMonoType :: Type -> Bool
131isMonoType ForAll{} = False
132isMonoType _ = True
134-- |
135-- Universally quantify a type
136--
137mkForAll :: [String] -> Type -> Type
138mkForAll args ty = foldl (\t arg -> ForAll arg t Nothing) ty args
140-- |
141-- Replace a type variable, taking into account variable shadowing
142--
143replaceTypeVars :: String -> Type -> Type -> Type
144replaceTypeVars v r = replaceAllTypeVars [(v, r)]
146-- |
147-- Replace named type variables with types
148--
149replaceAllTypeVars :: [(String, Type)] -> Type -> Type
150replaceAllTypeVars = go []
151 where
153 go :: [String] -> [(String, Type)] -> Type -> Type
154 go _ m (TypeVar v) =
155 case v `lookup` m of
156 Just r -> r
157 Nothing -> TypeVar v
158 go bs m (TypeApp t1 t2) = TypeApp (go bs m t1) (go bs m t2)
159 go bs m (SaturatedTypeSynonym name' ts) = SaturatedTypeSynonym name' $ map (go bs m) ts
160 go bs m f@(ForAll v t sco) | v `elem` keys = go bs (filter ((/= v) . fst) m) f
161 | v `elem` usedVars =
162 let v' = genName v (keys ++ bs ++ usedVars)
163 t' = go bs [(v, TypeVar v')] t
164 in ForAll v' (go (v' : bs) m t') sco
165 | otherwise = ForAll v (go (v : bs) m t) sco
166 where
167 keys = map fst m
168 usedVars = concatMap (usedTypeVariables . snd) m
169 go bs m (ConstrainedType cs t) = ConstrainedType (map (second $ map (go bs m)) cs) (go bs m t)
170 go bs m (RCons name' t r) = RCons name' (go bs m t) (go bs m r)
171 go bs m (KindedType t k) = KindedType (go bs m t) k
172 go _ _ ty = ty
174 genName orig inUse = try 0
175 where
176 try :: Integer -> String
177 try n | (orig ++ show n) `elem` inUse = try (n + 1)
178 | otherwise = orig ++ show n
180-- |
181-- Collect all type variables appearing in a type
182--
183usedTypeVariables :: Type -> [String]
184usedTypeVariables = nub . everythingOnTypes (++) go
185 where
186 go (TypeVar v) = [v]
187 go _ = []
189-- |
190-- Collect all free type variables appearing in a type
191--
192freeTypeVariables :: Type -> [String]
193freeTypeVariables = nub . go []
194 where
195 go :: [String] -> Type -> [String]
196 go bound (TypeVar v) | v `notElem` bound = [v]
197 go bound (TypeApp t1 t2) = go bound t1 ++ go bound t2
198 go bound (SaturatedTypeSynonym _ ts) = concatMap (go bound) ts
199 go bound (ForAll v t _) = go (v : bound) t
200 go bound (ConstrainedType cs t) = concatMap (concatMap (go bound) . snd) cs ++ go bound t
201 go bound (RCons _ t r) = go bound t ++ go bound r
202 go bound (KindedType t _) = go bound t
203 go _ _ = []
205-- |
206-- Universally quantify over all type variables appearing free in a type
207--
208quantify :: Type -> Type
209quantify ty = foldr (\arg t -> ForAll arg t Nothing) ty $ freeTypeVariables ty
211-- |
212-- Move all universal quantifiers to the front of a type
213--
214moveQuantifiersToFront :: Type -> Type
215moveQuantifiersToFront = go [] []
216 where
217 go qs cs (ForAll q ty sco) = go ((q, sco) : qs) cs ty
218 go qs cs (ConstrainedType cs' ty) = go qs (cs ++ cs') ty
219 go qs cs ty =
220 let constrained = case cs of
221 [] -> ty
222 cs' -> ConstrainedType cs' ty
223 in case qs of
224 [] -> constrained
225 qs' -> foldl (\ty' (q, sco) -> ForAll q ty' sco) constrained qs'
227-- |
228-- Check if a type contains wildcards
229--
230containsWildcards :: Type -> Bool
231containsWildcards = everythingOnTypes (||) go
232 where
233 go :: Type -> Bool
234 go TypeWildcard = True
235 go _ = False
237--
238-- Traversals
239--
241everywhereOnTypes :: (Type -> Type) -> Type -> Type
242everywhereOnTypes f = go
243 where
244 go (TypeApp t1 t2) = f (TypeApp (go t1) (go t2))
245 go (SaturatedTypeSynonym name tys) = f (SaturatedTypeSynonym name (map go tys))
246 go (ForAll arg ty sco) = f (ForAll arg (go ty) sco)
247 go (ConstrainedType cs ty) = f (ConstrainedType (map (fmap (map go)) cs) (go ty))
248 go (RCons name ty rest) = f (RCons name (go ty) (go rest))
249 go (KindedType ty k) = f (KindedType (go ty) k)
250 go (PrettyPrintFunction t1 t2) = f (PrettyPrintFunction (go t1) (go t2))
251 go (PrettyPrintArray t) = f (PrettyPrintArray (go t))
252 go (PrettyPrintObject t) = f (PrettyPrintObject (go t))
253 go (PrettyPrintForAll args t) = f (PrettyPrintForAll args (go t))
254 go other = f other
256everywhereOnTypesTopDown :: (Type -> Type) -> Type -> Type
257everywhereOnTypesTopDown f = go . f
258 where
259 go (TypeApp t1 t2) = TypeApp (go (f t1)) (go (f t2))
260 go (SaturatedTypeSynonym name tys) = SaturatedTypeSynonym name (map (go . f) tys)
261 go (ForAll arg ty sco) = ForAll arg (go (f ty)) sco
262 go (ConstrainedType cs ty) = ConstrainedType (map (fmap (map (go . f))) cs) (go (f ty))
263 go (RCons name ty rest) = RCons name (go (f ty)) (go (f rest))
264 go (KindedType ty k) = KindedType (go (f ty)) k
265 go (PrettyPrintFunction t1 t2) = PrettyPrintFunction (go (f t1)) (go (f t2))
266 go (PrettyPrintArray t) = PrettyPrintArray (go (f t))
267 go (PrettyPrintObject t) = PrettyPrintObject (go (f t))
268 go (PrettyPrintForAll args t) = PrettyPrintForAll args (go (f t))
269 go other = f other
271everywhereOnTypesM :: (Functor m, Applicative m, Monad m) => (Type -> m Type) -> Type -> m Type
272everywhereOnTypesM f = go
273 where
274 go (TypeApp t1 t2) = (TypeApp <$> go t1 <*> go t2) >>= f
275 go (SaturatedTypeSynonym name tys) = (SaturatedTypeSynonym name <$> mapM go tys) >>= f
276 go (ForAll arg ty sco) = (ForAll arg <$> go ty <*> pure sco) >>= f
277 go (ConstrainedType cs ty) = (ConstrainedType <$> mapM (sndM (mapM go)) cs <*> go ty) >>= f
278 go (RCons name ty rest) = (RCons name <$> go ty <*> go rest) >>= f
279 go (KindedType ty k) = (KindedType <$> go ty <*> pure k) >>= f
280 go (PrettyPrintFunction t1 t2) = (PrettyPrintFunction <$> go t1 <*> go t2) >>= f
281 go (PrettyPrintArray t) = (PrettyPrintArray <$> go t) >>= f
282 go (PrettyPrintObject t) = (PrettyPrintObject <$> go t) >>= f
283 go (PrettyPrintForAll args t) = (PrettyPrintForAll args <$> go t) >>= f
284 go other = f other
286everywhereOnTypesTopDownM :: (Functor m, Applicative m, Monad m) => (Type -> m Type) -> Type -> m Type
287everywhereOnTypesTopDownM f = go <=< f
288 where
289 go (TypeApp t1 t2) = TypeApp <$> (f t1 >>= go) <*> (f t2 >>= go)
290 go (SaturatedTypeSynonym name tys) = SaturatedTypeSynonym name <$> mapM (go <=< f) tys
291 go (ForAll arg ty sco) = ForAll arg <$> (f ty >>= go) <*> pure sco
292 go (ConstrainedType cs ty) = ConstrainedType <$> mapM (sndM (mapM (go <=< f))) cs <*> (f ty >>= go)
293 go (RCons name ty rest) = RCons name <$> (f ty >>= go) <*> (f rest >>= go)
294 go (KindedType ty k) = KindedType <$> (f ty >>= go) <*> pure k
295 go (PrettyPrintFunction t1 t2) = PrettyPrintFunction <$> (f t1 >>= go) <*> (f t2 >>= go)
296 go (PrettyPrintArray t) = PrettyPrintArray <$> (f t >>= go)
297 go (PrettyPrintObject t) = PrettyPrintObject <$> (f t >>= go)
298 go (PrettyPrintForAll args t) = PrettyPrintForAll args <$> (f t >>= go)
299 go other = f other
301everythingOnTypes :: (r -> r -> r) -> (Type -> r) -> Type -> r
302everythingOnTypes (<>) f = go
303 where
304 go t@(TypeApp t1 t2) = f t <> go t1 <> go t2
305 go t@(SaturatedTypeSynonym _ tys) = foldl (<>) (f t) (map go tys)
306 go t@(ForAll _ ty _) = f t <> go ty
307 go t@(ConstrainedType cs ty) = foldl (<>) (f t) (map go $ concatMap snd cs) <> go ty
308 go t@(RCons _ ty rest) = f t <> go ty <> go rest
309 go t@(KindedType ty _) = f t <> go ty
310 go t@(PrettyPrintFunction t1 t2) = f t <> go t1 <> go t2
311 go t@(PrettyPrintArray t1) = f t <> go t1
312 go t@(PrettyPrintObject t1) = f t <> go t1
313 go t@(PrettyPrintForAll _ t1) = f t <> go t1
314 go other = f other