git.iko.soy/rowtype-yoga/purescript-native
on a979da1 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript.hs
252 lines 10 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The main compiler module
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DataKinds #-}
18module Language.PureScript (module P, compile, compile', MonadMake(..), make, preludeFilename) where
20import Language.PureScript.Types as P
21import Language.PureScript.Kinds as P
22import Language.PureScript.Declarations as P
23import Language.PureScript.Names as P
24import Language.PureScript.Parser as P
25import Language.PureScript.CodeGen as P
26import Language.PureScript.CodeGen.Common as P
27import Language.PureScript.TypeChecker as P
28import Language.PureScript.Pretty as P
29import Language.PureScript.Sugar as P
30import Language.PureScript.Options as P
31import Language.PureScript.ModuleDependencies as P
32import Language.PureScript.Environment as P
33import Language.PureScript.Errors as P
34import Language.PureScript.DeadCodeElimination as P
35import Language.PureScript.Supply as P
36import Language.PureScript.Renamer as P
38import qualified Language.PureScript.Constants as C
39import qualified Paths_purescript as Paths
41import Data.List (sortBy, groupBy, intercalate)
42import Data.Time.Clock
43import Data.Function (on)
44import Data.Maybe (fromMaybe)
45import Control.Monad.Error
46import Control.Arrow ((&&&))
47import Control.Applicative
48import qualified Data.Map as M
49import qualified Data.Set as S
51import System.FilePath ((</>), pathSeparator, takeDirectory)
52import System.Directory (getAppUserDataDirectory, doesFileExist)
53import System.Environment (getProgName)
55-- |
56-- Compile a collection of modules
57--
58-- The compilation pipeline proceeds as follows:
59--
60-- * Sort the modules based on module dependencies, checking for cyclic dependencies.
61--
62-- * Perform a set of desugaring passes.
63--
64-- * Type check, and elaborate values to include type annotations and type class dictionaries.
65--
66-- * Regroup values to take into account new value dependencies introduced by elaboration.
67--
68-- * Eliminate dead code.
69--
70-- * Generate Javascript, and perform optimization passes.
71--
72-- * Pretty-print the generated Javascript
73--
74compile :: Options Compile -> [Module] -> [String] -> Either String (String, String, Environment)
75compile = compile' initEnvironment
77compile' :: Environment -> Options Compile -> [Module] -> [String] -> Either String (String, String, Environment)
78compile' env opts ms prefix = do
79 (sorted, _) <- sortModules $ map importPrim $ if optionsNoPrelude opts then ms else (map importPrelude ms)
80 (desugared, nextVar) <- stringifyErrorStack True $ runSupplyT 0 $ desugar sorted
81 (elaborated, env') <- runCheck' opts env $ forM desugared $ typeCheckModule mainModuleIdent
82 regrouped <- stringifyErrorStack True $ createBindingGroupsModule . collapseBindingGroupsModule $ elaborated
83 let entryPoints = moduleNameFromString `map` entryPointModules (optionsAdditional opts)
84 let elim = if null entryPoints then regrouped else eliminateDeadCode entryPoints regrouped
85 let renamed = renameInModules elim
86 let codeGenModuleNames = moduleNameFromString `map` codeGenModules (optionsAdditional opts)
87 let modulesToCodeGen = if null codeGenModuleNames then renamed else filter (\(Module mn _ _) -> mn `elem` codeGenModuleNames) renamed
88 let js = evalSupply nextVar $ concat <$> mapM (\m -> moduleToJs opts m env') modulesToCodeGen
89 let exts = intercalate "\n" . map (`moduleToPs` env') $ modulesToCodeGen
90 js' <- generateMain env' opts js
91 let pjs = unlines $ map ("// " ++) prefix ++ [prettyPrintJS js']
92 return (pjs, exts, env')
93 where
94 mainModuleIdent = moduleNameFromString <$> optionsMain opts
96generateMain :: Environment -> Options Compile -> [JS] -> Either String [JS]
97generateMain env opts js =
98 case moduleNameFromString <$> optionsMain opts of
99 Just mmi -> do
100 when ((mmi, Ident C.main) `M.notMember` names env) $
101 Left $ show mmi ++ "." ++ C.main ++ " is undefined"
102 return $ js ++ [JSApp (JSAccessor C.main (JSAccessor (moduleNameToJs mmi) (JSVar (browserNamespace (optionsAdditional opts))))) []]
103 _ -> return js
105-- |
106-- A type class which collects the IO actions we need to be able to run in "make" mode
107--
108class MonadMake m where
109 -- |
110 -- Get a file timestamp
111 --
112 getTimestamp :: FilePath -> m (Maybe UTCTime)
114 -- |
115 -- Read a file as a string
116 --
117 readTextFile :: FilePath -> m String
119 -- |
120 -- Write a text file
121 --
122 writeTextFile :: FilePath -> String -> m ()
124 -- |
125 -- Report an error
126 --
127 liftError :: Either String a -> m a
129 -- |
130 -- Respond to a progress update
131 --
132 progress :: String -> m ()
134-- |
135-- Compiles in "make" mode, compiling each module separately to a js files and an externs file
136--
137-- If timestamps have not changed, the externs file can be used to provide the module's types without
138-- having to typecheck the module again.
139--
140make :: (Functor m, Applicative m, Monad m, MonadMake m) => FilePath -> Options Make -> [(FilePath, Module)] -> [String] -> m Environment
141make outputDir opts ms prefix = do
142 let filePathMap = M.fromList (map (\(fp, Module mn _ _) -> (mn, fp)) ms)
144 (sorted, graph) <- liftError $ sortModules $ map importPrim $ if optionsNoPrelude opts then map snd ms else (map (importPrelude . snd) ms)
146 toRebuild <- foldM (\s (Module moduleName' _ _) -> do
147 let filePath = runModuleName moduleName'
149 jsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "index.js"
150 externsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "externs.purs"
151 inputFile = fromMaybe (error "Input file is undefined in make") $ M.lookup moduleName' filePathMap
153 jsTimestamp <- getTimestamp jsFile
154 externsTimestamp <- getTimestamp externsFile
155 inputTimestamp <- getTimestamp inputFile
157 return $ case (inputTimestamp, jsTimestamp, externsTimestamp) of
158 (Just t1, Just t2, Just t3) | t1 < min t2 t3 -> s
159 _ -> S.insert moduleName' s) S.empty sorted
161 marked <- rebuildIfNecessary (reverseDependencies graph) toRebuild sorted
163 (desugared, nextVar) <- liftError $ stringifyErrorStack True $ runSupplyT 0 $ zip (map fst marked) <$> desugar (map snd marked)
165 evalSupplyT nextVar (go initEnvironment desugared)
167 where
168 go :: (Functor m, Applicative m, Monad m, MonadMake m) => Environment -> [(Bool, Module)] -> SupplyT m Environment
169 go env [] = return env
170 go env ((False, m) : ms') = do
171 (_, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
173 go env' ms'
174 go env ((True, m@(Module moduleName' _ exps)) : ms') = do
175 let filePath = runModuleName moduleName'
176 jsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "index.js"
177 externsFile = outputDir ++ pathSeparator : filePath ++ pathSeparator : "externs.purs"
179 lift . progress $ "Compiling " ++ runModuleName moduleName'
181 (Module _ elaborated _, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
183 regrouped <- lift . liftError . stringifyErrorStack True . createBindingGroups moduleName' . collapseBindingGroups $ elaborated
185 let mod' = Module moduleName' regrouped exps
186 let [renamed] = renameInModules [mod']
188 pjs <- prettyPrintJS <$> moduleToJs opts renamed env'
189 let js = unlines $ map ("// " ++) prefix ++ [pjs]
190 let exts = unlines $ map ("-- " ++ ) prefix ++ [moduleToPs renamed env']
192 lift $ writeTextFile jsFile js
193 lift $ writeTextFile externsFile exts
195 go env' ms'
197 rebuildIfNecessary :: (Functor m, Monad m, MonadMake m) => M.Map ModuleName [ModuleName] -> S.Set ModuleName -> [Module] -> m [(Bool, Module)]
198 rebuildIfNecessary _ _ [] = return []
199 rebuildIfNecessary graph toRebuild (m@(Module moduleName' _ _) : ms') | moduleName' `S.member` toRebuild = do
200 let deps = fromMaybe [] $ moduleName' `M.lookup` graph
201 toRebuild' = toRebuild `S.union` S.fromList deps
202 (:) (True, m) <$> rebuildIfNecessary graph toRebuild' ms'
203 rebuildIfNecessary graph toRebuild (Module moduleName' _ _ : ms') = do
204 let externsFile = outputDir ++ pathSeparator : runModuleName moduleName' ++ pathSeparator : "externs.purs"
205 externs <- readTextFile externsFile
206 externsModules <- liftError . either (Left . show) Right $ P.runIndentParser externsFile P.parseModules externs
207 case externsModules of
208 [m'@(Module moduleName'' _ _)] | moduleName'' == moduleName' -> (:) (False, m') <$> rebuildIfNecessary graph toRebuild ms'
209 _ -> liftError . Left $ "Externs file " ++ externsFile ++ " was invalid"
211reverseDependencies :: ModuleGraph -> M.Map ModuleName [ModuleName]
212reverseDependencies g = combine [ (dep, mn) | (mn, deps) <- g, dep <- deps ]
213 where
214 combine :: (Ord a) => [(a, b)] -> M.Map a [b]
215 combine = M.fromList . map ((fst . head) &&& map snd) . groupBy ((==) `on` fst) . sortBy (compare `on` fst)
217-- |
218-- Add an import declaration for a module if it does not already explicitly import it.
219--
220addDefaultImport :: ModuleName -> Module -> Module
221addDefaultImport toImport m@(Module mn decls exps) =
222 if isExistingImport `any` decls || mn == toImport then m
223 else Module mn (ImportDeclaration toImport Unqualified Nothing : decls) exps
224 where
225 isExistingImport (ImportDeclaration mn' _ _) | mn' == toImport = True
226 isExistingImport (PositionedDeclaration _ d) = isExistingImport d
227 isExistingImport _ = False
229importPrim :: Module -> Module
230importPrim = addDefaultImport (ModuleName [ProperName C.prim])
232importPrelude :: Module -> Module
233importPrelude = addDefaultImport (ModuleName [ProperName C.prelude])
235preludeFilename :: IO FilePath
236preludeFilename = do
237 fs <- sequence [localPrelude, appPrelude, cabalPrelude]
238 es <- filterM doesFileExist fs
239 case es of
240 (x : _) -> return x
241 _ -> error "No Prelude found."
242 where
243 localPrelude :: IO FilePath
244 localPrelude = ((</> "prelude.purs") . takeDirectory) <$> getProgName
246 appPrelude :: IO FilePath
247 appPrelude = do
248 appDir <- getAppUserDataDirectory "purescript"
249 return $ appDir </> "prelude" </> "prelude.purs"
251 cabalPrelude :: IO FilePath
252 cabalPrelude = Paths.getDataFileName "prelude/prelude.purs"