git.iko.soy/rowtype-yoga/purescript-native
on c0274e2 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/Names.hs
120 lines 3.7 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.Names
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- Data types for names
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DeriveDataTypeable #-}
17{-# LANGUAGE DeriveFunctor #-}
18{-# LANGUAGE TemplateHaskell #-}
19{-# LANGUAGE GADTs #-}
21module Language.PureScript.Names where
23import Data.List
24import Data.Data
25import Data.List.Split (splitOn)
26import Data.Aeson.TH
27import qualified Data.Aeson as A
28import qualified Data.Text as T
30-- |
31-- Names for value identifiers
32--
33data Ident
34 -- |
35 -- An alphanumeric identifier
36 --
37 = Ident String
38 -- |
39 -- A symbolic name for an infix operator
40 --
41 | Op String deriving (Show, Read, Eq, Ord, Data, Typeable)
43runIdent :: Ident -> String
44runIdent (Ident i) = i
45runIdent (Op op) = op
47showIdent :: Ident -> String
48showIdent (Ident i) = i
49showIdent (Op op) = '(' : op ++ ")"
51-- |
52-- Proper names, i.e. capitalized names for e.g. module names, type//data constructors.
53--
54newtype ProperName = ProperName { runProperName :: String } deriving (Show, Read, Eq, Ord, Data, Typeable)
56-- |
57-- Module names
58--
59newtype ModuleName = ModuleName [ProperName] deriving (Show, Read, Eq, Ord, Data, Typeable)
61runModuleName :: ModuleName -> String
62runModuleName (ModuleName pns) = intercalate "." (runProperName `map` pns)
64moduleNameFromString :: String -> ModuleName
65moduleNameFromString = ModuleName . splitProperNames
66 where
67 splitProperNames s = case dropWhile (== '.') s of
68 "" -> []
69 s' -> ProperName w : splitProperNames s''
70 where (w, s'') = break (== '.') s'
72-- |
73-- A qualified name, i.e. a name with an optional module name
74--
75data Qualified a = Qualified (Maybe ModuleName) a deriving (Show, Read, Eq, Ord, Data, Typeable, Functor)
77showQualified :: (a -> String) -> Qualified a -> String
78showQualified f (Qualified Nothing a) = f a
79showQualified f (Qualified (Just name) a) = runModuleName name ++ "." ++ f a
81instance (a ~ ProperName) => A.ToJSON (Qualified a) where
82 toJSON = A.toJSON . showQualified runProperName
84instance (a ~ ProperName) => A.FromJSON (Qualified a) where
85 parseJSON =
86 A.withText "Qualified ProperName" $ \str ->
87 return $ case reverse (splitOn "." (T.unpack str)) of
88 [name] -> Qualified Nothing (ProperName name)
89 (name:rest) -> Qualified (Just (reconstructModuleName rest)) (ProperName name)
90 _ -> Qualified Nothing (ProperName "")
91 where
92 reconstructModuleName = moduleNameFromString . intercalate "." . reverse
94-- |
95-- Provide a default module name, if a name is unqualified
96--
97qualify :: ModuleName -> Qualified a -> (ModuleName, a)
98qualify m (Qualified Nothing a) = (m, a)
99qualify _ (Qualified (Just m) a) = (m, a)
101-- |
102-- Makes a qualified value from a name and module name.
103--
104mkQualified :: a -> ModuleName -> Qualified a
105mkQualified name mn = Qualified (Just mn) name
107-- | Remove the module name from a qualified name
108disqualify :: Qualified a -> a
109disqualify (Qualified _ a) = a
111-- |
112-- Checks whether a qualified value is actually qualified with a module reference
113--
114isUnqualified :: Qualified a -> Bool
115isUnqualified (Qualified Nothing _) = True
116isUnqualified _ = False
118$(deriveJSON (defaultOptions { sumEncoding = ObjectWithSingleField }) ''Ident)
119$(deriveJSON (defaultOptions { sumEncoding = ObjectWithSingleField }) ''ProperName)
120$(deriveJSON (defaultOptions { sumEncoding = ObjectWithSingleField }) ''ModuleName)