git.iko.soy/rowtype-yoga/purescript-native
on aabb9d3 help sign in
rowtype-yoga/purescript-native/src/PureScript/Parser/Values.hs
235 lines 11 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : PureScript.Parser.Values
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12--
13-----------------------------------------------------------------------------
15module PureScript.Parser.Values (
16 parseValue,
17 parseBinder
18) where
20import PureScript.Values
21import qualified PureScript.Parser.Common as C
22import Control.Applicative
23import qualified Text.Parsec as P
24import Text.Parsec.Expr
25import Control.Monad
26import Control.Arrow (Arrow(..))
27import PureScript.Parser.Types
28import PureScript.Types
30booleanLiteral :: P.Parsec String P.Column Bool
31booleanLiteral = (C.reserved "true" >> return True) P.<|> (C.reserved "false" >> return False)
33parseNumericLiteral :: P.Parsec String P.Column Value
34parseNumericLiteral = NumericLiteral <$> C.integerOrFloat
36parseStringLiteral :: P.Parsec String P.Column Value
37parseStringLiteral = StringLiteral <$> C.stringLiteral
39parseBooleanLiteral :: P.Parsec String P.Column Value
40parseBooleanLiteral = BooleanLiteral <$> booleanLiteral
42parseArrayLiteral :: P.Parsec String P.Column Value
43parseArrayLiteral = ArrayLiteral <$> (C.squares $ parseValue `P.sepBy` (C.indented *> C.comma))
45parseObjectLiteral :: P.Parsec String P.Column Value
46parseObjectLiteral = ObjectLiteral <$> (C.braces $ parseIdentifierAndValue `P.sepBy` (C.indented *> C.comma))
48parseIdentifierAndValue :: P.Parsec String P.Column (String, Value)
49parseIdentifierAndValue = (,) <$> (C.indented *> C.identifier <* C.indented <* C.colon)
50 <*> (C.indented *> parseValue)
52parseAbs :: P.Parsec String P.Column Value
53parseAbs = do
54 C.lexeme $ P.char '\\'
55 args <- (C.indented *> C.parseIdent) `P.sepBy` (C.indented *> C.comma)
56 C.lexeme $ C.indented *> P.string "->"
57 value <- parseValue
58 return $ Abs args value
60parseApp :: P.Parsec String P.Column Value
61parseApp = App <$> parseValue
62 <*> (C.indented *> C.parens (parseValue `P.sepBy` (C.indented *> C.comma)))
64parseVar :: P.Parsec String P.Column Value
65parseVar = Var <$> C.parseIdent
67parseConstructor :: P.Parsec String P.Column Value
68parseConstructor = Constructor <$> C.properName
70parseCase :: P.Parsec String P.Column Value
71parseCase = Case <$> (P.between (C.reserved "case") (C.indented *> C.reserved "of") parseValue)
72 <*> (C.indented *> C.mark (P.many (C.same *> C.mark parseCaseAlternative)))
74parseCaseAlternative :: P.Parsec String P.Column (Binder, Value)
75parseCaseAlternative = (,) <$> (parseBinder <* C.lexeme (P.string "->")) <*> parseValue
77parseBlock :: P.Parsec String P.Column Value
78parseBlock = Block <$> (C.reserved "do" *> parseManyStatements)
80parseManyStatements :: P.Parsec String P.Column [Statement]
81parseManyStatements = C.indented *> (C.mark $ P.many $ C.same *> C.mark parseStatement)
83parseValueAtom :: P.Parsec String P.Column Value
84parseValueAtom = C.indented *> P.choice (map P.try
85 [ parseNumericLiteral
86 , parseStringLiteral
87 , parseBooleanLiteral
88 , parseArrayLiteral
89 , parseObjectLiteral
90 , parseAbs
91 , parseVar
92 , parseConstructor
93 , parseBlock
94 , parseCase
95 , C.parens parseValue ])
97parseValue :: P.Parsec String P.Column Value
98parseValue = buildExpressionParser operators $ C.fold (C.lexeme typedValue) (C.lexeme funArgs) App
99 where
100 typedValue = C.augment parseValueAtom parseTypeAnnotation TypedValue
101 funArgs = C.indented *> C.parens (parseValue `P.sepBy` (C.indented *> C.comma))
102 parseTypeAnnotation = P.try $ C.lexeme (C.indented *> P.string "::") *> parsePolyType
103 operators = [ [ Postfix $ Accessor <$> (C.indented *> C.dot *> C.indented *> C.identifier)
104 , Postfix $ Indexer <$> (C.indented *> C.squares parseValue) ]
105 , [ Prefix $ C.lexeme (P.try $ C.indented *> C.reservedOp "!") >> return (Unary Not)
106 , Prefix $ C.lexeme (P.try $ C.indented *> C.reservedOp "~") >> return (Unary BitwiseNot)
107 , Prefix $ C.lexeme (P.try $ C.indented *> C.reservedOp "-") >> return (Unary Negate) ]
108 , [ Infix (C.lexeme (P.try (C.indented *> C.parseIdentInfix) >>= \ident -> return $ \t1 t2 -> App (App (Var ident) [t1]) [t2])) AssocRight ]
109 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "<=") >> return (Binary LessThanOrEqualTo)) AssocRight
110 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">=") >> return (Binary GreaterThanOrEqualTo)) AssocRight ]
111 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "<") >> return (Binary LessThan)) AssocRight
112 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">") >> return (Binary GreaterThan)) AssocRight ]
113 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "*") >> return (Binary Multiply)) AssocRight
114 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "/") >> return (Binary Divide)) AssocRight
115 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "%") >> return (Binary Modulus)) AssocRight ]
116 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "++") >> return (Binary Concat)) AssocRight
117 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "+") >> return (Binary Add)) AssocRight
118 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "-") >> return (Binary Subtract)) AssocRight ]
119 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "<<") >> return (Binary ShiftLeft)) AssocRight
120 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">>>") >> return (Binary ZeroFillShiftRight)) AssocRight
121 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">>") >> return (Binary ShiftRight)) AssocRight ]
122 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "==") >> return (Binary EqualTo)) AssocRight
123 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "!=") >> return (Binary NotEqualTo)) AssocRight ]
124 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "&") >> return (Binary BitwiseAnd)) AssocRight ]
125 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "^") >> return (Binary BitwiseXor)) AssocRight ]
126 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "|") >> return (Binary BitwiseOr)) AssocRight ]
127 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "&&") >> return (Binary And)) AssocRight ]
128 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "||") >> return (Binary Or)) AssocRight ]
129 ]
131parseVariableIntroduction :: P.Parsec String P.Column Statement
132parseVariableIntroduction = do
133 C.reserved "var"
134 name <- C.indented *> C.parseIdent
135 C.lexeme $ C.indented *> P.char '='
136 value <- parseValue
137 return $ VariableIntroduction name value
139parseAssignment :: P.Parsec String P.Column Statement
140parseAssignment = do
141 tgt <- parseAssignmentTarget
142 C.lexeme $ C.indented *> P.char '='
143 value <- parseValue
144 return $ Assignment tgt value
146parseWhile :: P.Parsec String P.Column Statement
147parseWhile = While <$> (C.reserved "while" *> C.indented *> parseValue <* C.indented <* C.colon)
148 <*> parseManyStatements
150parseFor :: P.Parsec String P.Column Statement
151parseFor = For <$> (C.reserved "for" *> C.indented *> C.parseIdent)
152 <*> (C.indented *> C.lexeme (P.string "<-") *> parseValue)
153 <*> (C.indented *> C.reserved "until" *> parseValue <* C.colon)
154 <*> parseManyStatements
156parseForEach :: P.Parsec String P.Column Statement
157parseForEach = ForEach <$> (C.reserved "foreach" *> C.indented *> C.parseIdent)
158 <*> (C.indented *> C.reserved "in" *> parseValue <* C.colon)
159 <*> parseManyStatements
161parseIf :: P.Parsec String P.Column Statement
162parseIf = If <$> parseIfStatement
164parseIfStatement :: P.Parsec String P.Column IfStatement
165parseIfStatement =
166 IfStatement <$> (C.reserved "if" *> C.indented *> parseValue <* C.indented <* C.colon)
167 <*> parseManyStatements
168 <*> P.optionMaybe (C.same *> parseElseStatement)
170parseElseStatement :: P.Parsec String P.Column ElseStatement
171parseElseStatement = C.reserved "else" >> (ElseIf <$> (C.indented *> parseIfStatement)
172 <|> Else <$> (C.indented *> C.colon *> parseManyStatements))
174parseReturn :: P.Parsec String P.Column Statement
175parseReturn = Return <$> (C.reserved "return" *> parseValue)
177parseStatement :: P.Parsec String P.Column Statement
178parseStatement = P.choice (map P.try
179 [ parseVariableIntroduction
180 , parseAssignment
181 , parseWhile
182 , parseFor
183 , parseForEach
184 , parseIf
185 , parseReturn ])
187parseStringBinder :: P.Parsec String P.Column Binder
188parseStringBinder = StringBinder <$> C.stringLiteral
190parseBooleanBinder :: P.Parsec String P.Column Binder
191parseBooleanBinder = BooleanBinder <$> booleanLiteral
193parseNumberBinder :: P.Parsec String P.Column Binder
194parseNumberBinder = NumberBinder <$> C.integerOrFloat
196parseVarBinder :: P.Parsec String P.Column Binder
197parseVarBinder = VarBinder <$> C.parseIdent
199parseNullaryBinder :: P.Parsec String P.Column Binder
200parseNullaryBinder = NullaryBinder <$> C.lexeme C.properName
202parseUnaryBinder :: P.Parsec String P.Column Binder
203parseUnaryBinder = UnaryBinder <$> C.lexeme C.properName <*> (C.indented *> parseBinder)
205parseObjectBinder :: P.Parsec String P.Column Binder
206parseObjectBinder = ObjectBinder <$> C.braces ((C.indented *> parseIdentifierAndBinder) `P.sepBy` (C.indented *> C.comma))
208parseArrayBinder :: P.Parsec String P.Column Binder
209parseArrayBinder = C.squares $ ArrayBinder <$> ((C.indented *> parseBinder) `P.sepBy` (C.indented *> C.comma))
210 <*> P.optionMaybe (C.indented *> C.colon *> C.indented *> parseBinder)
212parseIdentifierAndBinder :: P.Parsec String P.Column (String, Binder)
213parseIdentifierAndBinder = do
214 name <- C.lexeme C.identifier
215 C.lexeme $ C.indented *> P.char '='
216 binder <- C.indented *> parseBinder
217 return (name, binder)
219parseBinder :: P.Parsec String P.Column Binder
220parseBinder = P.choice (map P.try
221 [ parseStringBinder
222 , parseBooleanBinder
223 , parseNumberBinder
224 , parseVarBinder
225 , parseUnaryBinder
226 , parseNullaryBinder
227 , parseObjectBinder
228 , parseArrayBinder
229 , C.parens parseBinder ])
231parseAssignmentTarget :: P.Parsec String P.Column AssignmentTarget
232parseAssignmentTarget = buildExpressionParser operators (AssignVariable <$> C.parseIdent)
233 where
234 operators = [ [ Postfix $ AssignArrayIndex <$> (C.indented *> C.squares parseValue)
235 , Postfix $ AssignObjectProperty <$> (C.indented *> C.dot *> C.indented *> C.identifier) ] ]