git.iko.soy/rowtype-yoga/purescript-native
on aae5678 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript.hs
252 lines 10 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The main compiler module
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DataKinds, QuasiQuotes, TemplateHaskell #-}
18module Language.PureScript (module P, compile, compile', RebuildPolicy(..), MonadMake(..), make, prelude) where
20import Language.PureScript.Types as P
21import Language.PureScript.Kinds as P
22import Language.PureScript.AST as P
23import Language.PureScript.Names as P
24import Language.PureScript.Parser as P
25import Language.PureScript.CodeGen as P
26import Language.PureScript.CodeGen.Common as P
27import Language.PureScript.TypeChecker as P
28import Language.PureScript.Pretty as P
29import Language.PureScript.Sugar as P
30import Language.PureScript.Options as P
31import Language.PureScript.ModuleDependencies as P
32import Language.PureScript.Environment as P
33import Language.PureScript.Errors as P
34import Language.PureScript.DeadCodeElimination as P
35import Language.PureScript.Supply as P
36import Language.PureScript.Renamer as P
38import qualified Language.PureScript.Constants as C
40import Data.List (sortBy, groupBy, intercalate)
41import Data.Time.Clock
42import Data.Function (on)
43import Data.Maybe (fromMaybe)
44import Data.FileEmbed (embedFile)
46import Control.Monad.Error
47import Control.Arrow ((&&&))
48import Control.Applicative
50import qualified Data.Map as M
51import qualified Data.Set as S
52import qualified Data.ByteString.UTF8 as BU
54import System.FilePath ((</>))
56-- |
57-- Compile a collection of modules
58--
59-- The compilation pipeline proceeds as follows:
60--
61-- * Sort the modules based on module dependencies, checking for cyclic dependencies.
62--
63-- * Perform a set of desugaring passes.
64--
65-- * Type check, and elaborate values to include type annotations and type class dictionaries.
66--
67-- * Regroup values to take into account new value dependencies introduced by elaboration.
68--
69-- * Eliminate dead code.
70--
71-- * Generate Javascript, and perform optimization passes.
72--
73-- * Pretty-print the generated Javascript
74--
75compile :: Options Compile -> [Module] -> [String] -> Either String (String, String, Environment)
76compile = compile' initEnvironment
78compile' :: Environment -> Options Compile -> [Module] -> [String] -> Either String (String, String, Environment)
79compile' env opts ms prefix = do
80 (sorted, _) <- sortModules $ map importPrim $ if optionsNoPrelude opts then ms else (map importPrelude ms)
81 (desugared, nextVar) <- stringifyErrorStack True $ runSupplyT 0 $ desugar sorted
82 (elaborated, env') <- runCheck' opts env $ forM desugared $ typeCheckModule mainModuleIdent
83 regrouped <- stringifyErrorStack True $ createBindingGroupsModule . collapseBindingGroupsModule $ elaborated
84 let entryPoints = moduleNameFromString `map` entryPointModules (optionsAdditional opts)
85 let elim = if null entryPoints then regrouped else eliminateDeadCode entryPoints regrouped
86 let renamed = renameInModules elim
87 let codeGenModuleNames = moduleNameFromString `map` codeGenModules (optionsAdditional opts)
88 let modulesToCodeGen = if null codeGenModuleNames then renamed else filter (\(Module mn _ _) -> mn `elem` codeGenModuleNames) renamed
89 let js = evalSupply nextVar $ concat <$> mapM (\m -> moduleToJs opts m env') modulesToCodeGen
90 let exts = intercalate "\n" . map (`moduleToPs` env') $ modulesToCodeGen
91 js' <- generateMain env' opts js
92 let pjs = unlines $ map ("// " ++) prefix ++ [prettyPrintJS js']
93 return (pjs, exts, env')
94 where
95 mainModuleIdent = moduleNameFromString <$> optionsMain opts
97generateMain :: Environment -> Options Compile -> [JS] -> Either String [JS]
98generateMain env opts js =
99 case moduleNameFromString <$> optionsMain opts of
100 Just mmi -> do
101 when ((mmi, Ident C.main) `M.notMember` names env) $
102 Left $ show mmi ++ "." ++ C.main ++ " is undefined"
103 return $ js ++ [JSApp (JSAccessor C.main (JSAccessor (moduleNameToJs mmi) (JSVar (browserNamespace (optionsAdditional opts))))) []]
104 _ -> return js
106-- |
107-- A type class which collects the IO actions we need to be able to run in "make" mode
108--
109class MonadMake m where
110 -- |
111 -- Get a file timestamp
112 --
113 getTimestamp :: FilePath -> m (Maybe UTCTime)
115 -- |
116 -- Read a file as a string
117 --
118 readTextFile :: FilePath -> m String
120 -- |
121 -- Write a text file
122 --
123 writeTextFile :: FilePath -> String -> m ()
125 -- |
126 -- Report an error
127 --
128 liftError :: Either String a -> m a
130 -- |
131 -- Respond to a progress update
132 --
133 progress :: String -> m ()
135-- |
136-- Determines when to rebuild a module
137--
138data RebuildPolicy
139 -- | Never rebuild this module
140 = RebuildNever
141 -- | Always rebuild this module
142 | RebuildAlways deriving (Show, Eq, Ord)
144-- Traverse (Either e) instance (base 4.7)
145traverseEither :: Applicative f => (a -> f b) -> Either e a -> f (Either e b)
146traverseEither _ (Left x) = pure (Left x)
147traverseEither f (Right y) = Right <$> f y
149-- |
150-- Compiles in "make" mode, compiling each module separately to a js files and an externs file
151--
152-- If timestamps have not changed, the externs file can be used to provide the module's types without
153-- having to typecheck the module again.
154--
155make :: (Functor m, Applicative m, Monad m, MonadMake m) => FilePath -> Options Make -> [(Either RebuildPolicy FilePath, Module)] -> [String] -> m Environment
156make outputDir opts ms prefix = do
157 let filePathMap = M.fromList (map (\(fp, Module mn _ _) -> (mn, fp)) ms)
159 (sorted, graph) <- liftError $ sortModules $ map importPrim $ if optionsNoPrelude opts then map snd ms else (map (importPrelude . snd) ms)
161 toRebuild <- foldM (\s (Module moduleName' _ _) -> do
162 let filePath = runModuleName moduleName'
164 jsFile = outputDir </> filePath </> "index.js"
165 externsFile = outputDir </> filePath </> "externs.purs"
166 inputFile = fromMaybe (error "Module has no filename in 'make'") $ M.lookup moduleName' filePathMap
168 jsTimestamp <- getTimestamp jsFile
169 externsTimestamp <- getTimestamp externsFile
170 inputTimestamp <- traverseEither getTimestamp inputFile
172 return $ case (inputTimestamp, jsTimestamp, externsTimestamp) of
173 (Right (Just t1), Just t2, Just t3) | t1 < min t2 t3 -> s
174 (Left RebuildNever, Just _, Just _) -> s
175 _ -> S.insert moduleName' s) S.empty sorted
177 marked <- rebuildIfNecessary (reverseDependencies graph) toRebuild sorted
179 (desugared, nextVar) <- liftError $ stringifyErrorStack True $ runSupplyT 0 $ zip (map fst marked) <$> desugar (map snd marked)
181 evalSupplyT nextVar (go initEnvironment desugared)
183 where
184 go :: (Functor m, Applicative m, Monad m, MonadMake m) => Environment -> [(Bool, Module)] -> SupplyT m Environment
185 go env [] = return env
186 go env ((False, m) : ms') = do
187 (_, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
189 go env' ms'
190 go env ((True, m@(Module moduleName' _ exps)) : ms') = do
191 let filePath = runModuleName moduleName'
192 jsFile = outputDir </> filePath </> "index.js"
193 externsFile = outputDir </> filePath </> "externs.purs"
195 lift . progress $ "Compiling " ++ runModuleName moduleName'
197 (Module _ elaborated _, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
199 regrouped <- lift . liftError . stringifyErrorStack True . createBindingGroups moduleName' . collapseBindingGroups $ elaborated
201 let mod' = Module moduleName' regrouped exps
202 let [renamed] = renameInModules [mod']
204 pjs <- prettyPrintJS <$> moduleToJs opts renamed env'
205 let js = unlines $ map ("// " ++) prefix ++ [pjs]
206 let exts = unlines $ map ("-- " ++ ) prefix ++ [moduleToPs renamed env']
208 lift $ writeTextFile jsFile js
209 lift $ writeTextFile externsFile exts
211 go env' ms'
213 rebuildIfNecessary :: (Functor m, Monad m, MonadMake m) => M.Map ModuleName [ModuleName] -> S.Set ModuleName -> [Module] -> m [(Bool, Module)]
214 rebuildIfNecessary _ _ [] = return []
215 rebuildIfNecessary graph toRebuild (m@(Module moduleName' _ _) : ms') | moduleName' `S.member` toRebuild = do
216 let deps = fromMaybe [] $ moduleName' `M.lookup` graph
217 toRebuild' = toRebuild `S.union` S.fromList deps
218 (:) (True, m) <$> rebuildIfNecessary graph toRebuild' ms'
219 rebuildIfNecessary graph toRebuild (Module moduleName' _ _ : ms') = do
220 let externsFile = outputDir </> runModuleName moduleName' </> "externs.purs"
221 externs <- readTextFile externsFile
222 externsModules <- liftError . either (Left . show) Right $ P.runIndentParser externsFile P.parseModules externs
223 case externsModules of
224 [m'@(Module moduleName'' _ _)] | moduleName'' == moduleName' -> (:) (False, m') <$> rebuildIfNecessary graph toRebuild ms'
225 _ -> liftError . Left $ "Externs file " ++ externsFile ++ " was invalid"
227reverseDependencies :: ModuleGraph -> M.Map ModuleName [ModuleName]
228reverseDependencies g = combine [ (dep, mn) | (mn, deps) <- g, dep <- deps ]
229 where
230 combine :: (Ord a) => [(a, b)] -> M.Map a [b]
231 combine = M.fromList . map ((fst . head) &&& map snd) . groupBy ((==) `on` fst) . sortBy (compare `on` fst)
233-- |
234-- Add an import declaration for a module if it does not already explicitly import it.
235--
236addDefaultImport :: ModuleName -> Module -> Module
237addDefaultImport toImport m@(Module mn decls exps) =
238 if isExistingImport `any` decls || mn == toImport then m
239 else Module mn (ImportDeclaration toImport Unqualified Nothing : decls) exps
240 where
241 isExistingImport (ImportDeclaration mn' _ _) | mn' == toImport = True
242 isExistingImport (PositionedDeclaration _ d) = isExistingImport d
243 isExistingImport _ = False
245importPrim :: Module -> Module
246importPrim = addDefaultImport (ModuleName [ProperName C.prim])
248importPrelude :: Module -> Module
249importPrelude = addDefaultImport (ModuleName [ProperName C.prelude])
251prelude :: String
252prelude = BU.toString $(embedFile "prelude/prelude.purs")