git.iko.soy/rowtype-yoga/purescript-native
on f04ca54 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
198 lines 9.8 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
33import Language.PureScript.Types
34import Language.PureScript.Names
35import Language.PureScript.Values
36import Language.PureScript.Kinds
37import Language.PureScript.Declarations
38import Language.PureScript.Environment
40addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
41addDataType moduleName name args dctors ctorKind = do
42 env <- getEnv
43 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, DataType args dctors) (types env) }
44 forM_ dctors $ \(dctor, tys) ->
45 rethrow (("Error in data constructor " ++ show dctor ++ ":\n") ++) $
46 addDataConstructor moduleName name args dctor tys
48addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
49addDataConstructor moduleName name args dctor tys = do
50 env <- getEnv
51 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
52 let dctorTy = foldr function retTy tys
53 let polyType = mkForAll args dctorTy
54 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (name, polyType) (dataConstructors env) }
56addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
57addTypeSynonym moduleName name args ty kind = do
58 env <- getEnv
59 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
60 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
62valueIsNotDefined :: ModuleName -> Ident -> Check ()
63valueIsNotDefined moduleName name = do
64 env <- getEnv
65 case M.lookup (moduleName, name) (names env) of
66 Just _ -> throwError $ show name ++ " is already defined"
67 Nothing -> return ()
69addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
70addValue moduleName name ty nameKind = do
71 env <- getEnv
72 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind) (names env) })
74addTypeClass :: ModuleName -> ProperName -> [String] -> [Declaration] -> Check ()
75addTypeClass moduleName pn args ds =
76 let members = map (\(TypeDeclaration ident ty) -> (ident, ty)) ds in
77 modify $ \st -> st { checkEnv = (checkEnv st) { typeClasses = M.insert (Qualified (Just moduleName) pn) (args, members) (typeClasses . checkEnv $ st) } }
79addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
80addTypeClassDictionaries entries =
81 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
83checkTypeClassInstance :: ModuleName -> Type -> Check ()
84checkTypeClassInstance _ (TypeVar _) = return ()
85checkTypeClassInstance _ (TypeConstructor ctor) = do
86 env <- getEnv
87 when (ctor `M.member` typeSynonyms env) $ throwError "Type synonym instances are disallowed"
88 return ()
89checkTypeClassInstance m (TypeApp ty (TypeVar _)) = checkTypeClassInstance m ty
90checkTypeClassInstance _ _ = throwError "Type class instance must be of the form T a1 ... an"
92-- |
93-- Type check all declarations in a module
94--
95-- At this point, many declarations will have been desugared, but it is still necessary to
96--
97-- * Kind-check all types and add them to the @Environment@
98--
99-- * Type-check all values and add them to the @Environment@
100--
101-- * Bring type class instances into scope
102--
103-- * Process module imports
104--
105typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
106typeCheckAll _ _ [] = return []
107typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
108 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
109 ctorKind <- kindsOf moduleName name args (concatMap snd dctors)
110 addDataType moduleName name args dctors ctorKind
111 ds <- typeCheckAll mainModuleName moduleName rest
112 return $ d : ds
113typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
114 rethrow ("Error in data binding group:\n" ++) $ do
115 let syns = mapMaybe toTypeSynonym tys
116 let dataDecls = mapMaybe toDataDecl tys
117 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
118 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) ->
119 addDataType moduleName name args dctors ctorKind
120 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) ->
121 addTypeSynonym moduleName name args ty kind
122 ds <- typeCheckAll mainModuleName moduleName rest
123 return $ d : ds
124 where
125 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
126 toTypeSynonym _ = Nothing
127 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
128 toDataDecl _ = Nothing
129typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
130 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
131 kind <- kindsOf moduleName name args [ty]
132 addTypeSynonym moduleName name args ty kind
133 ds <- typeCheckAll mainModuleName moduleName rest
134 return $ d : ds
135typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
136typeCheckAll mainModuleName moduleName (ValueDeclaration name nameKind [] Nothing val : rest) = do
137 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
138 valueIsNotDefined moduleName name
139 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
140 addValue moduleName name ty nameKind
141 return $ ValueDeclaration name nameKind [] Nothing val'
142 ds <- typeCheckAll mainModuleName moduleName rest
143 return $ d : ds
144typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
145typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
146 d <- rethrow (("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals) ++ ":\n") ++) $ do
147 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
148 valueIsNotDefined moduleName name
149 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
150 vals' <- forM (zipWith (\(name, nameKind, _) (_, (val, ty)) -> (name, val, nameKind, ty)) vals tys) $ \(name, val, nameKind, ty) -> do
151 addValue moduleName name ty nameKind
152 return (name, nameKind, val)
153 return $ BindingGroupDeclaration vals'
154 ds <- typeCheckAll mainModuleName moduleName rest
155 return $ d : ds
156typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
157 env <- getEnv
158 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, ExternData) (types env) }
159 ds <- typeCheckAll mainModuleName moduleName rest
160 return $ d : ds
161typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
162 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
163 env <- getEnv
164 kind <- kindOf moduleName ty
165 guardWith "Expected kind *" $ kind == Star
166 case M.lookup (moduleName, name) (names env) of
167 Just _ -> throwError $ show name ++ " is already defined"
168 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
169 ds <- typeCheckAll mainModuleName moduleName rest
170 return $ d : ds
171typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
172 ds <- typeCheckAll mainModuleName moduleName rest
173 env <- getEnv
174 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
175 return $ d : ds
176typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName _) : rest) = do
177 env <- getEnv
178 let instances = filter (\tcd ->
179 let Qualified (Just mn) _ = tcdName tcd in
180 moduleName == mn && tcdType tcd == TCDRegular
181 ) (typeClassDictionaries env)
182 forM_ instances $ \tcd -> do
183 let (Qualified _ ident) = tcdName tcd
184 addTypeClassDictionaries [tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (tcdName tcd) }]
185 ds <- typeCheckAll mainModuleName currentModule rest
186 return $ d : ds
187typeCheckAll mainModuleName moduleName (d@(TypeClassDeclaration pn args tys) : rest) = do
188 addTypeClass moduleName pn args tys
189 ds <- typeCheckAll mainModuleName moduleName rest
190 return $ d : ds
191typeCheckAll mainModuleName moduleName (TypeInstanceDeclaration dictName deps className tys _ : rest) = do
192 typeCheckAll mainModuleName moduleName (ExternInstanceDeclaration dictName deps className tys : rest)
193typeCheckAll mainModuleName moduleName (d@(ExternInstanceDeclaration dictName deps className tys) : rest) = do
194 mapM_ (checkTypeClassInstance moduleName) tys
195 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
196 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
197 ds <- typeCheckAll mainModuleName moduleName rest
198 return $ d : ds