git.iko.soy/rowtype-yoga/purescript-native
on c4186db help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
209 lines 11 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import Data.Monoid ((<>))
30import qualified Data.Map as M
31import Control.Monad.State
32import Control.Monad.Error
34import Language.PureScript.Types
35import Language.PureScript.Names
36import Language.PureScript.Kinds
37import Language.PureScript.Declarations
38import Language.PureScript.TypeClassDictionaries
39import Language.PureScript.Environment
40import Language.PureScript.Errors
42addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
43addDataType moduleName name args dctors ctorKind = do
44 env <- getEnv
45 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, DataType args dctors) (types env) }
46 forM_ dctors $ \(dctor, tys) ->
47 rethrow (strMsg ("Error in data constructor " ++ show dctor) <>) $
48 addDataConstructor moduleName name args dctor tys
50addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
51addDataConstructor moduleName name args dctor tys = do
52 env <- getEnv
53 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
54 let dctorTy = foldr function retTy tys
55 let polyType = mkForAll args dctorTy
56 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (name, polyType) (dataConstructors env) }
58addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
59addTypeSynonym moduleName name args ty kind = do
60 env <- getEnv
61 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
62 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
64valueIsNotDefined :: ModuleName -> Ident -> Check ()
65valueIsNotDefined moduleName name = do
66 env <- getEnv
67 case M.lookup (moduleName, name) (names env) of
68 Just _ -> throwError . strMsg $ show name ++ " is already defined"
69 Nothing -> return ()
71addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
72addValue moduleName name ty nameKind = do
73 env <- getEnv
74 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind) (names env) })
76addTypeClass :: ModuleName -> ProperName -> [String] -> [(Qualified ProperName, [Type])] -> [Declaration] -> Check ()
77addTypeClass moduleName pn args implies ds =
78 let members = map toPair ds in
79 modify $ \st -> st { checkEnv = (checkEnv st) { typeClasses = M.insert (Qualified (Just moduleName) pn) (args, members, implies) (typeClasses . checkEnv $ st) } }
80 where
81 toPair (TypeDeclaration ident ty) = (ident, ty)
82 toPair (PositionedDeclaration _ d) = toPair d
83 toPair _ = error "Invalid declaration in TypeClassDeclaration"
85addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
86addTypeClassDictionaries entries =
87 let mentries = M.fromList [ ((canonicalizeDictionary entry, mn), entry) | entry@TypeClassDictionaryInScope{ tcdName = Qualified mn _ } <- entries ]
88 in modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = (typeClassDictionaries . checkEnv $ st) `M.union` mentries } }
90checkTypeClassInstance :: ModuleName -> Type -> Check ()
91checkTypeClassInstance _ (TypeVar _) = return ()
92checkTypeClassInstance _ (TypeConstructor ctor) = do
93 env <- getEnv
94 when (ctor `M.member` typeSynonyms env) . throwError . strMsg $ "Type synonym instances are disallowed"
95 return ()
96checkTypeClassInstance m (TypeApp t1 t2) = checkTypeClassInstance m t1 >> checkTypeClassInstance m t2
97checkTypeClassInstance _ ty = throwError $ mkErrorStack "Type class instance head is invalid." (Just (TypeError ty))
99-- |
100-- Type check all declarations in a module
101--
102-- At this point, many declarations will have been desugared, but it is still necessary to
103--
104-- * Kind-check all types and add them to the @Environment@
105--
106-- * Type-check all values and add them to the @Environment@
107--
108-- * Bring type class instances into scope
109--
110-- * Process module imports
111--
112typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
113typeCheckAll _ _ [] = return []
114typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
115 rethrow (strMsg ("Error in type constructor " ++ show name) <>) $ do
116 ctorKind <- kindsOf True moduleName name args (concatMap snd dctors)
117 addDataType moduleName name args dctors ctorKind
118 ds <- typeCheckAll mainModuleName moduleName rest
119 return $ d : ds
120typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
121 rethrow (strMsg "Error in data binding group" <>) $ do
122 let syns = mapMaybe toTypeSynonym tys
123 let dataDecls = mapMaybe toDataDecl tys
124 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
125 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) ->
126 addDataType moduleName name args dctors ctorKind
127 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) ->
128 addTypeSynonym moduleName name args ty kind
129 ds <- typeCheckAll mainModuleName moduleName rest
130 return $ d : ds
131 where
132 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
133 toTypeSynonym (PositionedDeclaration _ d') = toTypeSynonym d'
134 toTypeSynonym _ = Nothing
135 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
136 toDataDecl (PositionedDeclaration _ d') = toDataDecl d'
137 toDataDecl _ = Nothing
138typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
139 rethrow (strMsg ("Error in type synonym " ++ show name) <>) $ do
140 kind <- kindsOf False moduleName name args [ty]
141 addTypeSynonym moduleName name args ty kind
142 ds <- typeCheckAll mainModuleName moduleName rest
143 return $ d : ds
144typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
145typeCheckAll mainModuleName moduleName (ValueDeclaration name nameKind [] Nothing val : rest) = do
146 d <- rethrow (strMsg ("Error in declaration " ++ show name) <>) $ do
147 valueIsNotDefined moduleName name
148 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
149 addValue moduleName name ty nameKind
150 return $ ValueDeclaration name nameKind [] Nothing val'
151 ds <- typeCheckAll mainModuleName moduleName rest
152 return $ d : ds
153typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
154typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
155 d <- rethrow (strMsg ("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals)) <>) $ do
156 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
157 valueIsNotDefined moduleName name
158 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
159 vals' <- forM (zipWith (\(name, nameKind, _) (_, (val, ty)) -> (name, val, nameKind, ty)) vals tys) $ \(name, val, nameKind, ty) -> do
160 addValue moduleName name ty nameKind
161 return (name, nameKind, val)
162 return $ BindingGroupDeclaration vals'
163 ds <- typeCheckAll mainModuleName moduleName rest
164 return $ d : ds
165typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
166 env <- getEnv
167 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, ExternData) (types env) }
168 ds <- typeCheckAll mainModuleName moduleName rest
169 return $ d : ds
170typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
171 rethrow (strMsg ("Error in foreign import declaration " ++ show name) <>) $ do
172 env <- getEnv
173 kind <- kindOf moduleName ty
174 guardWith (strMsg "Expected kind *") $ kind == Star
175 case M.lookup (moduleName, name) (names env) of
176 Just _ -> throwError . strMsg $ show name ++ " is already defined"
177 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
178 ds <- typeCheckAll mainModuleName moduleName rest
179 return $ d : ds
180typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
181 ds <- typeCheckAll mainModuleName moduleName rest
182 env <- getEnv
183 guardWith (strMsg ("Fixity declaration with no binding: " ++ name)) $ M.member (moduleName, Op name) $ names env
184 return $ d : ds
185typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName _ _) : rest) = do
186 tcds <- getTypeClassDictionaries
187 let instances = filter (\tcd -> let Qualified (Just mn) _ = tcdName tcd in moduleName == mn) tcds
188 addTypeClassDictionaries [ tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (canonicalizeDictionary tcd) }
189 | tcd <- instances
190 , let (Qualified _ ident) = tcdName tcd
191 ]
192 ds <- typeCheckAll mainModuleName currentModule rest
193 return $ d : ds
194typeCheckAll mainModuleName moduleName (d@(TypeClassDeclaration pn args implies tys) : rest) = do
195 addTypeClass moduleName pn args implies tys
196 ds <- typeCheckAll mainModuleName moduleName rest
197 return $ d : ds
198typeCheckAll mainModuleName moduleName (TypeInstanceDeclaration dictName deps className tys _ : rest) = do
199 typeCheckAll mainModuleName moduleName (ExternInstanceDeclaration dictName deps className tys : rest)
200typeCheckAll mainModuleName moduleName (d@(ExternInstanceDeclaration dictName deps className tys) : rest) = do
201 mapM_ (checkTypeClassInstance moduleName) tys
202 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
203 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
204 ds <- typeCheckAll mainModuleName moduleName rest
205 return $ d : ds
206typeCheckAll mainModuleName moduleName (PositionedDeclaration pos d : rest) =
207 rethrowWithPosition pos $ do
208 (d' : rest') <- typeCheckAll mainModuleName moduleName (d : rest)
209 return (PositionedDeclaration pos d' : rest')