git.iko.soy/rowtype-yoga/purescript-native
on caa1dc6 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
230 lines 12 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import Data.List (nub, (\\))
30import Data.Monoid ((<>))
31import Data.Foldable (for_)
32import qualified Data.Map as M
34import Control.Monad.State
35import Control.Monad.Error
37import Language.PureScript.Types
38import Language.PureScript.Names
39import Language.PureScript.Kinds
40import Language.PureScript.Declarations
41import Language.PureScript.TypeClassDictionaries
42import Language.PureScript.Environment
43import Language.PureScript.Errors
45addDataType :: ModuleName -> DataDeclType -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
46addDataType moduleName dtype name args dctors ctorKind = do
47 env <- getEnv
48 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, DataType args dctors) (types env) }
49 forM_ dctors $ \(dctor, tys) ->
50 rethrow (strMsg ("Error in data constructor " ++ show dctor) <>) $
51 addDataConstructor moduleName dtype name args dctor tys
53addDataConstructor :: ModuleName -> DataDeclType -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
54addDataConstructor moduleName dtype name args dctor tys = do
55 env <- getEnv
56 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
57 let dctorTy = foldr function retTy tys
58 let polyType = mkForAll args dctorTy
59 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (dtype, name, polyType) (dataConstructors env) }
61addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
62addTypeSynonym moduleName name args ty kind = do
63 env <- getEnv
64 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
65 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
67valueIsNotDefined :: ModuleName -> Ident -> Check ()
68valueIsNotDefined moduleName name = do
69 env <- getEnv
70 case M.lookup (moduleName, name) (names env) of
71 Just _ -> throwError . strMsg $ show name ++ " is already defined"
72 Nothing -> return ()
74addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
75addValue moduleName name ty nameKind = do
76 env <- getEnv
77 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind, Defined) (names env) })
79addTypeClass :: ModuleName -> ProperName -> [String] -> [(Qualified ProperName, [Type])] -> [Declaration] -> Check ()
80addTypeClass moduleName pn args implies ds =
81 let members = map toPair ds in
82 modify $ \st -> st { checkEnv = (checkEnv st) { typeClasses = M.insert (Qualified (Just moduleName) pn) (args, members, implies) (typeClasses . checkEnv $ st) } }
83 where
84 toPair (TypeDeclaration ident ty) = (ident, ty)
85 toPair (PositionedDeclaration _ d) = toPair d
86 toPair _ = error "Invalid declaration in TypeClassDeclaration"
88addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
89addTypeClassDictionaries entries =
90 let mentries = M.fromList [ ((canonicalizeDictionary entry, mn), entry) | entry@TypeClassDictionaryInScope{ tcdName = Qualified mn _ } <- entries ]
91 in modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = (typeClassDictionaries . checkEnv $ st) `M.union` mentries } }
93checkDuplicateTypeArguments :: [String] -> Check ()
94checkDuplicateTypeArguments args = for_ firstDup $ \dup ->
95 throwError . strMsg $ "Duplicate type argument '" ++ dup ++ "'"
96 where
97 firstDup :: Maybe String
98 firstDup = listToMaybe $ args \\ nub args
100checkTypeClassInstance :: ModuleName -> Type -> Check ()
101checkTypeClassInstance _ (TypeVar _) = return ()
102checkTypeClassInstance _ (TypeConstructor ctor) = do
103 env <- getEnv
104 when (ctor `M.member` typeSynonyms env) . throwError . strMsg $ "Type synonym instances are disallowed"
105 return ()
106checkTypeClassInstance m (TypeApp t1 t2) = checkTypeClassInstance m t1 >> checkTypeClassInstance m t2
107checkTypeClassInstance _ ty = throwError $ mkErrorStack "Type class instance head is invalid." (Just (TypeError ty))
109-- |
110-- Type check all declarations in a module
111--
112-- At this point, many declarations will have been desugared, but it is still necessary to
113--
114-- * Kind-check all types and add them to the @Environment@
115--
116-- * Type-check all values and add them to the @Environment@
117--
118-- * Bring type class instances into scope
119--
120-- * Process module imports
121--
122typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
123typeCheckAll _ _ [] = return []
124typeCheckAll mainModuleName moduleName (d@(DataDeclaration dtype name args dctors) : rest) = do
125 rethrow (strMsg ("Error in type constructor " ++ show name) <>) $ do
126 when (dtype == Newtype) $ checkNewtype dctors
127 checkDuplicateTypeArguments args
128 ctorKind <- kindsOf True moduleName name args (concatMap snd dctors)
129 addDataType moduleName dtype name args dctors ctorKind
130 ds <- typeCheckAll mainModuleName moduleName rest
131 return $ d : ds
132 where
133 checkNewtype :: [(ProperName, [Type])] -> Check ()
134 checkNewtype [(_, [_])] = return ()
135 checkNewtype [(_, _)] = throwError . strMsg $ "newtypes constructors must have a single argument"
136 checkNewtype _ = throwError . strMsg $ "newtypes must have a single constructor"
137typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
138 rethrow (strMsg "Error in data binding group" <>) $ do
139 let syns = mapMaybe toTypeSynonym tys
140 let dataDecls = mapMaybe toDataDecl tys
141 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(_, name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
142 forM_ (zip dataDecls data_ks) $ \((dtype, name, args, dctors), ctorKind) -> do
143 checkDuplicateTypeArguments args
144 addDataType moduleName dtype name args dctors ctorKind
145 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) -> do
146 checkDuplicateTypeArguments args
147 addTypeSynonym moduleName name args ty kind
148 ds <- typeCheckAll mainModuleName moduleName rest
149 return $ d : ds
150 where
151 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
152 toTypeSynonym (PositionedDeclaration _ d') = toTypeSynonym d'
153 toTypeSynonym _ = Nothing
154 toDataDecl (DataDeclaration dtype nm args dctors) = Just (dtype, nm, args, dctors)
155 toDataDecl (PositionedDeclaration _ d') = toDataDecl d'
156 toDataDecl _ = Nothing
157typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
158 rethrow (strMsg ("Error in type synonym " ++ show name) <>) $ do
159 checkDuplicateTypeArguments args
160 kind <- kindsOf False moduleName name args [ty]
161 addTypeSynonym moduleName name args ty kind
162 ds <- typeCheckAll mainModuleName moduleName rest
163 return $ d : ds
164typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
165typeCheckAll mainModuleName moduleName (ValueDeclaration name nameKind [] Nothing val : rest) = do
166 d <- rethrow (strMsg ("Error in declaration " ++ show name) <>) $ do
167 valueIsNotDefined moduleName name
168 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
169 addValue moduleName name ty nameKind
170 return $ ValueDeclaration name nameKind [] Nothing val'
171 ds <- typeCheckAll mainModuleName moduleName rest
172 return $ d : ds
173typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
174typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
175 d <- rethrow (strMsg ("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals)) <>) $ do
176 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
177 valueIsNotDefined moduleName name
178 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
179 vals' <- forM (zipWith (\(name, nameKind, _) (_, (val, ty)) -> (name, val, nameKind, ty)) vals tys) $ \(name, val, nameKind, ty) -> do
180 addValue moduleName name ty nameKind
181 return (name, nameKind, val)
182 return $ BindingGroupDeclaration vals'
183 ds <- typeCheckAll mainModuleName moduleName rest
184 return $ d : ds
185typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
186 env <- getEnv
187 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, ExternData) (types env) }
188 ds <- typeCheckAll mainModuleName moduleName rest
189 return $ d : ds
190typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
191 rethrow (strMsg ("Error in foreign import declaration " ++ show name) <>) $ do
192 env <- getEnv
193 kind <- kindOf moduleName ty
194 guardWith (strMsg "Expected kind *") $ kind == Star
195 case M.lookup (moduleName, name) (names env) of
196 Just _ -> throwError . strMsg $ show name ++ " is already defined"
197 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy, Defined) (names env) })
198 ds <- typeCheckAll mainModuleName moduleName rest
199 return $ d : ds
200typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
201 ds <- typeCheckAll mainModuleName moduleName rest
202 env <- getEnv
203 guardWith (strMsg ("Fixity declaration with no binding: " ++ name)) $ M.member (moduleName, Op name) $ names env
204 return $ d : ds
205typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName _ _) : rest) = do
206 tcds <- getTypeClassDictionaries
207 let instances = filter (\tcd -> let Qualified (Just mn) _ = tcdName tcd in moduleName == mn) tcds
208 addTypeClassDictionaries [ tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (canonicalizeDictionary tcd) }
209 | tcd <- instances
210 , let (Qualified _ ident) = tcdName tcd
211 ]
212 ds <- typeCheckAll mainModuleName currentModule rest
213 return $ d : ds
214typeCheckAll mainModuleName moduleName (d@(TypeClassDeclaration pn args implies tys) : rest) = do
215 addTypeClass moduleName pn args implies tys
216 ds <- typeCheckAll mainModuleName moduleName rest
217 return $ d : ds
218typeCheckAll mainModuleName moduleName (TypeInstanceDeclaration dictName deps className tys _ : rest) = do
219 typeCheckAll mainModuleName moduleName (ExternInstanceDeclaration dictName deps className tys : rest)
220typeCheckAll mainModuleName moduleName (d@(ExternInstanceDeclaration dictName deps className tys) : rest) = do
221 mapM_ (checkTypeClassInstance moduleName) tys
222 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
223 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
224 ds <- typeCheckAll mainModuleName moduleName rest
225 return $ d : ds
226typeCheckAll mainModuleName moduleName (PositionedDeclaration pos d : rest) =
227 rethrowWithPosition pos $ do
228 (d' : rest') <- typeCheckAll mainModuleName moduleName (d : rest)
229 return (PositionedDeclaration pos d' : rest')