git.iko.soy/rowtype-yoga/purescript-native
on e84d52b help sign in
rowtype-yoga/purescript-native/src/Language/PureScript.hs
248 lines 9.9 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The main compiler module
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE DataKinds, QuasiQuotes, TemplateHaskell #-}
18module Language.PureScript (module P, compile, compile', RebuildPolicy(..), MonadMake(..), make, prelude) where
20import Language.PureScript.Types as P
21import Language.PureScript.Kinds as P
22import Language.PureScript.Declarations as P
23import Language.PureScript.Names as P
24import Language.PureScript.Parser as P
25import Language.PureScript.CodeGen as P
26import Language.PureScript.CodeGen.Common as P
27import Language.PureScript.TypeChecker as P
28import Language.PureScript.Pretty as P
29import Language.PureScript.Sugar as P
30import Language.PureScript.Options as P
31import Language.PureScript.ModuleDependencies as P
32import Language.PureScript.Environment as P
33import Language.PureScript.Errors as P
34import Language.PureScript.DeadCodeElimination as P
35import Language.PureScript.Supply as P
36import Language.PureScript.Renamer as P
38import qualified Language.PureScript.Constants as C
40import Data.List (sortBy, groupBy, intercalate)
41import Data.Time.Clock
42import Data.Function (on)
43import Data.Maybe (fromMaybe)
44import Data.FileEmbed (embedFile)
45import Data.Traversable (traverse)
47import Control.Monad.Error
48import Control.Arrow ((&&&))
49import Control.Applicative
51import qualified Data.Map as M
52import qualified Data.Set as S
53import qualified Data.ByteString.UTF8 as BU
55import System.FilePath ((</>))
57-- |
58-- Compile a collection of modules
59--
60-- The compilation pipeline proceeds as follows:
61--
62-- * Sort the modules based on module dependencies, checking for cyclic dependencies.
63--
64-- * Perform a set of desugaring passes.
65--
66-- * Type check, and elaborate values to include type annotations and type class dictionaries.
67--
68-- * Regroup values to take into account new value dependencies introduced by elaboration.
69--
70-- * Eliminate dead code.
71--
72-- * Generate Javascript, and perform optimization passes.
73--
74-- * Pretty-print the generated Javascript
75--
76compile :: Options Compile -> [Module] -> [String] -> Either String (String, String, Environment)
77compile = compile' initEnvironment
79compile' :: Environment -> Options Compile -> [Module] -> [String] -> Either String (String, String, Environment)
80compile' env opts ms prefix = do
81 (sorted, _) <- sortModules $ map importPrim $ if optionsNoPrelude opts then ms else (map importPrelude ms)
82 (desugared, nextVar) <- stringifyErrorStack True $ runSupplyT 0 $ desugar sorted
83 (elaborated, env') <- runCheck' opts env $ forM desugared $ typeCheckModule mainModuleIdent
84 regrouped <- stringifyErrorStack True $ createBindingGroupsModule . collapseBindingGroupsModule $ elaborated
85 let entryPoints = moduleNameFromString `map` entryPointModules (optionsAdditional opts)
86 let elim = if null entryPoints then regrouped else eliminateDeadCode entryPoints regrouped
87 let renamed = renameInModules elim
88 let codeGenModuleNames = moduleNameFromString `map` codeGenModules (optionsAdditional opts)
89 let modulesToCodeGen = if null codeGenModuleNames then renamed else filter (\(Module mn _ _) -> mn `elem` codeGenModuleNames) renamed
90 let js = evalSupply nextVar $ concat <$> mapM (\m -> moduleToJs opts m env') modulesToCodeGen
91 let exts = intercalate "\n" . map (`moduleToPs` env') $ modulesToCodeGen
92 js' <- generateMain env' opts js
93 let pjs = unlines $ map ("// " ++) prefix ++ [prettyPrintJS js']
94 return (pjs, exts, env')
95 where
96 mainModuleIdent = moduleNameFromString <$> optionsMain opts
98generateMain :: Environment -> Options Compile -> [JS] -> Either String [JS]
99generateMain env opts js =
100 case moduleNameFromString <$> optionsMain opts of
101 Just mmi -> do
102 when ((mmi, Ident C.main) `M.notMember` names env) $
103 Left $ show mmi ++ "." ++ C.main ++ " is undefined"
104 return $ js ++ [JSApp (JSAccessor C.main (JSAccessor (moduleNameToJs mmi) (JSVar (browserNamespace (optionsAdditional opts))))) []]
105 _ -> return js
107-- |
108-- A type class which collects the IO actions we need to be able to run in "make" mode
109--
110class MonadMake m where
111 -- |
112 -- Get a file timestamp
113 --
114 getTimestamp :: FilePath -> m (Maybe UTCTime)
116 -- |
117 -- Read a file as a string
118 --
119 readTextFile :: FilePath -> m String
121 -- |
122 -- Write a text file
123 --
124 writeTextFile :: FilePath -> String -> m ()
126 -- |
127 -- Report an error
128 --
129 liftError :: Either String a -> m a
131 -- |
132 -- Respond to a progress update
133 --
134 progress :: String -> m ()
136-- |
137-- Determines when to rebuild a module
138--
139data RebuildPolicy
140 -- | Never rebuild this module
141 = RebuildNever
142 -- | Always rebuild this module
143 | RebuildAlways deriving (Show, Eq, Ord)
145-- |
146-- Compiles in "make" mode, compiling each module separately to a js files and an externs file
147--
148-- If timestamps have not changed, the externs file can be used to provide the module's types without
149-- having to typecheck the module again.
150--
151make :: (Functor m, Applicative m, Monad m, MonadMake m) => FilePath -> Options Make -> [(Either RebuildPolicy FilePath, Module)] -> [String] -> m Environment
152make outputDir opts ms prefix = do
153 let filePathMap = M.fromList (map (\(fp, Module mn _ _) -> (mn, fp)) ms)
155 (sorted, graph) <- liftError $ sortModules $ map importPrim $ if optionsNoPrelude opts then map snd ms else (map (importPrelude . snd) ms)
157 toRebuild <- foldM (\s (Module moduleName' _ _) -> do
158 let filePath = runModuleName moduleName'
160 jsFile = outputDir </> filePath </> "index.js"
161 externsFile = outputDir </> filePath </> "externs.purs"
162 inputFile = fromMaybe (error "Module has no filename in 'make'") $ M.lookup moduleName' filePathMap
164 jsTimestamp <- getTimestamp jsFile
165 externsTimestamp <- getTimestamp externsFile
166 inputTimestamp <- traverse getTimestamp inputFile
168 return $ case (inputTimestamp, jsTimestamp, externsTimestamp) of
169 (Right (Just t1), Just t2, Just t3) | t1 < min t2 t3 -> s
170 (Left RebuildNever, Just _, Just _) -> s
171 _ -> S.insert moduleName' s) S.empty sorted
173 marked <- rebuildIfNecessary (reverseDependencies graph) toRebuild sorted
175 (desugared, nextVar) <- liftError $ stringifyErrorStack True $ runSupplyT 0 $ zip (map fst marked) <$> desugar (map snd marked)
177 evalSupplyT nextVar (go initEnvironment desugared)
179 where
180 go :: (Functor m, Applicative m, Monad m, MonadMake m) => Environment -> [(Bool, Module)] -> SupplyT m Environment
181 go env [] = return env
182 go env ((False, m) : ms') = do
183 (_, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
185 go env' ms'
186 go env ((True, m@(Module moduleName' _ exps)) : ms') = do
187 let filePath = runModuleName moduleName'
188 jsFile = outputDir </> filePath </> "index.js"
189 externsFile = outputDir </> filePath </> "externs.purs"
191 lift . progress $ "Compiling " ++ runModuleName moduleName'
193 (Module _ elaborated _, env') <- lift . liftError . runCheck' opts env $ typeCheckModule Nothing m
195 regrouped <- lift . liftError . stringifyErrorStack True . createBindingGroups moduleName' . collapseBindingGroups $ elaborated
197 let mod' = Module moduleName' regrouped exps
198 let [renamed] = renameInModules [mod']
200 pjs <- prettyPrintJS <$> moduleToJs opts renamed env'
201 let js = unlines $ map ("// " ++) prefix ++ [pjs]
202 let exts = unlines $ map ("-- " ++ ) prefix ++ [moduleToPs renamed env']
204 lift $ writeTextFile jsFile js
205 lift $ writeTextFile externsFile exts
207 go env' ms'
209 rebuildIfNecessary :: (Functor m, Monad m, MonadMake m) => M.Map ModuleName [ModuleName] -> S.Set ModuleName -> [Module] -> m [(Bool, Module)]
210 rebuildIfNecessary _ _ [] = return []
211 rebuildIfNecessary graph toRebuild (m@(Module moduleName' _ _) : ms') | moduleName' `S.member` toRebuild = do
212 let deps = fromMaybe [] $ moduleName' `M.lookup` graph
213 toRebuild' = toRebuild `S.union` S.fromList deps
214 (:) (True, m) <$> rebuildIfNecessary graph toRebuild' ms'
215 rebuildIfNecessary graph toRebuild (Module moduleName' _ _ : ms') = do
216 let externsFile = outputDir </> runModuleName moduleName' </> "externs.purs"
217 externs <- readTextFile externsFile
218 externsModules <- liftError . either (Left . show) Right $ P.runIndentParser externsFile P.parseModules externs
219 case externsModules of
220 [m'@(Module moduleName'' _ _)] | moduleName'' == moduleName' -> (:) (False, m') <$> rebuildIfNecessary graph toRebuild ms'
221 _ -> liftError . Left $ "Externs file " ++ externsFile ++ " was invalid"
223reverseDependencies :: ModuleGraph -> M.Map ModuleName [ModuleName]
224reverseDependencies g = combine [ (dep, mn) | (mn, deps) <- g, dep <- deps ]
225 where
226 combine :: (Ord a) => [(a, b)] -> M.Map a [b]
227 combine = M.fromList . map ((fst . head) &&& map snd) . groupBy ((==) `on` fst) . sortBy (compare `on` fst)
229-- |
230-- Add an import declaration for a module if it does not already explicitly import it.
231--
232addDefaultImport :: ModuleName -> Module -> Module
233addDefaultImport toImport m@(Module mn decls exps) =
234 if isExistingImport `any` decls || mn == toImport then m
235 else Module mn (ImportDeclaration toImport Unqualified Nothing : decls) exps
236 where
237 isExistingImport (ImportDeclaration mn' _ _) | mn' == toImport = True
238 isExistingImport (PositionedDeclaration _ d) = isExistingImport d
239 isExistingImport _ = False
241importPrim :: Module -> Module
242importPrim = addDefaultImport (ModuleName [ProperName C.prim])
244importPrelude :: Module -> Module
245importPrelude = addDefaultImport (ModuleName [ProperName C.prelude])
247prelude :: String
248prelude = BU.toString $(embedFile "prelude/prelude.purs")