git.iko.soy/rowtype-yoga/purescript-native
on e84d52b help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
343 lines 16 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckModule
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import Data.List (nub, (\\), find, intercalate)
30import Data.Monoid ((<>))
31import Data.Foldable (for_)
32import qualified Data.Map as M
34import Control.Monad.State
35import Control.Monad.Error
37import Language.PureScript.Types
38import Language.PureScript.Names
39import Language.PureScript.Kinds
40import Language.PureScript.Declarations
41import Language.PureScript.TypeClassDictionaries
42import Language.PureScript.Environment
43import Language.PureScript.Errors
45addDataType :: ModuleName -> DataDeclType -> ProperName -> [(String, Maybe Kind)] -> [(ProperName, [Type])] -> Kind -> Check ()
46addDataType moduleName dtype name args dctors ctorKind = do
47 env <- getEnv
48 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, DataType args dctors) (types env) }
49 forM_ dctors $ \(dctor, tys) ->
50 rethrow (strMsg ("Error in data constructor " ++ show dctor) <>) $
51 addDataConstructor moduleName dtype name (map fst args) dctor tys
53addDataConstructor :: ModuleName -> DataDeclType -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
54addDataConstructor moduleName dtype name args dctor tys = do
55 env <- getEnv
56 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
57 let dctorTy = foldr function retTy tys
58 let polyType = mkForAll args dctorTy
59 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (dtype, name, polyType) (dataConstructors env) }
61addTypeSynonym :: ModuleName -> ProperName -> [(String, Maybe Kind)] -> Type -> Kind -> Check ()
62addTypeSynonym moduleName name args ty kind = do
63 env <- getEnv
64 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
65 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
67valueIsNotDefined :: ModuleName -> Ident -> Check ()
68valueIsNotDefined moduleName name = do
69 env <- getEnv
70 case M.lookup (moduleName, name) (names env) of
71 Just _ -> throwError . strMsg $ show name ++ " is already defined"
72 Nothing -> return ()
74addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
75addValue moduleName name ty nameKind = do
76 env <- getEnv
77 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind, Defined) (names env) })
79addTypeClass :: ModuleName -> ProperName -> [(String, Maybe Kind)] -> [(Qualified ProperName, [Type])] -> [Declaration] -> Check ()
80addTypeClass moduleName pn args implies ds =
81 let members = map toPair ds in
82 modify $ \st -> st { checkEnv = (checkEnv st) { typeClasses = M.insert (Qualified (Just moduleName) pn) (args, members, implies) (typeClasses . checkEnv $ st) } }
83 where
84 toPair (TypeDeclaration ident ty) = (ident, ty)
85 toPair (PositionedDeclaration _ d) = toPair d
86 toPair _ = error "Invalid declaration in TypeClassDeclaration"
88addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
89addTypeClassDictionaries entries =
90 let mentries = M.fromList [ ((canonicalizeDictionary entry, mn), entry) | entry@TypeClassDictionaryInScope{ tcdName = Qualified mn _ } <- entries ]
91 in modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = (typeClassDictionaries . checkEnv $ st) `M.union` mentries } }
93checkDuplicateTypeArguments :: [String] -> Check ()
94checkDuplicateTypeArguments args = for_ firstDup $ \dup ->
95 throwError . strMsg $ "Duplicate type argument '" ++ dup ++ "'"
96 where
97 firstDup :: Maybe String
98 firstDup = listToMaybe $ args \\ nub args
100checkTypeClassInstance :: ModuleName -> Type -> Check ()
101checkTypeClassInstance _ (TypeVar _) = return ()
102checkTypeClassInstance _ (TypeConstructor ctor) = do
103 env <- getEnv
104 when (ctor `M.member` typeSynonyms env) . throwError . strMsg $ "Type synonym instances are disallowed"
105 return ()
106checkTypeClassInstance m (TypeApp t1 t2) = checkTypeClassInstance m t1 >> checkTypeClassInstance m t2
107checkTypeClassInstance _ ty = throwError $ mkErrorStack "Type class instance head is invalid." (Just (TypeError ty))
109-- |
110-- Type check all declarations in a module
111--
112-- At this point, many declarations will have been desugared, but it is still necessary to
113--
114-- * Kind-check all types and add them to the @Environment@
115--
116-- * Type-check all values and add them to the @Environment@
117--
118-- * Bring type class instances into scope
119--
120-- * Process module imports
121--
122typeCheckAll :: Maybe ModuleName -> ModuleName -> [DeclarationRef] -> [Declaration] -> Check [Declaration]
123typeCheckAll mainModuleName moduleName exps = go
124 where
125 go :: [Declaration] -> Check [Declaration]
126 go [] = return []
127 go (DataDeclaration dtype name args dctors : rest) = do
128 rethrow (strMsg ("Error in type constructor " ++ show name) <>) $ do
129 when (dtype == Newtype) $ checkNewtype dctors
130 checkDuplicateTypeArguments $ map fst args
131 ctorKind <- kindsOf True moduleName name args (concatMap snd dctors)
132 let args' = args `withKinds` ctorKind
133 addDataType moduleName dtype name args' dctors ctorKind
134 ds <- go rest
135 return $ DataDeclaration dtype name args dctors : ds
136 where
137 checkNewtype :: [(ProperName, [Type])] -> Check ()
138 checkNewtype [(_, [_])] = return ()
139 checkNewtype [(_, _)] = throwError . strMsg $ "newtypes constructors must have a single argument"
140 checkNewtype _ = throwError . strMsg $ "newtypes must have a single constructor"
141 go (d@(DataBindingGroupDeclaration tys) : rest) = do
142 rethrow (strMsg "Error in data binding group" <>) $ do
143 let syns = mapMaybe toTypeSynonym tys
144 let dataDecls = mapMaybe toDataDecl tys
145 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(_, name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
146 forM_ (zip dataDecls data_ks) $ \((dtype, name, args, dctors), ctorKind) -> do
147 checkDuplicateTypeArguments $ map fst args
148 let args' = args `withKinds` ctorKind
149 addDataType moduleName dtype name args' dctors ctorKind
150 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) -> do
151 checkDuplicateTypeArguments $ map fst args
152 let args' = args `withKinds` kind
153 addTypeSynonym moduleName name args' ty kind
154 ds <- go rest
155 return $ d : ds
156 where
157 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
158 toTypeSynonym (PositionedDeclaration _ d') = toTypeSynonym d'
159 toTypeSynonym _ = Nothing
160 toDataDecl (DataDeclaration dtype nm args dctors) = Just (dtype, nm, args, dctors)
161 toDataDecl (PositionedDeclaration _ d') = toDataDecl d'
162 toDataDecl _ = Nothing
163 go (TypeSynonymDeclaration name args ty : rest) = do
164 rethrow (strMsg ("Error in type synonym " ++ show name) <>) $ do
165 checkDuplicateTypeArguments $ map fst args
166 kind <- kindsOf False moduleName name args [ty]
167 let args' = args `withKinds` kind
168 addTypeSynonym moduleName name args' ty kind
169 ds <- go rest
170 return $ TypeSynonymDeclaration name args ty : ds
171 go (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
172 go (ValueDeclaration name nameKind [] (Right val) : rest) = do
173 d <- rethrow (strMsg ("Error in declaration " ++ show name) <>) $ do
174 valueIsNotDefined moduleName name
175 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
176 addValue moduleName name ty nameKind
177 return $ ValueDeclaration name nameKind [] $ Right val'
178 ds <- go rest
179 return $ d : ds
180 go (ValueDeclaration{} : _) = error "Binders were not desugared"
181 go (BindingGroupDeclaration vals : rest) = do
182 d <- rethrow (strMsg ("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals)) <>) $ do
183 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
184 valueIsNotDefined moduleName name
185 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
186 vals' <- forM [ (name, val, nameKind, ty)
187 | (name, nameKind, _) <- vals
188 , (name', (val, ty)) <- tys
189 , name == name'
190 ] $ \(name, val, nameKind, ty) -> do
191 addValue moduleName name ty nameKind
192 return (name, nameKind, val)
193 return $ BindingGroupDeclaration vals'
194 ds <- go rest
195 return $ d : ds
196 go (d@(ExternDataDeclaration name kind) : rest) = do
197 env <- getEnv
198 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, ExternData) (types env) }
199 ds <- go rest
200 return $ d : ds
201 go (d@(ExternDeclaration importTy name _ ty) : rest) = do
202 rethrow (strMsg ("Error in foreign import declaration " ++ show name) <>) $ do
203 env <- getEnv
204 kind <- kindOf moduleName ty
205 guardWith (strMsg "Expected kind *") $ kind == Star
206 case M.lookup (moduleName, name) (names env) of
207 Just _ -> throwError . strMsg $ show name ++ " is already defined"
208 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy, Defined) (names env) })
209 ds <- go rest
210 return $ d : ds
211 go (d@(FixityDeclaration _ name) : rest) = do
212 ds <- go rest
213 env <- getEnv
214 guardWith (strMsg ("Fixity declaration with no binding: " ++ name)) $ M.member (moduleName, Op name) $ names env
215 return $ d : ds
216 go (d@(ImportDeclaration importedModule _ _) : rest) = do
217 tcds <- getTypeClassDictionaries
218 let instances = filter (\tcd -> let Qualified (Just mn) _ = tcdName tcd in importedModule == mn) tcds
219 addTypeClassDictionaries [ tcd { tcdName = Qualified (Just moduleName) ident, tcdType = TCDAlias (canonicalizeDictionary tcd) }
220 | tcd <- instances
221 , tcdExported tcd
222 , let (Qualified _ ident) = tcdName tcd
223 ]
224 ds <- go rest
225 return $ d : ds
226 go (d@(TypeClassDeclaration pn args implies tys) : rest) = do
227 addTypeClass moduleName pn args implies tys
228 ds <- go rest
229 return $ d : ds
230 go (TypeInstanceDeclaration dictName deps className tys _ : rest) =
231 go (ExternInstanceDeclaration dictName deps className tys : rest)
232 go (d@(ExternInstanceDeclaration dictName deps className tys) : rest) = do
233 mapM_ (checkTypeClassInstance moduleName) tys
234 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
235 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular isInstanceExported]
236 ds <- go rest
237 return $ d : ds
238 where
239 isInstanceExported :: Bool
240 isInstanceExported = any exportsInstance exps
242 exportsInstance :: DeclarationRef -> Bool
243 exportsInstance (TypeInstanceRef name) | name == dictName = True
244 exportsInstance (PositionedDeclarationRef _ r) = exportsInstance r
245 exportsInstance _ = False
247 go (PositionedDeclaration pos d : rest) =
248 rethrowWithPosition pos $ do
249 (d' : rest') <- go (d : rest)
250 return (PositionedDeclaration pos d' : rest')
252 -- |
253 -- This function adds the argument kinds for a type constructor so that they may appear in the externs file,
254 -- extracted from the kind of the type constructor itself.
255 --
256 withKinds :: [(String, Maybe Kind)] -> Kind -> [(String, Maybe Kind)]
257 withKinds [] _ = []
258 withKinds (s@(_, Just _ ):ss) (FunKind _ k) = s : withKinds ss k
259 withKinds ( (s, Nothing):ss) (FunKind k1 k2) = (s, Just k1) : withKinds ss k2
260 withKinds _ _ = error "Invalid arguments to peelKinds"
262-- |
263-- Type check an entire module and ensure all types and classes defined within the module that are
264-- required by exported members are also exported.
265--
266typeCheckModule :: Maybe ModuleName -> Module -> Check Module
267typeCheckModule _ (Module _ _ Nothing) = error "exports should have been elaborated"
268typeCheckModule mainModuleName (Module mn decls (Just exps)) = do
269 modify (\s -> s { checkCurrentModule = Just mn })
270 decls' <- typeCheckAll mainModuleName mn exps decls
271 forM_ exps $ \e -> do
272 checkTypesAreExported e
273 checkClassMembersAreExported e
274 checkClassesAreExported e
275 return $ Module mn decls' (Just exps)
276 where
278 checkMemberExport :: (Show a) => String -> (Type -> [a]) -> (a -> Bool) -> DeclarationRef -> Check ()
279 checkMemberExport thing extract test (ValueRef name) = do
280 ty <- lookupVariable mn (Qualified (Just mn) name)
281 case find test (extract ty) of
282 Just hiddenType -> throwError . strMsg $
283 "Error in module '" ++ show mn ++ "':\n\
284 \Exporting declaration '" ++ show name ++ "' requires " ++ thing ++ " '" ++ show hiddenType ++ "' to be exported as well"
285 Nothing -> return ()
286 checkMemberExport _ _ _ _ = return ()
288 -- Check that all the type constructors defined in the current module that appear in member types
289 -- have also been exported from the module
290 checkTypesAreExported :: DeclarationRef -> Check ()
291 checkTypesAreExported = checkMemberExport "type" findTcons isTconHidden
292 where
293 findTcons :: Type -> [ProperName]
294 findTcons = everythingOnTypes (++) go
295 where
296 go (TypeConstructor (Qualified (Just mn') name)) | mn' == mn = [name]
297 go _ = []
298 isTconHidden :: ProperName -> Bool
299 isTconHidden tyName = all go exps
300 where
301 go (TypeRef tyName' _) = tyName' /= tyName
302 go _ = True
304 -- Check that all the classes defined in the current module that appear in member types have also
305 -- been exported from the module
306 checkClassesAreExported :: DeclarationRef -> Check ()
307 checkClassesAreExported = checkMemberExport "class" findClasses isClassHidden
308 where
309 findClasses :: Type -> [ProperName]
310 findClasses = everythingOnTypes (++) go
311 where
312 go (ConstrainedType cs _) = mapMaybe (extractCurrentModuleClass . fst) cs
313 go _ = []
314 extractCurrentModuleClass :: Qualified ProperName -> Maybe ProperName
315 extractCurrentModuleClass (Qualified (Just mn') name) | mn == mn' = Just name
316 extractCurrentModuleClass _ = Nothing
317 isClassHidden :: ProperName -> Bool
318 isClassHidden clsName = all go exps
319 where
320 go (TypeClassRef clsName') = clsName' /= clsName
321 go _ = True
323 checkClassMembersAreExported :: DeclarationRef -> Check ()
324 checkClassMembersAreExported (TypeClassRef name) = do
325 let members = ValueRef `map` head (mapMaybe findClassMembers decls)
326 let missingMembers = members \\ exps
327 unless (null missingMembers) $
328 throwError . strMsg $
329 "Error in module '" ++ show mn ++ "':\n\
330 \Class '" ++ show name ++ "' is exported but is missing member exports for '" ++ intercalate "', '" (map (show . runValueRef) missingMembers) ++ "'"
331 where
332 runValueRef :: DeclarationRef -> Ident
333 runValueRef (ValueRef refName) = refName
334 runValueRef _ = error "non-ValueRef passed to runValueRef"
335 findClassMembers :: Declaration -> Maybe [Ident]
336 findClassMembers (TypeClassDeclaration name' _ _ ds) | name == name' = Just $ map extractMemberName ds
337 findClassMembers (PositionedDeclaration _ d) = findClassMembers d
338 findClassMembers _ = Nothing
339 extractMemberName :: Declaration -> Ident
340 extractMemberName (PositionedDeclaration _ d) = extractMemberName d
341 extractMemberName (TypeDeclaration memberName _) = memberName
342 extractMemberName _ = error "Unexpected declaration in typeclass member list"
343 checkClassMembersAreExported _ = return ()