git.iko.soy/rowtype-yoga/purescript-native
on d66e332 help sign in
rowtype-yoga/purescript-native/src/PureScript/Parser/Values.hs
234 lines 11 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : PureScript.Parser.Values
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12--
13-----------------------------------------------------------------------------
15module PureScript.Parser.Values (
16 parseValue,
17 parseBinder
18) where
20import PureScript.Values
21import qualified PureScript.Parser.Common as C
22import Control.Applicative
23import qualified Text.Parsec as P
24import Text.Parsec.Expr
25import Control.Monad
26import Control.Arrow (Arrow(..))
27import PureScript.Parser.Types
28import PureScript.Types
30booleanLiteral :: P.Parsec String P.Column Bool
31booleanLiteral = (C.reserved "true" >> return True) P.<|> (C.reserved "false" >> return False)
33parseNumericLiteral :: P.Parsec String P.Column Value
34parseNumericLiteral = NumericLiteral <$> C.integerOrFloat
36parseStringLiteral :: P.Parsec String P.Column Value
37parseStringLiteral = StringLiteral <$> C.stringLiteral
39parseBooleanLiteral :: P.Parsec String P.Column Value
40parseBooleanLiteral = BooleanLiteral <$> booleanLiteral
42parseArrayLiteral :: P.Parsec String P.Column Value
43parseArrayLiteral = ArrayLiteral <$> (C.squares $ parseValue `P.sepBy` (C.indented *> C.comma))
45parseObjectLiteral :: P.Parsec String P.Column Value
46parseObjectLiteral = ObjectLiteral <$> (C.braces $ parseIdentifierAndValue `P.sepBy` (C.indented *> C.comma))
48parseIdentifierAndValue :: P.Parsec String P.Column (String, Value)
49parseIdentifierAndValue = (,) <$> (C.indented *> C.identifier <* C.indented <* C.colon)
50 <*> (C.indented *> parseValue)
52parseAbs :: P.Parsec String P.Column Value
53parseAbs = do
54 C.lexeme $ P.char '\\'
55 args <- (C.indented *> C.parseIdent) `P.sepBy` (C.indented *> C.comma)
56 C.lexeme $ C.indented *> P.string "->"
57 value <- parseValue
58 return $ Abs args value
60parseApp :: P.Parsec String P.Column Value
61parseApp = App <$> parseValue
62 <*> (C.indented *> C.parens (parseValue `P.sepBy` (C.indented *> C.comma)))
64parseVar :: P.Parsec String P.Column Value
65parseVar = Var <$> C.parseIdent
67parseConstructor :: P.Parsec String P.Column Value
68parseConstructor = Constructor <$> C.properName
70parseCase :: P.Parsec String P.Column Value
71parseCase = Case <$> (P.between (C.reserved "case") (C.indented *> C.reserved "of") parseValue)
72 <*> (C.indented *> C.mark (P.many (C.same *> C.mark parseCaseAlternative)))
74parseCaseAlternative :: P.Parsec String P.Column (Binder, Value)
75parseCaseAlternative = (,) <$> (parseBinder <* C.lexeme (P.string "->")) <*> parseValue
77parseBlock :: P.Parsec String P.Column Value
78parseBlock = Block <$> (C.reserved "do" *> parseManyStatements)
80parseManyStatements :: P.Parsec String P.Column [Statement]
81parseManyStatements = C.indented *> (C.mark $ P.many $ C.same *> C.mark parseStatement)
83parseValueAtom :: P.Parsec String P.Column Value
84parseValueAtom = C.indented *> P.choice (map P.try
85 [ parseNumericLiteral
86 , parseStringLiteral
87 , parseBooleanLiteral
88 , parseArrayLiteral
89 , parseObjectLiteral
90 , parseAbs
91 , parseVar
92 , parseConstructor
93 , parseBlock
94 , parseCase
95 , C.parens parseValue ])
97parseValue :: P.Parsec String P.Column Value
98parseValue = buildExpressionParser operators . C.buildPostfixParser postfixTable $ parseValueAtom
99 where
100 postfixTable = [ Accessor <$> (C.indented *> C.dot *> C.indented *> C.identifier)
101 , Indexer <$> (C.indented *> C.squares parseValue)
102 , flip App <$> (C.indented *> C.parens (parseValue `P.sepBy` (C.indented *> C.comma)))
103 , flip TypedValue <$> (P.try $ C.lexeme (C.indented *> P.string "::") *> parsePolyType) ]
104 operators = [ [ Prefix $ C.lexeme (P.try $ C.indented *> C.reservedOp "!") >> return (Unary Not)
105 , Prefix $ C.lexeme (P.try $ C.indented *> C.reservedOp "~") >> return (Unary BitwiseNot)
106 , Prefix $ C.lexeme (P.try $ C.indented *> C.reservedOp "-") >> return (Unary Negate) ]
107 , [ Infix (C.lexeme (P.try (C.indented *> C.parseIdentInfix) >>= \ident -> return $ \t1 t2 -> App (App (Var ident) [t1]) [t2])) AssocRight ]
108 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "<=") >> return (Binary LessThanOrEqualTo)) AssocRight
109 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">=") >> return (Binary GreaterThanOrEqualTo)) AssocRight ]
110 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "<") >> return (Binary LessThan)) AssocRight
111 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">") >> return (Binary GreaterThan)) AssocRight ]
112 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "*") >> return (Binary Multiply)) AssocRight
113 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "/") >> return (Binary Divide)) AssocRight
114 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "%") >> return (Binary Modulus)) AssocRight ]
115 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "++") >> return (Binary Concat)) AssocRight
116 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "+") >> return (Binary Add)) AssocRight
117 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "-") >> return (Binary Subtract)) AssocRight ]
118 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "<<") >> return (Binary ShiftLeft)) AssocRight
119 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">>>") >> return (Binary ZeroFillShiftRight)) AssocRight
120 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp ">>") >> return (Binary ShiftRight)) AssocRight ]
121 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "==") >> return (Binary EqualTo)) AssocRight
122 , Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "!=") >> return (Binary NotEqualTo)) AssocRight ]
123 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "&") >> return (Binary BitwiseAnd)) AssocRight ]
124 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "^") >> return (Binary BitwiseXor)) AssocRight ]
125 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "|") >> return (Binary BitwiseOr)) AssocRight ]
126 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "&&") >> return (Binary And)) AssocRight ]
127 , [ Infix (C.lexeme (P.try $ C.indented *> C.reservedOp "||") >> return (Binary Or)) AssocRight ]
128 ]
130parseVariableIntroduction :: P.Parsec String P.Column Statement
131parseVariableIntroduction = do
132 C.reserved "var"
133 name <- C.indented *> C.parseIdent
134 C.lexeme $ C.indented *> P.char '='
135 value <- parseValue
136 return $ VariableIntroduction name value
138parseAssignment :: P.Parsec String P.Column Statement
139parseAssignment = do
140 tgt <- parseAssignmentTarget
141 C.lexeme $ C.indented *> P.char '='
142 value <- parseValue
143 return $ Assignment tgt value
145parseWhile :: P.Parsec String P.Column Statement
146parseWhile = While <$> (C.reserved "while" *> C.indented *> parseValue <* C.indented <* C.colon)
147 <*> parseManyStatements
149parseFor :: P.Parsec String P.Column Statement
150parseFor = For <$> (C.reserved "for" *> C.indented *> C.parseIdent)
151 <*> (C.indented *> C.lexeme (P.string "<-") *> parseValue)
152 <*> (C.indented *> C.reserved "until" *> parseValue <* C.colon)
153 <*> parseManyStatements
155parseForEach :: P.Parsec String P.Column Statement
156parseForEach = ForEach <$> (C.reserved "foreach" *> C.indented *> C.parseIdent)
157 <*> (C.indented *> C.reserved "in" *> parseValue <* C.colon)
158 <*> parseManyStatements
160parseIf :: P.Parsec String P.Column Statement
161parseIf = If <$> parseIfStatement
163parseIfStatement :: P.Parsec String P.Column IfStatement
164parseIfStatement =
165 IfStatement <$> (C.reserved "if" *> C.indented *> parseValue <* C.indented <* C.colon)
166 <*> parseManyStatements
167 <*> P.optionMaybe (C.same *> parseElseStatement)
169parseElseStatement :: P.Parsec String P.Column ElseStatement
170parseElseStatement = C.reserved "else" >> (ElseIf <$> (C.indented *> parseIfStatement)
171 <|> Else <$> (C.indented *> C.colon *> parseManyStatements))
173parseReturn :: P.Parsec String P.Column Statement
174parseReturn = Return <$> (C.reserved "return" *> parseValue)
176parseStatement :: P.Parsec String P.Column Statement
177parseStatement = P.choice (map P.try
178 [ parseVariableIntroduction
179 , parseAssignment
180 , parseWhile
181 , parseFor
182 , parseForEach
183 , parseIf
184 , parseReturn ])
186parseStringBinder :: P.Parsec String P.Column Binder
187parseStringBinder = StringBinder <$> C.stringLiteral
189parseBooleanBinder :: P.Parsec String P.Column Binder
190parseBooleanBinder = BooleanBinder <$> booleanLiteral
192parseNumberBinder :: P.Parsec String P.Column Binder
193parseNumberBinder = NumberBinder <$> C.integerOrFloat
195parseVarBinder :: P.Parsec String P.Column Binder
196parseVarBinder = VarBinder <$> C.parseIdent
198parseNullaryBinder :: P.Parsec String P.Column Binder
199parseNullaryBinder = NullaryBinder <$> C.lexeme C.properName
201parseUnaryBinder :: P.Parsec String P.Column Binder
202parseUnaryBinder = UnaryBinder <$> C.lexeme C.properName <*> (C.indented *> parseBinder)
204parseObjectBinder :: P.Parsec String P.Column Binder
205parseObjectBinder = ObjectBinder <$> C.braces ((C.indented *> parseIdentifierAndBinder) `P.sepBy` (C.indented *> C.comma))
207parseArrayBinder :: P.Parsec String P.Column Binder
208parseArrayBinder = C.squares $ ArrayBinder <$> ((C.indented *> parseBinder) `P.sepBy` (C.indented *> C.comma))
209 <*> P.optionMaybe (C.indented *> C.colon *> C.indented *> parseBinder)
211parseIdentifierAndBinder :: P.Parsec String P.Column (String, Binder)
212parseIdentifierAndBinder = do
213 name <- C.lexeme C.identifier
214 C.lexeme $ C.indented *> P.char '='
215 binder <- C.indented *> parseBinder
216 return (name, binder)
218parseBinder :: P.Parsec String P.Column Binder
219parseBinder = P.choice (map P.try
220 [ parseStringBinder
221 , parseBooleanBinder
222 , parseNumberBinder
223 , parseVarBinder
224 , parseUnaryBinder
225 , parseNullaryBinder
226 , parseObjectBinder
227 , parseArrayBinder
228 , C.parens parseBinder ])
230parseAssignmentTarget :: P.Parsec String P.Column AssignmentTarget
231parseAssignmentTarget = buildExpressionParser operators (AssignVariable <$> C.parseIdent)
232 where
233 operators = [ [ Postfix $ AssignArrayIndex <$> (C.indented *> C.squares parseValue)
234 , Postfix $ AssignObjectProperty <$> (C.indented *> C.dot *> C.indented *> C.identifier) ] ]