git.iko.soy/rowtype-yoga/purescript-native
on f8da0b9 help sign in
rowtype-yoga/purescript-native/src/Language/PureScript/TypeChecker.hs
196 lines 9.8 kB history raw
1-----------------------------------------------------------------------------
2--
3-- Module : Language.PureScript.TypeChecker
4-- Copyright : (c) Phil Freeman 2013
5-- License : MIT
6--
7-- Maintainer : Phil Freeman <paf31@cantab.net>
8-- Stability : experimental
9-- Portability :
10--
11-- |
12-- The top-level type checker, which checks all declarations in a module.
13--
14-----------------------------------------------------------------------------
16{-# LANGUAGE FlexibleInstances #-}
18module Language.PureScript.TypeChecker (
19 module T,
20 typeCheckAll
21) where
23import Language.PureScript.TypeChecker.Monad as T
24import Language.PureScript.TypeChecker.Kinds as T
25import Language.PureScript.TypeChecker.Types as T
26import Language.PureScript.TypeChecker.Synonyms as T
28import Data.Maybe
29import qualified Data.Map as M
30import Control.Monad.State
31import Control.Monad.Error
33import Language.PureScript.Types
34import Language.PureScript.Names
35import Language.PureScript.Values
36import Language.PureScript.Kinds
37import Language.PureScript.Declarations
38import Language.PureScript.Environment
39import Language.PureScript.Pretty.Types
41addDataType :: ModuleName -> ProperName -> [String] -> [(ProperName, [Type])] -> Kind -> Check ()
42addDataType moduleName name args dctors ctorKind = do
43 env <- getEnv
44 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (ctorKind, DataType args dctors) (types env) }
45 forM_ dctors $ \(dctor, tys) ->
46 rethrow (("Error in data constructor " ++ show dctor ++ ":\n") ++) $
47 addDataConstructor moduleName name args dctor tys
49addDataConstructor :: ModuleName -> ProperName -> [String] -> ProperName -> [Type] -> Check ()
50addDataConstructor moduleName name args dctor tys = do
51 env <- getEnv
52 let retTy = foldl TypeApp (TypeConstructor (Qualified (Just moduleName) name)) (map TypeVar args)
53 let dctorTy = foldr function retTy tys
54 let polyType = mkForAll args dctorTy
55 putEnv $ env { dataConstructors = M.insert (Qualified (Just moduleName) dctor) (name, polyType) (dataConstructors env) }
57addTypeSynonym :: ModuleName -> ProperName -> [String] -> Type -> Kind -> Check ()
58addTypeSynonym moduleName name args ty kind = do
59 env <- getEnv
60 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, TypeSynonym) (types env)
61 , typeSynonyms = M.insert (Qualified (Just moduleName) name) (args, ty) (typeSynonyms env) }
63valueIsNotDefined :: ModuleName -> Ident -> Check ()
64valueIsNotDefined moduleName name = do
65 env <- getEnv
66 case M.lookup (moduleName, name) (names env) of
67 Just _ -> throwError $ show name ++ " is already defined"
68 Nothing -> return ()
70addValue :: ModuleName -> Ident -> Type -> NameKind -> Check ()
71addValue moduleName name ty nameKind = do
72 env <- getEnv
73 putEnv (env { names = M.insert (moduleName, name) (ty, nameKind) (names env) })
75addTypeClass :: ModuleName -> ProperName -> [String] -> [Declaration] -> Check ()
76addTypeClass moduleName pn args ds =
77 let members = map (\(TypeDeclaration ident ty) -> (ident, ty)) ds in
78 modify $ \st -> st { checkEnv = (checkEnv st) { typeClasses = M.insert (Qualified (Just moduleName) pn) (args, members) (typeClasses . checkEnv $ st) } }
80addTypeClassDictionaries :: [TypeClassDictionaryInScope] -> Check ()
81addTypeClassDictionaries entries =
82 modify $ \st -> st { checkEnv = (checkEnv st) { typeClassDictionaries = entries ++ (typeClassDictionaries . checkEnv $ st) } }
84checkTypeClassInstance :: ModuleName -> Type -> Check ()
85checkTypeClassInstance _ (TypeVar _) = return ()
86checkTypeClassInstance _ (TypeConstructor ctor) = do
87 env <- getEnv
88 when (ctor `M.member` typeSynonyms env) $ throwError "Type synonym instances are disallowed"
89 return ()
90checkTypeClassInstance m (TypeApp t1 t2) = checkTypeClassInstance m t1 >> checkTypeClassInstance m t2
91checkTypeClassInstance _ ty = throwError $ "Type class instance head is invalid: " ++ prettyPrintType ty
93-- |
94-- Type check all declarations in a module
95--
96-- At this point, many declarations will have been desugared, but it is still necessary to
97--
98-- * Kind-check all types and add them to the @Environment@
99--
100-- * Type-check all values and add them to the @Environment@
101--
102-- * Bring type class instances into scope
103--
104-- * Process module imports
105--
106typeCheckAll :: Maybe ModuleName -> ModuleName -> [Declaration] -> Check [Declaration]
107typeCheckAll _ _ [] = return []
108typeCheckAll mainModuleName moduleName (d@(DataDeclaration name args dctors) : rest) = do
109 rethrow (("Error in type constructor " ++ show name ++ ":\n") ++) $ do
110 ctorKind <- kindsOf moduleName name args (concatMap snd dctors)
111 addDataType moduleName name args dctors ctorKind
112 ds <- typeCheckAll mainModuleName moduleName rest
113 return $ d : ds
114typeCheckAll mainModuleName moduleName (d@(DataBindingGroupDeclaration tys) : rest) = do
115 rethrow ("Error in data binding group:\n" ++) $ do
116 let syns = mapMaybe toTypeSynonym tys
117 let dataDecls = mapMaybe toDataDecl tys
118 (syn_ks, data_ks) <- kindsOfAll moduleName syns (map (\(name, args, dctors) -> (name, args, concatMap snd dctors)) dataDecls)
119 forM_ (zip dataDecls data_ks) $ \((name, args, dctors), ctorKind) ->
120 addDataType moduleName name args dctors ctorKind
121 forM_ (zip syns syn_ks) $ \((name, args, ty), kind) ->
122 addTypeSynonym moduleName name args ty kind
123 ds <- typeCheckAll mainModuleName moduleName rest
124 return $ d : ds
125 where
126 toTypeSynonym (TypeSynonymDeclaration nm args ty) = Just (nm, args, ty)
127 toTypeSynonym _ = Nothing
128 toDataDecl (DataDeclaration nm args dctors) = Just (nm, args, dctors)
129 toDataDecl _ = Nothing
130typeCheckAll mainModuleName moduleName (d@(TypeSynonymDeclaration name args ty) : rest) = do
131 rethrow (("Error in type synonym " ++ show name ++ ":\n") ++) $ do
132 kind <- kindsOf moduleName name args [ty]
133 addTypeSynonym moduleName name args ty kind
134 ds <- typeCheckAll mainModuleName moduleName rest
135 return $ d : ds
136typeCheckAll _ _ (TypeDeclaration _ _ : _) = error "Type declarations should have been removed"
137typeCheckAll mainModuleName moduleName (ValueDeclaration name nameKind [] Nothing val : rest) = do
138 d <- rethrow (("Error in declaration " ++ show name ++ ":\n") ++) $ do
139 valueIsNotDefined moduleName name
140 [(_, (val', ty))] <- typesOf mainModuleName moduleName [(name, val)]
141 addValue moduleName name ty nameKind
142 return $ ValueDeclaration name nameKind [] Nothing val'
143 ds <- typeCheckAll mainModuleName moduleName rest
144 return $ d : ds
145typeCheckAll _ _ (ValueDeclaration{} : _) = error "Binders were not desugared"
146typeCheckAll mainModuleName moduleName (BindingGroupDeclaration vals : rest) = do
147 d <- rethrow (("Error in binding group " ++ show (map (\(ident, _, _) -> ident) vals) ++ ":\n") ++) $ do
148 forM_ (map (\(ident, _, _) -> ident) vals) $ \name ->
149 valueIsNotDefined moduleName name
150 tys <- typesOf mainModuleName moduleName $ map (\(ident, _, ty) -> (ident, ty)) vals
151 vals' <- forM (zipWith (\(name, nameKind, _) (_, (val, ty)) -> (name, val, nameKind, ty)) vals tys) $ \(name, val, nameKind, ty) -> do
152 addValue moduleName name ty nameKind
153 return (name, nameKind, val)
154 return $ BindingGroupDeclaration vals'
155 ds <- typeCheckAll mainModuleName moduleName rest
156 return $ d : ds
157typeCheckAll mainModuleName moduleName (d@(ExternDataDeclaration name kind) : rest) = do
158 env <- getEnv
159 putEnv $ env { types = M.insert (Qualified (Just moduleName) name) (kind, ExternData) (types env) }
160 ds <- typeCheckAll mainModuleName moduleName rest
161 return $ d : ds
162typeCheckAll mainModuleName moduleName (d@(ExternDeclaration importTy name _ ty) : rest) = do
163 rethrow (("Error in foreign import declaration " ++ show name ++ ":\n") ++) $ do
164 env <- getEnv
165 kind <- kindOf moduleName ty
166 guardWith "Expected kind *" $ kind == Star
167 case M.lookup (moduleName, name) (names env) of
168 Just _ -> throwError $ show name ++ " is already defined"
169 Nothing -> putEnv (env { names = M.insert (moduleName, name) (ty, Extern importTy) (names env) })
170 ds <- typeCheckAll mainModuleName moduleName rest
171 return $ d : ds
172typeCheckAll mainModuleName moduleName (d@(FixityDeclaration _ name) : rest) = do
173 ds <- typeCheckAll mainModuleName moduleName rest
174 env <- getEnv
175 guardWith ("Fixity declaration with no binding: " ++ name) $ M.member (moduleName, Op name) $ names env
176 return $ d : ds
177typeCheckAll mainModuleName currentModule (d@(ImportDeclaration moduleName _ _) : rest) = do
178 env <- getEnv
179 let instances = filter (\tcd -> let Qualified (Just mn) _ = tcdName tcd in moduleName == mn) (typeClassDictionaries env)
180 forM_ instances $ \tcd -> do
181 let (Qualified _ ident) = tcdName tcd
182 addTypeClassDictionaries [tcd { tcdName = Qualified (Just currentModule) ident, tcdType = TCDAlias (canonicalizeDictionary tcd) }]
183 ds <- typeCheckAll mainModuleName currentModule rest
184 return $ d : ds
185typeCheckAll mainModuleName moduleName (d@(TypeClassDeclaration pn args tys) : rest) = do
186 addTypeClass moduleName pn args tys
187 ds <- typeCheckAll mainModuleName moduleName rest
188 return $ d : ds
189typeCheckAll mainModuleName moduleName (TypeInstanceDeclaration dictName deps className tys _ : rest) = do
190 typeCheckAll mainModuleName moduleName (ExternInstanceDeclaration dictName deps className tys : rest)
191typeCheckAll mainModuleName moduleName (d@(ExternInstanceDeclaration dictName deps className tys) : rest) = do
192 mapM_ (checkTypeClassInstance moduleName) tys
193 forM_ deps $ mapM_ (checkTypeClassInstance moduleName) . snd
194 addTypeClassDictionaries [TypeClassDictionaryInScope (Qualified (Just moduleName) dictName) className tys (Just deps) TCDRegular]
195 ds <- typeCheckAll mainModuleName moduleName rest
196 return $ d : ds