git.iko.soy/rowtype-yoga/purescript-native
on d844a5c help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
258 lines 13 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
32import Data.Either (rights, lefts)
34import Language.PureScript.Types
35import Language.PureScript.Names
36import Language.PureScript.Values
37import Language.PureScript.Kinds
38import Language.PureScript.Declarations
39import Language.PureScript.Sugar.TypeClasses
41addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
42addDataType moduleName name args dctors ctorKind = do
43 env <- getEnv
44 putEnv $ env { types = M.insert (moduleName, name) (ctorKind, Data) (types env) }
45 forM_ dctors $ \(dctor, tys) ->
46 rethrow (("Error in data constructor " ++ show dctor ++ ":\n") ++) $
47 addDataConstructor moduleName name args dctor tys
49addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
50addDataConstructor moduleName name args dctor tys = do
51 env <- getEnv
52 dataConstructorIsNotDefined moduleName dctor
53 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
54 let dctorTy = foldr function retTy tys
55 let polyType = mkForAll args dctorTy
56 putEnv $ env { dataConstructors = M.insert (moduleName, dctor) (qualifyAllUnqualifiedNames moduleName env polyType, DataConstructor) (dataConstructors env) }
58addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
59addTypeSynonym moduleName name args ty kind = do
60 env <- getEnv
61 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env)
62 , typeSynonyms = M.insert (moduleName, name) (args, qualifyAllUnqualifiedNames moduleName env ty) (typeSynonyms env) }
64typeIsNotDefined :: ModuleName -> ProperName -> Check ()
65typeIsNotDefined moduleName name = do
66 env <- getEnv
67 guardWith (show name ++ " is already defined") $
68 not $ M.member (moduleName, name) (types env)
70dataConstructorIsNotDefined :: ModuleName -> ProperName -> Check ()
71dataConstructorIsNotDefined moduleName dctor = do
72 env <- getEnv
73 guardWith (show dctor ++ " is already defined") $
74 not $ M.member (moduleName, dctor) (dataConstructors env)
76valueIsNotDefined :: ModuleName -> Ident -> Check ()
77valueIsNotDefined moduleName name = do
78 env <- getEnv
79 case M.lookup (moduleName, name) (names env) of
80 Just _ -> throwError $ show name ++ " is already defined"
81 Nothing -> return ()
83addValue :: ModuleName -> Ident -> Type -> Check ()
84addValue moduleName name ty = do
85 env <- getEnv
86 putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Value) (names env) })
88addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
89addTypeClassDictionaries entries = do
90 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
92checkTypeClassInstance :: ModuleName -> Type -> Check ()
93checkTypeClassInstance _ (TypeVar _) = return ()
94checkTypeClassInstance m (TypeConstructor ctor) = do
95 env <- getEnv
96 when (canonicalizeType m env ctor `M.member` typeSynonyms env) $ throwError "Type synonym instances are disallowed"
97 return ()
98checkTypeClassInstance m (TypeApp ty (TypeVar _)) = checkTypeClassInstance m ty
99checkTypeClassInstance _ _ = throwError "Type class instance must be of the form T a1 ... an"
101-- |
102-- Type check all declarations in a module
103--
104-- At this point, many declarations will have been desugared, but it is still necessary to
105--
106-- * Kind-check all types and add them to the @Environment@
107--
108-- * Type-check all values and add them to the @Environment@
109--
110-- * Bring type class instances into scope
111--
112-- * Process module imports
113--
114typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
115typeCheckAll _ _ [] = return []
116typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
117 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
118 typeIsNotDefined moduleName name
119 ctorKind <- kindsOf moduleName name args (concatMap snd dctors)
120 addDataType moduleName name args dctors ctorKind
121 ds <- typeCheckAll mainModuleName moduleName rest
122 return $ d : ds
123typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
124 rethrow ("Error in data binding group:\n" ++) $ do
125 let syns = mapMaybe toTypeSynonym tys
126 let dataDecls = mapMaybe toDataDecl tys
127 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
128 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) -> do
129 typeIsNotDefined moduleName name
130 addDataType moduleName name args dctors ctorKind
131 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) -> do
132 typeIsNotDefined moduleName name
133 addTypeSynonym moduleName name args ty kind
134 ds <- typeCheckAll mainModuleName moduleName rest
135 return $ d : ds
136 where
137 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
138 toTypeSynonym _ = Nothing
139 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
140 toDataDecl _ = Nothing
141typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
142 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
143 typeIsNotDefined moduleName name
144 kind <- kindsOf moduleName name args [ty]
145 addTypeSynonym moduleName name args ty kind
146 ds <- typeCheckAll mainModuleName moduleName rest
147 return $ d : ds
148typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
149typeCheckAll mainModuleName moduleName (ValueDeclaration name [] Nothing val : rest) = do
150 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
151 valueIsNotDefined moduleName name
152 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
153 addValue moduleName name ty
154 return $ ValueDeclaration name [] Nothing val'
155 ds <- typeCheckAll mainModuleName moduleName rest
156 return $ d : ds
157typeCheckAll _ _ (ValueDeclaration _ _ _ _ : _) = error "Binders were not desugared"
158typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
159 d <- rethrow (("Error in binding group " ++ show (map fst vals) ++ ":\n") ++) $ do
160 forM_ (map fst vals) $ \name ->
161 valueIsNotDefined moduleName name
162 tys <- typesOf mainModuleName moduleName vals
163 vals' <- forM (zip (map fst vals) (map snd tys)) $ \(name, (val, ty)) -> do
164 addValue moduleName name ty
165 return (name, val)
166 return $ BindingGroupDeclaration vals'
167 ds <- typeCheckAll mainModuleName moduleName rest
168 return $ d : ds
169typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
170 env <- getEnv
171 guardWith (show name ++ " is already defined") $ not $ M.member (moduleName, name) (types env)
172 putEnv $ env { types = M.insert (moduleName, name) (kind, TypeSynonym) (types env) }
173 ds <- typeCheckAll mainModuleName moduleName rest
174 return $ d : ds
175typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
176 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
177 env <- getEnv
178 kind <- kindOf moduleName ty
179 guardWith "Expected kind *" $ kind == Star
180 case M.lookup (moduleName, name) (names env) of
181 Just _ -> throwError $ show name ++ " is already defined"
182 Nothing -> putEnv (env { names = M.insert (moduleName, name) (qualifyAllUnqualifiedNames moduleName env ty, Extern importTy) (names env) })
183 ds <- typeCheckAll mainModuleName moduleName rest
184 return $ d : ds
185typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
186 ds <- typeCheckAll mainModuleName moduleName rest
187 env <- getEnv
188 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
189 return $ d : ds
190typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName idents) : rest) = do
191 env <- getEnv
192 rethrow errorMessage $ do
193 guardWith ("Module " ++ show moduleName ++ " does not exist") $ moduleExists env
194 case idents of
195 Nothing -> do
196 shadowIdents (map snd $ filterModule (names env)) env
197 shadowTypes (map snd $ filterModule (types env)) env
198 Just idents' -> do
199 shadowIdents (lefts idents') env
200 shadowTypes (rights idents') env
201 shadowTypeClassInstances env
202 ds <- typeCheckAll mainModuleName currentModule rest
203 return $ d : ds
204 where
205 errorMessage = (("Error in import declaration " ++ show moduleName ++ ":\n") ++)
206 filterModule = filter ((== moduleName) . fst) . M.keys
207 moduleExists env = not (null (filterModule (names env))) || not (null (filterModule (types env)))
208 shadowIdents idents' env =
209 forM_ idents' $ \ident -> do
210 case (moduleName, ident) `M.lookup` names env of
211 Just (_, Alias _ _) -> return ()
212 Just (pt, _) -> do
213 guardWith (show currentModule ++ "." ++ show ident ++ " is already defined") $ (currentModule, ident) `M.notMember` names env
214 modifyEnv (\e -> e { names = M.insert (currentModule, ident) (pt, Alias moduleName ident) (names e) })
215 Nothing -> throwError (show moduleName ++ "." ++ show ident ++ " is undefined")
216 shadowTypes pns env =
217 forM_ pns $ \pn -> do
218 case (moduleName, pn) `M.lookup` types env of
219 Nothing -> throwError (show moduleName ++ "." ++ show pn ++ " is undefined")
220 Just (_, DataAlias _ _) -> return ()
221 Just (k, _) -> do
222 guardWith (show currentModule ++ "." ++ show pn ++ " is already defined") $ (currentModule, pn) `M.notMember` types env
223 modifyEnv (\e -> e { types = M.insert (currentModule, pn) (k, DataAlias moduleName pn) (types e) })
224 let keys = map (snd . fst) . filter (\(_, (fn, _)) -> fn `constructs` pn) . M.toList . dataConstructors $ env
225 forM_ keys $ \dctor -> do
226 case (moduleName, dctor) `M.lookup` dataConstructors env of
227 Just (_, Alias _ _) -> return ()
228 Just (ctorTy, _) -> do
229 guardWith (show currentModule ++ "." ++ show dctor ++ " is already defined") $ (currentModule, dctor) `M.notMember` dataConstructors env
230 modifyEnv (\e -> e { dataConstructors = M.insert (currentModule, dctor) (ctorTy, Alias moduleName (Ident (runProperName dctor))) (dataConstructors e) })
231 Nothing -> throwError (show moduleName ++ "." ++ show dctor ++ " is undefined")
232 shadowTypeClassInstances env = do
233 let instances = filter (\tcd ->
234 let Qualified (Just mn) _ = tcdName tcd in
235 moduleName == mn && tcdType tcd == TCDRegular
236 ) (typeClassDictionaries env)
237 forM_ instances $ \tcd -> do
238 let (Qualified _ ident) = tcdName tcd
239 addTypeClassDictionaries [tcd { tcdName = (Qualified (Just currentModule) ident), tcdType = TCDAlias (tcdName tcd) }]
240 constructs (TypeConstructor (Qualified (Just mn) pn')) pn
241 = mn == moduleName && pn' == pn
242 constructs (ForAll _ ty _) pn = ty `constructs` pn
243 constructs (TypeApp (TypeApp t _) ty) pn | t == tyFunction = ty `constructs` pn
244 constructs (TypeApp ty _) pn = ty `constructs` pn
245 constructs fn _ = error $ "Invalid arguments to constructs: " ++ show fn
246typeCheckAll mainModuleName moduleName (d@(TypeClassDeclaration _ _ _) : rest) = do
247 env <- getEnv
248 ds <- typeCheckAll mainModuleName moduleName rest
249 return $ qualifyAllUnqualifiedNames moduleName env d : ds
250typeCheckAll mainModuleName moduleName (d@(TypeInstanceDeclaration deps className ty _) : rest) = do
251 env <- getEnv
252 dictName <- Check . lift $ mkDictionaryValueName moduleName className ty
253 checkTypeClassInstance moduleName ty
254 forM_ deps $ checkTypeClassInstance moduleName . snd
255 addTypeClassDictionaries (qualifyAllUnqualifiedNames moduleName env
256 [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className ty (Just deps) TCDRegular])
257 ds <- typeCheckAll mainModuleName moduleName rest
258 return $ qualifyAllUnqualifiedNames moduleName env d : ds