git.iko.soy/rowtype-yoga/purescript-native
on bf0e439 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
206 lines 10 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12--
13-----------------------------------------------------------------------------
15{-# LANGUAGE FlexibleInstances #-}
17module Language.PureScript.TypeChecker (
18 module T,
19 typeCheckAll
20) where
22import Language.PureScript.TypeChecker.Monad as T
23import Language.PureScript.TypeChecker.Kinds as T
24import Language.PureScript.TypeChecker.Types as T
25import Language.PureScript.TypeChecker.Synonyms as T
27import Data.Maybe
28import qualified Data.Map as M
29import Control.Monad.State
30import Control.Monad.Error
31import Data.Either (rights, lefts)
33import Language.PureScript.Types
34import Language.PureScript.Names
35import Language.PureScript.Kinds
36import Language.PureScript.Declarations
37import Language.PureScript.Sugar.TypeClasses
39addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, Maybe Type)] -> Kind -> Check ()
40addDataType moduleName name args dctors ctorKind = do
41 env <- getEnv
42 putEnv $ env { types = M.insert (moduleName, name) (ctorKind, Data) (types env) }
43 forM_ dctors $ \(dctor, maybeTy) ->
44 rethrow (("Error in data constructor " ++ show name ++ ":\n") ++) $
45 addDataConstructor moduleName name args dctor maybeTy
47addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> Maybe Type -> Check ()
48addDataConstructor moduleName name args dctor maybeTy = do
49 env <- getEnv
50 dataConstructorIsNotDefined moduleName dctor
51 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
52 let dctorTy = maybe retTy (\ty -> Function [ty] retTy) maybeTy
53 let polyType = mkForAll args dctorTy
54 putEnv $ env { dataConstructors = M.insert (moduleName, dctor) (qualifyAllUnqualifiedNames moduleName env polyType, DataConstructor) (dataConstructors env) }
56addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
57addTypeSynonym moduleName name args ty kind = do
58 env <- getEnv
59 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env)
60 , typeSynonyms = M.insert (moduleName, name) (args, qualifyAllUnqualifiedNames moduleName env ty) (typeSynonyms env) }
62typeIsNotDefined :: ModuleName -> ProperName -> Check ()
63typeIsNotDefined moduleName name = do
64 env <- getEnv
65 guardWith (show name ++ " is already defined") $
66 not $ M.member (moduleName, name) (types env)
68dataConstructorIsNotDefined :: ModuleName -> ProperName -> Check ()
69dataConstructorIsNotDefined moduleName dctor = do
70 env <- getEnv
71 guardWith (show dctor ++ " is already defined") $
72 not $ M.member (moduleName, dctor) (dataConstructors env)
74valueIsNotDefined :: ModuleName -> Ident -> Check ()
75valueIsNotDefined moduleName name = do
76 env <- getEnv
77 case M.lookup (moduleName, name) (names env) of
78 Just _ -> throwError $ show name ++ " is already defined"
79 Nothing -> return ()
81addValue :: ModuleName -> Ident -> Type -> Check ()
82addValue moduleName name ty = do
83 env <- getEnv
84 putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Value) (names env) })
86typeCheckAll :: ModuleName -> [Declaration] -> Check [Declaration]
87typeCheckAll _ [] = return []
88typeCheckAll moduleName (d@(DataDeclaration name args dctors) : rest) = do
89 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
90 typeIsNotDefined moduleName name
91 ctorKind <- kindsOf moduleName name args (mapMaybe snd dctors)
92 addDataType moduleName name args dctors ctorKind
93 ds <- typeCheckAll moduleName rest
94 return $ d : ds
95typeCheckAll moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
96 rethrow (("Error in data binding group " ++ show (map (\(name, _, _) -> name) tys) ++ ":\n") ++) $ do
97 forM_ tys $ \(name, _, _) ->
98 typeIsNotDefined moduleName name
99 ks <- kindsOfAll moduleName (map (\(name, args, dctors) -> (name, args, mapMaybe snd dctors)) tys)
100 forM_ (zip tys ks) $ \((name, args, dctors), ctorKind) ->
101 addDataType moduleName name args dctors ctorKind
102 ds <- typeCheckAll moduleName rest
103 return $ d : ds
104typeCheckAll moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
105 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
106 typeIsNotDefined moduleName name
107 kind <- kindsOf moduleName name args [ty]
108 addTypeSynonym moduleName name args ty kind
109 ds <- typeCheckAll moduleName rest
110 return $ d : ds
111typeCheckAll _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
112typeCheckAll moduleName (ValueDeclaration name [] Nothing val : rest) = do
113 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
114 valueIsNotDefined moduleName name
115 [(_, (val', ty))] <- typesOf moduleName [(name, val)]
116 addValue moduleName name ty
117 return $ ValueDeclaration name [] Nothing val'
118 ds <- typeCheckAll moduleName rest
119 return $ d : ds
120typeCheckAll _ (ValueDeclaration _ _ _ _ : _) = error "Binders were not desugared"
121typeCheckAll moduleName (BindingGroupDeclaration vals : rest) = do
122 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
123 forM_ (map fst vals) $ \name ->
124 valueIsNotDefined moduleName name
125 tys <- typesOf moduleName vals
126 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
127 addValue moduleName name ty
128 return (name, val)
129 return $ BindingGroupDeclaration vals'
130 ds <- typeCheckAll moduleName rest
131 return $ d : ds
132typeCheckAll moduleName (d@(ExternDataDeclaration name kind) : rest) = do
133 env <- getEnv
134 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
135 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env) }
136 ds <- typeCheckAll moduleName rest
137 return $ d : ds
138typeCheckAll moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
139 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
140 env <- getEnv
141 kind <- kindOf moduleName ty
142 guardWith "Expected kind *" $ kind == Star
143 case M.lookup (moduleName, name) (names env) of
144 Just _ -> throwError $ show name ++ " is already defined"
145 Nothing -> putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Extern importTy) (names env) })
146 ds <- typeCheckAll moduleName rest
147 return $ d : ds
148typeCheckAll moduleName (d@(FixityDeclaration _ name) : rest) = do
149 ds <- typeCheckAll moduleName rest
150 env <- getEnv
151 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
152 return $ d : ds
153typeCheckAll currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
154 env <- getEnv
155 rethrow errorMessage $ do
156 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
157 case idents of
158 Nothing -> do
159 shadowIdents (map snd $ filterModule (names env)) env
160 shadowTypes (map snd $ filterModule (types env)) env
161 Just idents' -> do
162 shadowIdents (lefts idents') env
163 shadowTypes (rights idents') env
164 ds <- typeCheckAll currentModule rest
165 return $ d : ds
166 where errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
167 filterModule = filter ((== moduleName) . fst) . M.keys
168 moduleExists env = not (null (filterModule (names env))) || not (null (filterModule (types env)))
169 shadowIdents idents' env =
170 forM_ idents' $ \ident -> do
171 case (moduleName, ident) `M.lookup` names env of
172 Just (_, Alias _ _) -> return ()
173 Just (pt, _) -> do
174 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
175 modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
176 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
177 shadowTypes pns env =
178 forM_ pns $ \pn -> do
179 case (moduleName, pn) `M.lookup` types env of
180 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
181 Just (_, DataAlias _ _) -> return ()
182 Just (k, _) -> do
183 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (currentModule, pn) `M.notMember` types env
184 modifyEnv (\e -> e { types = M.insert (currentModule, pn) (k, DataAlias moduleName pn) (types e) })
185 let keys = map (snd . fst) . filter (\(_, (fn, _)) -> fn `constructs` pn) . M.toList . dataConstructors $ env
186 forM_ keys $ \dctor -> do
187 case (moduleName, dctor) `M.lookup` dataConstructors env of
188 Just (_, Alias _ _) -> return ()
189 Just (ctorTy, _) -> do
190 guardWith (show currentModule ++ "." ++ show dctor ++ " is already defined") $ (currentModule, dctor) `M.notMember` dataConstructors env
191 modifyEnv (\e -> e { dataConstructors = M.insert (currentModule, dctor) (ctorTy, Alias moduleName (Ident (runProperName dctor))) (dataConstructors e) })
192 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
193 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
194 = mn == moduleName && pn' == pn
195 constructs (ForAll _ ty) pn = ty `constructs` pn
196 constructs (Function _ ty) pn = ty `constructs` pn
197 constructs (TypeApp ty _) pn = ty `constructs` pn
198 constructs fn _ = error $ "Invalid arguments to constructs: " ++ show fn
199typeCheckAll moduleName (d@(TypeClassDeclaration _ _ _) : rest) = do
200 ds <- typeCheckAll moduleName rest
201 return $ d : ds
202typeCheckAll moduleName (d@(TypeInstanceDeclaration deps className ty _) : rest) = do
203 dictName <- Check . lift $ mkDictionaryValueName moduleName className ty
204 ds <- withTypeClassDictionaries [(dictName, deps, className, ty)] $
205 typeCheckAll moduleName rest
206 return $ d : ds