git.iko.soy/rowtype-yoga/purescript-native
on e01c79d help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/ModuleDependencies.hs
76 lines 2.4 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.ModuleDependencies
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- | Provides the ability to sort modules based on module dependencies
12--
13-----------------------------------------------------------------------------
15{-# LANGUAGE FlexibleContexts #-}
17module Language.PureScript.ModuleDependencies (
18 sortModules,
19 ModuleGraph
20) where
22import Control.Monad.Except
24import Data.Graph
25import Data.List (nub)
26import Data.Maybe (mapMaybe)
28import Language.PureScript.AST
29import Language.PureScript.Names
30import Language.PureScript.Types
32-- |
33-- A list of modules with their dependencies
34--
35type ModuleGraph = [(ModuleName, [ModuleName])]
37-- |
38-- Sort a collection of modules based on module dependencies.
39--
40-- Reports an error if the module graph contains a cycle.
41--
42sortModules :: (MonadError String m) => [Module] -> m ([Module], ModuleGraph)
43sortModules ms = do
44 let verts = map (\m@(Module _ _ ds _) -> (m, getModuleName m, nub (concatMap usedModules ds))) ms
45 ms' <- mapM toModule $ stronglyConnComp verts
46 let moduleGraph = map (\(_, mn, deps) -> (mn, deps)) verts
47 return (ms', moduleGraph)
49-- |
50-- Calculate a list of used modules based on explicit imports and qualified names
51--
52usedModules :: Declaration -> [ModuleName]
53usedModules = let (f, _, _, _, _) = everythingOnValues (++) forDecls forValues (const []) (const []) (const []) in nub . f
54 where
55 forDecls :: Declaration -> [ModuleName]
56 forDecls (ImportDeclaration mn _ _) = [mn]
57 forDecls _ = []
59 forValues :: Expr -> [ModuleName]
60 forValues (Var (Qualified (Just mn) _)) = [mn]
61 forValues (Constructor (Qualified (Just mn) _)) = [mn]
62 forValues (TypedValue _ _ ty) = forTypes ty
63 forValues _ = []
65 forTypes :: Type -> [ModuleName]
66 forTypes (TypeConstructor (Qualified (Just mn) _)) = [mn]
67 forTypes (ConstrainedType cs _) = mapMaybe (\(Qualified mn _, _) -> mn) cs
68 forTypes _ = []
70-- |
71-- Convert a strongly connected component of the module graph to a module
72--
73toModule :: (MonadError String m) => SCC Module -> m Module
74toModule (AcyclicSCC m) = return m
75toModule (CyclicSCC [m]) = return m
76toModule (CyclicSCC ms) = throwError $ "Cycle in module dependencies: " ++ show (map getModuleName ms)