@@ -0,0 +1,1063 @@
1+-----------------------------------------------------------------------------
2+--
3+-- Module : Language.PureScript.TypeChecker.Types
4+-- Copyright : (c) Phil Freeman 2013
5+-- License : MIT
6+--
7+-- Maintainer : Phil Freeman <paf31@cantab.net>
8+-- Stability : experimental
9+-- Portability :
10+--
11+-- |
12+-- This module implements the type checker
13+--
14+-----------------------------------------------------------------------------
15+
16+{-# OPTIONS_GHC -fno-warn-orphans #-}
17+{-# LANGUAGE FlexibleInstances #-}
18+{-# LANGUAGE FlexibleContexts #-}
19+{-# LANGUAGE MultiParamTypeClasses #-}
20+
21+module Language.PureScript.TypeChecker.Types (
22+ typesOf
23+) where
24+
25+{-
26+ The following functions represent the corresponding type checking judgements:
27+
28+ infer
29+ Synthesize a type for a value
30+
31+ check
32+ Check a value has a given type
33+
34+ checkProperties
35+ Check an object with a given type contains specified properties
36+
37+ checkFunctionApplication
38+ Check a function of a given type returns a value of another type when applied to its arguments
39+
40+ subsumes
41+ Check a type subsumes another type
42+-}
43+
44+import Data.List
45+import Data.Maybe (maybeToList, isNothing, isJust, fromMaybe)
46+import qualified Data.Data as D
47+import Data.Generics
48+ (everythingWithContext, mkM, everywhereM, everything, mkT,
49+ something, everywhere, mkQ)
50+import Data.Generics.Extras
51+
52+import Language.PureScript.Declarations
53+import Language.PureScript.Types
54+import Language.PureScript.Kinds
55+import Language.PureScript.Names
56+import Language.PureScript.TypeClassDictionaries
57+import Language.PureScript.TypeChecker.Monad
58+import Language.PureScript.TypeChecker.Kinds
59+import Language.PureScript.TypeChecker.Synonyms
60+import Language.PureScript.Pretty
61+import Language.PureScript.Environment
62+import Language.PureScript.Errors
63+import qualified Language.PureScript.Constants as C
64+
65+import Control.Monad.State
66+import Control.Monad.Error
67+import Control.Monad.Unify
68+
69+import Control.Applicative
70+import Control.Arrow (Arrow(..))
71+
72+import qualified Data.Map as M
73+import Data.Function (on)
74+import Data.Ord (comparing)
75+import Data.Monoid ((<>))
76+
77+instance Partial Type where
78+ unknown = TUnknown
79+ isUnknown (TUnknown u) = Just u
80+ isUnknown _ = Nothing
81+
82+instance Unifiable Check Type where
83+ (=?=) = unifyTypes
84+
85+-- |
86+-- Unify two types, updating the current substitution
87+--
88+unifyTypes :: Type -> Type -> UnifyT Type Check ()
89+unifyTypes t1 t2 = rethrow (mkErrorStack ("Error unifying type " ++ prettyPrintType t1 ++ " with type " ++ prettyPrintType t2) Nothing <>) $
90+ unifyTypes' t1 t2
91+ where
92+ unifyTypes' (TUnknown u1) (TUnknown u2) | u1 == u2 = return ()
93+ unifyTypes' (TUnknown u) t = u =:= t
94+ unifyTypes' t (TUnknown u) = u =:= t
95+ unifyTypes' (SaturatedTypeSynonym name args) ty = do
96+ ty1 <- introduceSkolemScope <=< expandTypeSynonym name $ args
97+ ty1 `unifyTypes` ty
98+ unifyTypes' ty s@(SaturatedTypeSynonym _ _) = s `unifyTypes` ty
99+ unifyTypes' (ForAll ident1 ty1 sc1) (ForAll ident2 ty2 sc2) =
100+ case (sc1, sc2) of
101+ (Just sc1', Just sc2') -> do
102+ sko <- newSkolemConstant
103+ let sk1 = skolemize ident1 sko sc1' ty1
104+ let sk2 = skolemize ident2 sko sc2' ty2
105+ sk1 `unifyTypes` sk2
106+ _ -> error "Skolemized type variable was not given a scope"
107+ unifyTypes' (ForAll ident ty1 (Just sc)) ty2 = do
108+ sko <- newSkolemConstant
109+ let sk = skolemize ident sko sc ty1
110+ sk `unifyTypes` ty2
111+ unifyTypes' ForAll{} _ = throwError . strMsg $ "Skolem variable scope is unspecified"
112+ unifyTypes' ty f@ForAll{} = f `unifyTypes` ty
113+ unifyTypes' (TypeVar v1) (TypeVar v2) | v1 == v2 = return ()
114+ unifyTypes' (TypeConstructor c1) (TypeConstructor c2) =
115+ guardWith (strMsg ("Cannot unify " ++ show c1 ++ " with " ++ show c2 ++ ".")) (c1 == c2)
116+ unifyTypes' (TypeApp t3 t4) (TypeApp t5 t6) = do
117+ t3 `unifyTypes` t5
118+ t4 `unifyTypes` t6
119+ unifyTypes' (Skolem s1 _) (Skolem s2 _) | s1 == s2 = return ()
120+ unifyTypes' r1@RCons{} r2 = unifyRows r1 r2
121+ unifyTypes' r1 r2@RCons{} = unifyRows r1 r2
122+ unifyTypes' r1@REmpty r2 = unifyRows r1 r2
123+ unifyTypes' r1 r2@REmpty = unifyRows r1 r2
124+ unifyTypes' t@(ConstrainedType _ _) _ = throwError . strMsg $ "Attempted to unify a constrained type " ++ prettyPrintType t ++ " with another type."
125+ unifyTypes' t3 t4@(ConstrainedType _ _) = unifyTypes' t4 t3
126+ unifyTypes' t3 t4 = throwError . strMsg $ "Cannot unify " ++ prettyPrintType t3 ++ " with " ++ prettyPrintType t4 ++ "."
127+
128+-- |
129+-- Unify two rows, updating the current substitution
130+--
131+-- Common labels are first identified, and unified. Remaining labels and types are unified with a
132+-- trailing row unification variable, if appropriate, otherwise leftover labels result in a unification
133+-- error.
134+--
135+unifyRows :: Type -> Type -> UnifyT Type Check ()
136+unifyRows r1 r2 =
137+ let
138+ (s1, r1') = rowToList r1
139+ (s2, r2') = rowToList r2
140+ int = [ (t1, t2) | (name, t1) <- s1, (name', t2) <- s2, name == name' ]
141+ sd1 = [ (name, t1) | (name, t1) <- s1, name `notElem` map fst s2 ]
142+ sd2 = [ (name, t2) | (name, t2) <- s2, name `notElem` map fst s1 ]
143+ in do
144+ forM_ int (uncurry (=?=))
145+ unifyRows' sd1 r1' sd2 r2'
146+ where
147+ unifyRows' :: [(String, Type)] -> Type -> [(String, Type)] -> Type -> UnifyT Type Check ()
148+ unifyRows' [] (TUnknown u) sd r = u =:= rowFromList (sd, r)
149+ unifyRows' sd r [] (TUnknown u) = u =:= rowFromList (sd, r)
150+ unifyRows' ((name, ty):row) r others u@(TUnknown un) = do
151+ occursCheck un ty
152+ forM_ row $ \(_, t) -> occursCheck un t
153+ u' <- fresh
154+ u =?= RCons name ty u'
155+ unifyRows' row r others u'
156+ unifyRows' [] REmpty [] REmpty = return ()
157+ unifyRows' [] (TypeVar v1) [] (TypeVar v2) | v1 == v2 = return ()
158+ unifyRows' [] (Skolem s1 _) [] (Skolem s2 _) | s1 == s2 = return ()
159+ unifyRows' sd3 r3 sd4 r4 = throwError . strMsg $ "Cannot unify (" ++ prettyPrintRow (rowFromList (sd3, r3)) ++ ") with (" ++ prettyPrintRow (rowFromList (sd4, r4)) ++ ")"
160+
161+-- |
162+-- Infer the types of multiple mutually-recursive values, and return elaborated values including
163+-- type class dictionaries and type annotations.
164+--
165+typesOf :: Maybe ModuleName -> ModuleName -> [(Ident, Value)] -> Check [(Ident, (Value, Type))]
166+typesOf mainModuleName moduleName vals = do
167+ tys <- fmap tidyUp . liftUnify $ do
168+ (es, dict, untypedDict) <- typeDictionaryForBindingGroup moduleName vals
169+ forM es $ \e -> do
170+ triple@(_, (_, ty)) <- typeForBindingGroupElement moduleName e dict untypedDict
171+ -- If --main is enabled, need to check that `main` has type Eff eff a for some eff, a
172+ when (Just moduleName == mainModuleName && fst e == Ident C.main) $ do
173+ [eff, a] <- replicateM 2 fresh
174+ ty =?= TypeApp (TypeApp (TypeConstructor (Qualified (Just (ModuleName [ProperName "Control", ProperName "Monad", ProperName "Eff"])) (ProperName "Eff"))) eff) a
175+ return triple
176+
177+ forM tys $ \(ident, (val, ty)) -> do
178+ -- Replace type class dictionary placeholders with actual dictionaries
179+ val' <- replaceTypeClassDictionaries moduleName val
180+ -- Check skolem variables did not escape their scope
181+ skolemEscapeCheck val'
182+ -- Remove type synonyms placeholders, remove duplicate row fields, and replace
183+ -- top-level unification variables with named type variables.
184+ let val'' = overTypes (desaturateAllTypeSynonyms . setifyAll) val'
185+ ty' = varIfUnknown . desaturateAllTypeSynonyms . setifyAll $ ty
186+ return (ident, (val'', ty'))
187+ where
188+ -- Apply the substitution that was returned from runUnify to both types and (type-annotated) values
189+ tidyUp (ts, sub) = map (\(i, (val, ty)) -> (i, (overTypes (sub $?) val, sub $? ty))) ts
190+
191+typeDictionaryForBindingGroup :: ModuleName -> [(Ident, Value)] -> UnifyT Type Check ([(Ident, (Value, Maybe (Type, Bool)))], M.Map (ModuleName, Ident) (Type, NameKind), [(Ident, Type)])
192+typeDictionaryForBindingGroup moduleName vals = do
193+ let
194+ -- Map each declaration to a name/value pair, with an optional type, if the declaration is typed
195+ es = map isTyped vals
196+ -- Filter the typed and untyped declarations
197+ typed = filter (isJust . snd . snd) es
198+ untyped = filter (isNothing . snd . snd) es
199+ -- Make a map of names to typed declarations
200+ typedDict = map (\(ident, (_, Just (ty, _))) -> (ident, ty)) typed
201+
202+ -- Create fresh unification variables for the types of untyped declarations
203+ untypedNames <- replicateM (length untyped) fresh
204+
205+ let
206+ -- Make a map of names to the unification variables of untyped declarations
207+ untypedDict = zip (map fst untyped) untypedNames
208+ -- Create the dictionary of all name/type pairs, which will be added to the environment during type checking
209+ dict = M.fromList (map (\(ident, ty) -> ((moduleName, ident), (ty, LocalVariable))) $ typedDict ++ untypedDict)
210+ return (es, dict, untypedDict)
211+
212+typeForBindingGroupElement :: ModuleName -> (Ident, (Value, Maybe (Type, Bool))) -> M.Map (ModuleName, Ident) (Type, NameKind) -> [(Ident, Type)] -> UnifyT Type Check (Ident, (Value, Type))
213+typeForBindingGroupElement moduleName e@(_, (val, _)) dict untypedDict = do
214+ -- If the declaration is a function, it has access to other values in the binding group.
215+ -- If not, the generated code might fail at runtime since those values might be undefined.
216+ let dict' = if isFunction val then dict else M.empty
217+ case e of
218+ -- Typed declarations
219+ (ident, (val', Just (ty, checkType))) -> do
220+ -- Kind check
221+ kind <- liftCheck $ kindOf moduleName ty
222+ guardWith (strMsg $ "Expected type of kind *, was " ++ prettyPrintKind kind) $ kind == Star
223+ -- Check the type with the new names in scope
224+ ty' <- introduceSkolemScope <=< replaceAllTypeSynonyms $ ty
225+ val'' <- bindNames dict' $ if checkType
226+ then TypedValue True <$> check val' ty' <*> pure ty'
227+ else return (TypedValue False val' ty')
228+ return (ident, (val'', ty'))
229+ -- Untyped declarations
230+ (ident, (val', Nothing)) -> do
231+ -- Infer the type with the new names in scope
232+ TypedValue _ val'' ty <- bindNames dict' $ infer val'
233+ ty =?= fromMaybe (error "name not found in dictionary") (lookup ident untypedDict)
234+ return (ident, (TypedValue True val'' ty, ty))
235+
236+-- |
237+-- Check if a value introduces a function
238+--
239+isFunction :: Value -> Bool
240+isFunction (Abs _ _) = True
241+isFunction (TypedValue _ val _) = isFunction val
242+isFunction (PositionedValue _ val) = isFunction val
243+isFunction _ = False
244+
245+-- |
246+-- Check if a value contains a type annotation
247+--
248+isTyped :: (Ident, Value) -> (Ident, (Value, Maybe (Type, Bool)))
249+isTyped (name, TypedValue checkType value ty) = (name, (value, Just (ty, checkType)))
250+isTyped (name, value) = (name, (value, Nothing))
251+
252+-- |
253+-- Map a function over type annotations appearing inside a value
254+--
255+overTypes :: (Type -> Type) -> Value -> Value
256+overTypes f = everywhere (mkT f)
257+
258+-- |
259+-- Replace type class dictionary placeholders with inferred type class dictionaries
260+--
261+replaceTypeClassDictionaries :: ModuleName -> Value -> Check Value
262+replaceTypeClassDictionaries mn = everywhereM' (mkM go)
263+ where
264+ go (TypeClassDictionary trySuperclasses constraint dicts) = do
265+ env <- getEnv
266+ let dicts' = fromMaybe (typeClassDictionaries env) dicts
267+ entails env mn dicts' constraint trySuperclasses
268+ go other = return other
269+
270+-- |
271+-- A simplified representation of expressions which are used to represent type
272+-- class dictionaries at runtime, which can be compared for equality
273+--
274+data DictionaryValue
275+ -- |
276+ -- A dictionary which is brought into scope by a local constraint
277+ --
278+ = LocalDictionaryValue (Qualified Ident)
279+ -- |
280+ -- A dictionary which is brought into scope by an instance declaration
281+ --
282+ | GlobalDictionaryValue (Qualified Ident)
283+ -- |
284+ -- A dictionary which depends on other dictionaries
285+ --
286+ | DependentDictionaryValue (Qualified Ident) [DictionaryValue]
287+ -- |
288+ -- A subclass dictionary
289+ --
290+ | SubclassDictionaryValue DictionaryValue Integer
291+ deriving (Show, Ord, Eq)
292+
293+-- |
294+-- Check that the current set of type class dictionaries entail the specified type class goal, and, if so,
295+-- return a type class dictionary reference.
296+--
297+entails :: Environment -> ModuleName -> [TypeClassDictionaryInScope] -> (Qualified ProperName, [Type]) -> Bool -> Check Value
298+entails env moduleName context = solve (sortedNubBy canonicalizeDictionary (filter filterModule context))
299+ where
300+ sortedNubBy :: (Ord k) => (v -> k) -> [v] -> [v]
301+ sortedNubBy f vs = M.elems (M.fromList (map (f &&& id) vs))
302+
303+ -- Filter out type dictionaries which are in scope in the current module
304+ filterModule :: TypeClassDictionaryInScope -> Bool
305+ filterModule (TypeClassDictionaryInScope { tcdName = Qualified (Just mn) _ }) | mn == moduleName = True
306+ filterModule (TypeClassDictionaryInScope { tcdName = Qualified Nothing _ }) = True
307+ filterModule _ = False
308+
309+ solve context' (className, tys) trySuperclasses =
310+ case chooseSimplestDictionaries (go className tys) of
311+ [] -> throwError . strMsg $ "No instance found for " ++ show className ++ " " ++ unwords (map prettyPrintTypeAtom tys)
312+ [dict] -> return (dictionaryValueToValue dict)
313+ _ -> throwError . strMsg $ "Overlapping instances found for " ++ show className ++ " " ++ unwords (map prettyPrintTypeAtom tys)
314+ where
315+ go className' tys' =
316+ -- Look for regular type instances
317+ [ mkDictionary (canonicalizeDictionary tcd) args
318+ | tcd <- context'
319+ -- Make sure the type class name matches the one we are trying to satisfy
320+ , className' == tcdClassName tcd
321+ -- Make sure the type unifies with the type in the type instance definition
322+ , subst <- maybeToList . (>>= verifySubstitution) . fmap concat $ zipWithM (typeHeadsAreEqual moduleName env) tys' (tcdInstanceTypes tcd)
323+ -- Solve any necessary subgoals
324+ , args <- solveSubgoals subst (tcdDependencies tcd) ] ++
325+
326+ -- Look for implementations via superclasses
327+ [ SubclassDictionaryValue suDict index
328+ | trySuperclasses
329+ , (subclassName, (args, _, implies)) <- M.toList (typeClasses env)
330+ -- Try each superclass
331+ , (index, (superclass, suTyArgs)) <- zip [0..] implies
332+ -- Make sure the type class name matches the superclass name
333+ , className' == superclass
334+ -- Make sure the types unify with the types in the superclass implication
335+ , subst <- maybeToList . (>>= verifySubstitution) . fmap concat $ zipWithM (typeHeadsAreEqual moduleName env) tys' suTyArgs
336+ -- Finally, satisfy the subclass constraint
337+ , suDict <- go subclassName (map (applySubst subst . TypeVar) args) ]
338+
339+ -- Create dictionaries for subgoals which still need to be solved by calling go recursively
340+ -- E.g. the goal (Show a, Show b) => Show (Either a b) can be satisfied if the current type
341+ -- unifies with Either a b, and we can satisfy the subgoals Show a and Show b recursively.
342+ solveSubgoals :: [(String, Type)] -> Maybe [(Qualified ProperName, [Type])] -> [Maybe [DictionaryValue]]
343+ solveSubgoals _ Nothing = return Nothing
344+ solveSubgoals subst (Just subgoals) = do
345+ dict <- mapM (uncurry go . second (map (replaceAllTypeVars subst))) subgoals
346+ return $ Just dict
347+ -- Make a dictionary from subgoal dictionaries by applying the correct function
348+ mkDictionary :: Qualified Ident -> Maybe [DictionaryValue] -> DictionaryValue
349+ mkDictionary fnName Nothing = LocalDictionaryValue fnName
350+ mkDictionary fnName (Just []) = GlobalDictionaryValue fnName
351+ mkDictionary fnName (Just dicts) = DependentDictionaryValue fnName dicts
352+ -- Turn a DictionaryValue into a Value
353+ dictionaryValueToValue :: DictionaryValue -> Value
354+ dictionaryValueToValue (LocalDictionaryValue fnName) = Var fnName
355+ dictionaryValueToValue (GlobalDictionaryValue fnName) = App (Var fnName) (ObjectLiteral [])
356+ dictionaryValueToValue (DependentDictionaryValue fnName dicts) = foldl App (Var fnName) (map dictionaryValueToValue dicts)
357+ dictionaryValueToValue (SubclassDictionaryValue dict index) =
358+ App (App (App (Var (Qualified (Just (ModuleName [ProperName C.prelude])) (Ident (C.!!))))
359+ (Accessor C.__superclasses (dictionaryValueToValue dict)))
360+ (NumericLiteral (Left index)))
361+ (ObjectLiteral [])
362+ -- Ensure that a substitution is valid
363+ verifySubstitution :: [(String, Type)] -> Maybe [(String, Type)]
364+ verifySubstitution subst = do
365+ let grps = groupBy ((==) `on` fst) subst
366+ guard (all (pairwise (unifiesWith env) . map snd) grps)
367+ return $ map head grps
368+ -- Apply a substitution to a type
369+ applySubst :: [(String, Type)] -> Type -> Type
370+ applySubst subst = everywhere (mkT replace)
371+ where
372+ replace t@(TypeVar v) = fromMaybe t $ lookup v subst
373+ replace other = other
374+ -- Choose the simplest DictionaryValues from a list of candidates
375+ -- The reason for this function is as follows:
376+ -- When considering overlapping instances, we don't want to consider the same dictionary
377+ -- to be an overlap of itself when obtained as a superclass of another class.
378+ -- Observing that we probably don't want to select a superclass instance when an instance
379+ -- is available directly, and that there is no way for a superclass instance to actually
380+ -- introduce an overlap that wouldn't have been there already, we simply remove dictionaries
381+ -- obtained as superclass instances if there are simpler instances available.
382+ chooseSimplestDictionaries :: [DictionaryValue] -> [DictionaryValue]
383+ chooseSimplestDictionaries ds = case filter isSimpleDictionaryValue ds of
384+ [] -> ds
385+ simple -> simple
386+ isSimpleDictionaryValue SubclassDictionaryValue{} = False
387+ isSimpleDictionaryValue (DependentDictionaryValue _ ds) = all isSimpleDictionaryValue ds
388+ isSimpleDictionaryValue _ = True
389+
390+-- |
391+-- Check all values in a list pairwise match a predicate
392+--
393+pairwise :: (a -> a -> Bool) -> [a] -> Bool
394+pairwise _ [] = True
395+pairwise _ [_] = True
396+pairwise p (x : xs) = all (p x) xs && pairwise p xs
397+
398+-- |
399+-- Check that two types unify
400+--
401+unifiesWith :: Environment -> Type -> Type -> Bool
402+unifiesWith _ (TUnknown _) _ = True
403+unifiesWith _ _ (TUnknown _) = True
404+unifiesWith _ (Skolem s1 _) (Skolem s2 _) | s1 == s2 = True
405+unifiesWith _ (TypeVar v1) (TypeVar v2) | v1 == v2 = True
406+unifiesWith _ (TypeConstructor c1) (TypeConstructor c2) | c1 == c2 = True
407+unifiesWith e (TypeApp h1 t1) (TypeApp h2 t2) = unifiesWith e h1 h2 && unifiesWith e t1 t2
408+unifiesWith e (SaturatedTypeSynonym name args) t2 =
409+ case expandTypeSynonym' e name args of
410+ Left _ -> False
411+ Right t1 -> unifiesWith e t1 t2
412+unifiesWith e t1 t2@(SaturatedTypeSynonym _ _) = unifiesWith e t2 t1
413+unifiesWith _ _ _ = False
414+
415+-- |
416+-- Check whether the type heads of two types are equal (for the purposes of type class dictionary lookup),
417+-- and return a substitution from type variables to types which makes the type heads unify.
418+--
419+typeHeadsAreEqual :: ModuleName -> Environment -> Type -> Type -> Maybe [(String, Type)]
420+typeHeadsAreEqual _ _ (Skolem s1 _) (Skolem s2 _) | s1 == s2 = Just []
421+typeHeadsAreEqual _ _ t (TypeVar v) = Just [(v, t)]
422+typeHeadsAreEqual _ _ (TypeConstructor c1) (TypeConstructor c2) | c1 == c2 = Just []
423+typeHeadsAreEqual m e (TypeApp h1 t1) (TypeApp h2 t2) = (++) <$> typeHeadsAreEqual m e h1 h2 <*> typeHeadsAreEqual m e t1 t2
424+typeHeadsAreEqual m e (SaturatedTypeSynonym name args) t2 = case expandTypeSynonym' e name args of
425+ Left _ -> Nothing
426+ Right t1 -> typeHeadsAreEqual m e t1 t2
427+typeHeadsAreEqual _ _ _ _ = Nothing
428+
429+-- |
430+-- Ensure skolem variables do not escape their scope
431+--
432+skolemEscapeCheck :: Value -> Check ()
433+skolemEscapeCheck (TypedValue False _ _) = return ()
434+skolemEscapeCheck root@TypedValue{} =
435+ -- Every skolem variable is created when a ForAll type is skolemized.
436+ -- This determines the scope of that skolem variable, which is copied from the SkolemScope
437+ -- field of the ForAll constructor.
438+ -- We traverse the tree top-down, and collect any SkolemScopes introduced by ForAlls.
439+ -- If a Skolem is encountered whose SkolemScope is not in the current list, we have found
440+ -- an escaped skolem variable.
441+ case everythingWithContext [] (++) (mkQ ((,) []) go) root of
442+ [] -> return ()
443+ ((binding, val) : _) -> throwError $ mkErrorStack ("Rigid/skolem type variable " ++ maybe "" (("bound by " ++) . prettyPrintValue) binding ++ " has escaped.") (Just (ValueError val))
444+ where
445+ go :: Value -> [(SkolemScope, Value)] -> ([(Maybe Value, Value)], [(SkolemScope, Value)])
446+ go val@(TypedValue _ _ (ForAll _ _ (Just sco))) scos = ([], (sco, val) : scos)
447+ go val@(TypedValue _ _ ty) scos = case collectSkolems ty \\ map fst scos of
448+ (sco : _) -> ([(findBindingScope sco, val)], scos)
449+ _ -> ([], scos)
450+ where
451+ collectSkolems :: Type -> [SkolemScope]
452+ collectSkolems = nub . everything (++) (mkQ [] collect)
453+ where
454+ collect (Skolem _ scope) = [scope]
455+ collect _ = []
456+ go _ scos = ([], scos)
457+ findBindingScope :: SkolemScope -> Maybe Value
458+ findBindingScope sco = something (mkQ Nothing go') root
459+ where
460+ go' val@(TypedValue _ _ (ForAll _ _ (Just sco'))) | sco == sco' = Just val
461+ go' _ = Nothing
462+skolemEscapeCheck val = throwError $ mkErrorStack "Untyped value passed to skolemEscapeCheck" (Just (ValueError val))
463+
464+-- |
465+-- Ensure a row contains no duplicate labels
466+--
467+setify :: Type -> Type
468+setify = rowFromList . first (M.toList . M.fromList) . rowToList
469+
470+-- |
471+-- \"Setify\" all rows occuring inside a value
472+--
473+setifyAll :: (D.Data d) => d -> d
474+setifyAll = everywhere (mkT setify)
475+
476+-- |
477+-- Replace outermost unsolved unification variables with named type variables
478+--
479+varIfUnknown :: Type -> Type
480+varIfUnknown ty =
481+ let unks = nub $ unknowns ty
482+ toName = (:) 't' . show
483+ ty' = everywhere (mkT typeToVar) ty
484+ typeToVar :: Type -> Type
485+ typeToVar (TUnknown (Unknown u)) = TypeVar (toName u)
486+ typeToVar t = t
487+ in mkForAll (sort . map (toName . runUnknown) $ unks) ty'
488+
489+-- |
490+-- Remove any ForAlls and ConstrainedType constructors in a type by introducing new unknowns
491+-- or TypeClassDictionary values.
492+--
493+-- This is necessary during type checking to avoid unifying a polymorphic type with a
494+-- unification variable.
495+--
496+instantiatePolyTypeWithUnknowns :: Value -> Type -> UnifyT Type Check (Value, Type)
497+instantiatePolyTypeWithUnknowns val (ForAll ident ty _) = do
498+ ty' <- replaceVarWithUnknown ident ty
499+ instantiatePolyTypeWithUnknowns val ty'
500+instantiatePolyTypeWithUnknowns val (ConstrainedType constraints ty) = do
501+ dicts <- getTypeClassDictionaries
502+ (_, ty') <- instantiatePolyTypeWithUnknowns (error "Types under a constraint cannot themselves be constrained") ty
503+ return (foldl App val (map (flip (TypeClassDictionary True) (Just dicts)) constraints), ty')
504+instantiatePolyTypeWithUnknowns val ty = return (val, ty)
505+
506+-- |
507+-- Replace a single type variable with a new unification variable
508+--
509+replaceVarWithUnknown :: String -> Type -> UnifyT Type Check Type
510+replaceVarWithUnknown ident ty = do
511+ tu <- fresh
512+ return $ replaceTypeVars ident tu ty
513+
514+-- |
515+-- Replace fully applied type synonyms with the @SaturatedTypeSynonym@ data constructor, which helps generate
516+-- better error messages during unification.
517+--
518+replaceAllTypeSynonyms' :: (D.Data d) => Environment -> d -> Either String d
519+replaceAllTypeSynonyms' env d =
520+ let
521+ syns = map (\(name, (args, _)) -> (name, length args)) . M.toList $ typeSynonyms env
522+ in
523+ saturateAllTypeSynonyms syns d
524+
525+replaceAllTypeSynonyms :: (Error e, Functor m, Monad m, MonadState CheckState m, MonadError e m) => (D.Data d) => d -> m d
526+replaceAllTypeSynonyms d = do
527+ env <- getEnv
528+ either (throwError . strMsg) return $ replaceAllTypeSynonyms' env d
529+
530+-- |
531+-- \"Desaturate\" @SaturatedTypeSynonym@s
532+--
533+desaturateAllTypeSynonyms :: (D.Data d) => d -> d
534+desaturateAllTypeSynonyms = everywhere (mkT replaceSaturatedTypeSynonym)
535+ where
536+ replaceSaturatedTypeSynonym (SaturatedTypeSynonym name args) = foldl TypeApp (TypeConstructor name) args
537+ replaceSaturatedTypeSynonym t = t
538+
539+-- |
540+-- Replace a type synonym and its arguments with the aliased type
541+--
542+expandTypeSynonym' :: Environment -> Qualified ProperName -> [Type] -> Either String Type
543+expandTypeSynonym' env name args =
544+ case M.lookup name (typeSynonyms env) of
545+ Just (synArgs, body) -> do
546+ let repl = replaceAllTypeVars (zip synArgs args) body
547+ replaceAllTypeSynonyms' env repl
548+ Nothing -> error "Type synonym was not defined"
549+
550+expandTypeSynonym :: (Error e, Functor m, Monad m, MonadState CheckState m, MonadError e m) => Qualified ProperName -> [Type] -> m Type
551+expandTypeSynonym name args = do
552+ env <- getEnv
553+ either (throwError . strMsg) return $ expandTypeSynonym' env name args
554+
555+expandAllTypeSynonyms :: (Error e, Functor m, Monad m, MonadState CheckState m, MonadError e m) => Type -> m Type
556+expandAllTypeSynonyms = everywhereM' (mkM go)
557+ where
558+ go (SaturatedTypeSynonym name args) = expandTypeSynonym name args
559+ go other = return other
560+
561+-- |
562+-- Ensure a set of property names and value does not contain duplicate labels
563+--
564+ensureNoDuplicateProperties :: (Error e, MonadError e m) => [(String, Value)] -> m ()
565+ensureNoDuplicateProperties ps = guardWith (strMsg "Duplicate property names") $ length (nub . map fst $ ps) == length ps
566+
567+-- |
568+-- Infer a type for a value, rethrowing any error to provide a more useful error message
569+--
570+infer :: Value -> UnifyT Type Check Value
571+infer val = rethrow (mkErrorStack "Error inferring type of value" (Just (ValueError val)) <>) $ infer' val
572+
573+-- |
574+-- Infer a type for a value
575+--
576+infer' :: Value -> UnifyT Type Check Value
577+infer' v@(NumericLiteral _) = return $ TypedValue True v tyNumber
578+infer' v@(StringLiteral _) = return $ TypedValue True v tyString
579+infer' v@(BooleanLiteral _) = return $ TypedValue True v tyBoolean
580+infer' (ArrayLiteral vals) = do
581+ ts <- mapM infer vals
582+ els <- fresh
583+ forM_ ts $ \(TypedValue _ _ t) -> els =?= TypeApp tyArray t
584+ return $ TypedValue True (ArrayLiteral ts) els
585+infer' (ObjectLiteral ps) = do
586+ ensureNoDuplicateProperties ps
587+ ts <- mapM (infer . snd) ps
588+ let fields = zipWith (\name (TypedValue _ _ t) -> (name, t)) (map fst ps) ts
589+ ty = TypeApp tyObject $ rowFromList (fields, REmpty)
590+ return $ TypedValue True (ObjectLiteral (zip (map fst ps) ts)) ty
591+infer' (ObjectUpdate o ps) = do
592+ ensureNoDuplicateProperties ps
593+ row <- fresh
594+ newVals <- zipWith (\(name, _) t -> (name, t)) ps <$> mapM (infer . snd) ps
595+ let newTys = map (\(name, TypedValue _ _ ty) -> (name, ty)) newVals
596+ oldTys <- zip (map fst ps) <$> replicateM (length ps) fresh
597+ let oldTy = TypeApp tyObject $ rowFromList (oldTys, row)
598+ o' <- TypedValue True <$> check o oldTy <*> pure oldTy
599+ return $ TypedValue True (ObjectUpdate o' newVals) $ TypeApp tyObject $ rowFromList (newTys, row)
600+infer' (Accessor prop val) = do
601+ typed@(TypedValue _ _ objTy) <- infer val
602+ propTy <- inferProperty objTy prop
603+ case propTy of
604+ Nothing -> do
605+ field <- fresh
606+ rest <- fresh
607+ _ <- subsumes Nothing objTy (TypeApp tyObject (RCons prop field rest))
608+ return $ TypedValue True (Accessor prop typed) field
609+ Just ty -> return $ TypedValue True (Accessor prop typed) ty
610+infer' (Abs (Left arg) ret) = do
611+ ty <- fresh
612+ Just moduleName <- checkCurrentModule <$> get
613+ bindLocalVariables moduleName [(arg, ty)] $ do
614+ body@(TypedValue _ _ bodyTy) <- infer' ret
615+ return $ TypedValue True (Abs (Left arg) body) $ function ty bodyTy
616+infer' (Abs (Right _) _) = error "Binder was not desugared"
617+infer' (App f arg) = do
618+ f'@(TypedValue _ _ ft) <- infer f
619+ (ret, app) <- checkFunctionApplication f' ft arg Nothing
620+ return $ TypedValue True app ret
621+infer' (Var var) = do
622+ Just moduleName <- checkCurrentModule <$> get
623+ ty <- introduceSkolemScope <=< replaceAllTypeSynonyms <=< lookupVariable moduleName $ var
624+ case ty of
625+ ConstrainedType constraints ty' -> do
626+ dicts <- getTypeClassDictionaries
627+ return $ TypedValue True (foldl App (Var var) (map (flip (TypeClassDictionary True) (Just dicts)) constraints)) ty'
628+ _ -> return $ TypedValue True (Var var) ty
629+infer' v@(Constructor c) = do
630+ env <- getEnv
631+ case M.lookup c (dataConstructors env) of
632+ Nothing -> throwError . strMsg $ "Constructor " ++ show c ++ " is undefined"
633+ Just (_, ty) -> do ty' <- introduceSkolemScope <=< replaceAllTypeSynonyms $ ty
634+ return $ TypedValue True v ty'
635+infer' (Case vals binders) = do
636+ ts <- mapM infer vals
637+ ret <- fresh
638+ binders' <- checkBinders (map (\(TypedValue _ _ t) -> t) ts) ret binders
639+ return $ TypedValue True (Case ts binders') ret
640+infer' (IfThenElse cond th el) = do
641+ cond' <- check cond tyBoolean
642+ v2@(TypedValue _ _ t2) <- infer th
643+ v3@(TypedValue _ _ t3) <- infer el
644+ t2 =?= t3
645+ return $ TypedValue True (IfThenElse cond' v2 v3) t2
646+infer' (Let ds val) = do
647+ (ds', val'@(TypedValue _ _ valTy)) <- inferLetBinding [] ds val infer
648+ return $ TypedValue True (Let ds' val') valTy
649+infer' (TypedValue checkType val ty) = do
650+ Just moduleName <- checkCurrentModule <$> get
651+ kind <- liftCheck $ kindOf moduleName ty
652+ guardWith (strMsg $ "Expected type of kind *, was " ++ prettyPrintKind kind) $ kind == Star
653+ ty' <- introduceSkolemScope <=< replaceAllTypeSynonyms $ ty
654+ val' <- if checkType then check val ty' else return val
655+ return $ TypedValue True val' ty'
656+infer' (PositionedValue pos val) = rethrowWithPosition pos $ infer' val
657+infer' _ = error "Invalid argument to infer"
658+
659+inferLetBinding :: [Declaration] -> [Declaration] -> Value -> (Value -> UnifyT Type Check Value) -> UnifyT Type Check ([Declaration], Value)
660+inferLetBinding seen [] ret j = (,) seen <$> j ret
661+inferLetBinding seen (ValueDeclaration ident nameKind [] Nothing val : rest) ret j = do
662+ valTy <- fresh
663+ Just moduleName <- checkCurrentModule <$> get
664+ let dict = if isFunction val then M.singleton (moduleName, ident) (valTy, nameKind) else M.empty
665+ TypedValue _ val' valTy' <- bindNames dict $ infer val
666+ valTy =?= valTy'
667+ bindNames (M.singleton (moduleName, ident) (valTy', nameKind)) $ inferLetBinding (seen ++ [ValueDeclaration ident nameKind [] Nothing val']) rest ret j
668+inferLetBinding seen (BindingGroupDeclaration ds : rest) ret j = do
669+ Just moduleName <- checkCurrentModule <$> get
670+ (es, dict, untypedDict) <- typeDictionaryForBindingGroup moduleName (map (\(i, _, v) -> (i, v)) ds)
671+ ds' <- forM es $ \e -> do
672+ (ident, (val', _)) <- typeForBindingGroupElement moduleName e dict untypedDict
673+ return $ (ident, LocalVariable, val')
674+ bindNames dict $ inferLetBinding (seen ++ [BindingGroupDeclaration ds']) rest ret j
675+inferLetBinding seen (PositionedDeclaration pos d : ds) ret j = do
676+ ((d' : ds'), val') <- inferLetBinding seen (d : ds) ret j
677+ return (PositionedDeclaration pos d' : ds', val')
678+inferLetBinding _ _ _ _ = error "Invalid argument to inferLetBinding"
679+
680+-- |
681+-- Infer the type of a property inside a record with a given type
682+--
683+inferProperty :: Type -> String -> UnifyT Type Check (Maybe Type)
684+inferProperty (TypeApp obj row) prop | obj == tyObject = do
685+ let (props, _) = rowToList row
686+ return $ lookup prop props
687+inferProperty (SaturatedTypeSynonym name args) prop = do
688+ replaced <- introduceSkolemScope <=< expandTypeSynonym name $ args
689+ inferProperty replaced prop
690+inferProperty (ForAll ident ty _) prop = do
691+ replaced <- replaceVarWithUnknown ident ty
692+ inferProperty replaced prop
693+inferProperty _ _ = return Nothing
694+
695+-- |
696+-- Infer the types of variables brought into scope by a binder
697+--
698+inferBinder :: Type -> Binder -> UnifyT Type Check (M.Map Ident Type)
699+inferBinder _ NullBinder = return M.empty
700+inferBinder val (StringBinder _) = val =?= tyString >> return M.empty
701+inferBinder val (NumberBinder _) = val =?= tyNumber >> return M.empty
702+inferBinder val (BooleanBinder _) = val =?= tyBoolean >> return M.empty
703+inferBinder val (VarBinder name) = return $ M.singleton name val
704+inferBinder val (ConstructorBinder ctor binders) = do
705+ env <- getEnv
706+ case M.lookup ctor (dataConstructors env) of
707+ Just (_, ty) -> do
708+ (_, fn) <- instantiatePolyTypeWithUnknowns (error "Data constructor types cannot contain constraints") ty
709+ fn' <- replaceAllTypeSynonyms fn
710+ go binders fn'
711+ where
712+ go [] ty' = do
713+ _ <- subsumes Nothing val ty'
714+ return M.empty
715+ go (binder : binders') (TypeApp (TypeApp t obj) ret) | t == tyFunction =
716+ M.union <$> inferBinder obj binder <*> go binders' ret
717+ go _ _ = throwError . strMsg $ "Wrong number of arguments to constructor " ++ show ctor
718+ _ -> throwError . strMsg $ "Constructor " ++ show ctor ++ " is not defined"
719+inferBinder val (ObjectBinder props) = do
720+ row <- fresh
721+ rest <- fresh
722+ m1 <- inferRowProperties row rest props
723+ val =?= TypeApp tyObject row
724+ return m1
725+ where
726+ inferRowProperties :: Type -> Type -> [(String, Binder)] -> UnifyT Type Check (M.Map Ident Type)
727+ inferRowProperties nrow row [] = nrow =?= row >> return M.empty
728+ inferRowProperties nrow row ((name, binder):binders) = do
729+ propTy <- fresh
730+ m1 <- inferBinder propTy binder
731+ m2 <- inferRowProperties nrow (RCons name propTy row) binders
732+ return $ m1 `M.union` m2
733+inferBinder val (ArrayBinder binders) = do
734+ el <- fresh
735+ m1 <- M.unions <$> mapM (inferBinder el) binders
736+ val =?= TypeApp tyArray el
737+ return m1
738+inferBinder val (ConsBinder headBinder tailBinder) = do
739+ el <- fresh
740+ m1 <- inferBinder el headBinder
741+ m2 <- inferBinder val tailBinder
742+ val =?= TypeApp tyArray el
743+ return $ m1 `M.union` m2
744+inferBinder val (NamedBinder name binder) = do
745+ m <- inferBinder val binder
746+ return $ M.insert name val m
747+inferBinder val (PositionedBinder pos binder) =
748+ rethrowWithPosition pos $ inferBinder val binder
749+
750+-- |
751+-- Check the types of the return values in a set of binders in a case statement
752+--
753+checkBinders :: [Type] -> Type -> [CaseAlternative] -> UnifyT Type Check [CaseAlternative]
754+checkBinders _ _ [] = return []
755+checkBinders nvals ret (CaseAlternative binders grd val : bs) = do
756+ Just moduleName <- checkCurrentModule <$> get
757+ m1 <- M.unions <$> zipWithM inferBinder nvals binders
758+ r <- bindLocalVariables moduleName (M.toList m1) $ do
759+ val' <- TypedValue True <$> check val ret <*> pure ret
760+ case grd of
761+ Nothing -> return $ CaseAlternative binders Nothing val'
762+ Just g -> do
763+ g' <- check g tyBoolean
764+ return $ CaseAlternative binders (Just g') val'
765+ rs <- checkBinders nvals ret bs
766+ return $ r : rs
767+
768+-- |
769+-- Generate a new skolem constant
770+--
771+newSkolemConstant :: UnifyT Type Check Int
772+newSkolemConstant = runUnknown <$> fresh'
773+
774+-- |
775+-- Generate a new skolem scope
776+--
777+newSkolemScope :: UnifyT Type Check SkolemScope
778+newSkolemScope = SkolemScope . runUnknown <$> fresh'
779+
780+-- |
781+-- Skolemize a type variable by replacing its instances with fresh skolem constants
782+--
783+skolemize :: String -> Int -> SkolemScope -> Type -> Type
784+skolemize ident sko scope = replaceTypeVars ident (Skolem sko scope)
785+
786+-- |
787+-- Introduce skolem scope at every occurence of a ForAll
788+--
789+introduceSkolemScope :: Type -> UnifyT Type Check Type
790+introduceSkolemScope = everywhereM (mkM go)
791+ where
792+ go (ForAll ident ty Nothing) = ForAll ident ty <$> (Just <$> newSkolemScope)
793+ go other = return other
794+
795+-- |
796+-- Check the type of a value, rethrowing errors to provide a better error message
797+--
798+check :: Value -> Type -> UnifyT Type Check Value
799+check val ty = rethrow (mkErrorStack errorMessage (Just (ValueError val)) <>) $ check' val ty
800+ where
801+ errorMessage =
802+ "Error checking type of term " ++
803+ prettyPrintValue val ++
804+ " against type " ++
805+ prettyPrintType ty
806+
807+-- |
808+-- Check the type of a value
809+--
810+check' :: Value -> Type -> UnifyT Type Check Value
811+check' val (ForAll ident ty _) = do
812+ scope <- newSkolemScope
813+ sko <- newSkolemConstant
814+ let sk = skolemize ident sko scope ty
815+ val' <- check val sk
816+ return $ TypedValue True val' (ForAll ident ty (Just scope))
817+check' val t@(ConstrainedType constraints ty) = do
818+ dictNames <- forM constraints $ \(Qualified _ (ProperName className), _) -> do
819+ n <- liftCheck freshDictionaryName
820+ return $ Ident $ "__dict_" ++ className ++ "_" ++ show n
821+ val' <- withTypeClassDictionaries (zipWith (\name (className, instanceTy) ->
822+ TypeClassDictionaryInScope name className instanceTy Nothing TCDRegular) (map (Qualified Nothing) dictNames)
823+ constraints) $ check val ty
824+ return $ TypedValue True (foldr (Abs . Left) val' dictNames) t
825+check' val (SaturatedTypeSynonym name args) = do
826+ ty <- introduceSkolemScope <=< expandTypeSynonym name $ args
827+ check val ty
828+check' val u@(TUnknown _) = do
829+ val'@(TypedValue _ _ ty) <- infer val
830+ -- Don't unify an unknown with an inferred polytype
831+ (val'', ty') <- instantiatePolyTypeWithUnknowns val' ty
832+ ty' =?= u
833+ return $ TypedValue True val'' ty'
834+check' v@(NumericLiteral _) t | t == tyNumber =
835+ return $ TypedValue True v t
836+check' v@(StringLiteral _) t | t == tyString =
837+ return $ TypedValue True v t
838+check' v@(BooleanLiteral _) t | t == tyBoolean =
839+ return $ TypedValue True v t
840+check' (ArrayLiteral vals) t@(TypeApp a ty) = do
841+ a =?= tyArray
842+ array <- ArrayLiteral <$> forM vals (`check` ty)
843+ return $ TypedValue True array t
844+check' (Abs (Left arg) ret) ty@(TypeApp (TypeApp t argTy) retTy) | t == tyFunction = do
845+ Just moduleName <- checkCurrentModule <$> get
846+ ret' <- bindLocalVariables moduleName [(arg, argTy)] $ check ret retTy
847+ return $ TypedValue True (Abs (Left arg) ret') ty
848+check' (Abs (Right _) _) _ = error "Binder was not desugared"
849+check' (App f arg) ret = do
850+ f'@(TypedValue _ _ ft) <- infer f
851+ (_, app) <- checkFunctionApplication f' ft arg (Just ret)
852+ return $ TypedValue True app ret
853+check' v@(Var var) ty = do
854+ Just moduleName <- checkCurrentModule <$> get
855+ repl <- introduceSkolemScope <=< replaceAllTypeSynonyms <=< lookupVariable moduleName $ var
856+ ty' <- introduceSkolemScope <=< replaceAllTypeSynonyms $ ty
857+ v' <- subsumes (Just v) repl ty'
858+ case v' of
859+ Nothing -> throwError . strMsg $ "Unable to check type subsumption"
860+ Just v'' -> return $ TypedValue True v'' ty'
861+check' (TypedValue checkType val ty1) ty2 = do
862+ Just moduleName <- checkCurrentModule <$> get
863+ kind <- liftCheck $ kindOf moduleName ty1
864+ guardWith (strMsg $ "Expected type of kind *, was " ++ prettyPrintKind kind) $ kind == Star
865+ ty1' <- introduceSkolemScope <=< replaceAllTypeSynonyms $ ty1
866+ val' <- subsumes (Just val) ty1' ty2
867+ case val' of
868+ Nothing -> throwError . strMsg $ "Unable to check type subsumption"
869+ Just val'' -> do
870+ val''' <- if checkType then check val'' ty1' else return val''
871+ return $ TypedValue checkType (TypedValue True val''' ty1) ty2
872+check' (Case vals binders) ret = do
873+ vals' <- mapM infer vals
874+ let ts = map (\(TypedValue _ _ t) -> t) vals'
875+ binders' <- checkBinders ts ret binders
876+ return $ TypedValue True (Case vals' binders') ret
877+check' (IfThenElse cond th el) ty = do
878+ cond' <- check cond tyBoolean
879+ th' <- check th ty
880+ el' <- check el ty
881+ return $ TypedValue True (IfThenElse cond' th' el') ty
882+check' (ObjectLiteral ps) t@(TypeApp obj row) | obj == tyObject = do
883+ ensureNoDuplicateProperties ps
884+ ps' <- checkProperties ps row False
885+ return $ TypedValue True (ObjectLiteral ps') t
886+check' (ObjectUpdate obj ps) t@(TypeApp o row) | o == tyObject = do
887+ ensureNoDuplicateProperties ps
888+ us <- zip (map fst ps) <$> replicateM (length ps) fresh
889+ let (propsToCheck, rest) = rowToList row
890+ propsToRemove = map fst ps
891+ remainingProps = filter (\(p, _) -> p `notElem` propsToRemove) propsToCheck
892+ obj' <- check obj (TypeApp tyObject (rowFromList (us ++ remainingProps, rest)))
893+ ps' <- checkProperties ps row True
894+ return $ TypedValue True (ObjectUpdate obj' ps') t
895+check' (Accessor prop val) ty = do
896+ rest <- fresh
897+ val' <- check val (TypeApp tyObject (RCons prop ty rest))
898+ return $ TypedValue True (Accessor prop val') ty
899+check' (Constructor c) ty = do
900+ env <- getEnv
901+ case M.lookup c (dataConstructors env) of
902+ Nothing -> throwError . strMsg $ "Constructor " ++ show c ++ " is undefined"
903+ Just (_, ty1) -> do
904+ repl <- introduceSkolemScope <=< replaceAllTypeSynonyms $ ty1
905+ _ <- subsumes Nothing repl ty
906+ return $ TypedValue True (Constructor c) ty
907+check' (Let ds val) ty = do
908+ (ds', val') <- inferLetBinding [] ds val (flip check ty)
909+ return $ TypedValue True (Let ds' val') ty
910+check' val ty | containsTypeSynonyms ty = do
911+ ty' <- introduceSkolemScope <=< expandAllTypeSynonyms $ ty
912+ check val ty'
913+check' (PositionedValue pos val) ty =
914+ rethrowWithPosition pos $ check val ty
915+check' val ty = throwError $ mkErrorStack ("Value does not have type " ++ prettyPrintType ty) (Just (ValueError val))
916+
917+containsTypeSynonyms :: Type -> Bool
918+containsTypeSynonyms = everything (||) (mkQ False go) where
919+ go (SaturatedTypeSynonym _ _) = True
920+ go _ = False
921+
922+-- |
923+-- Check the type of a collection of named record fields
924+--
925+-- The @lax@ parameter controls whether or not every record member has to be provided. For object updates, this is not the case.
926+--
927+checkProperties :: [(String, Value)] -> Type -> Bool -> UnifyT Type Check [(String, Value)]
928+checkProperties ps row lax = let (ts, r') = rowToList row in go ps ts r' where
929+ go [] [] REmpty = return []
930+ go [] [] u@(TUnknown _) = do u =?= REmpty
931+ return []
932+ go [] [] (Skolem _ _) | lax = return []
933+ go [] ((p, _): _) _ | lax = return []
934+ | otherwise = throwError $ mkErrorStack ("Object does not have property " ++ p) (Just (ValueError (ObjectLiteral ps)))
935+ go ((p,_):_) [] REmpty = throwError $ mkErrorStack ("Property " ++ p ++ " is not present in closed object type " ++ prettyPrintRow row) (Just (ValueError (ObjectLiteral ps)))
936+ go ((p,v):ps') [] u@(TUnknown _) = do
937+ v'@(TypedValue _ _ ty) <- infer v
938+ rest <- fresh
939+ u =?= RCons p ty rest
940+ ps'' <- go ps' [] rest
941+ return $ (p, v') : ps''
942+ go ((p,v):ps') ts r =
943+ case lookup p ts of
944+ Nothing -> do
945+ v'@(TypedValue _ _ ty) <- infer v
946+ rest <- fresh
947+ r =?= RCons p ty rest
948+ ps'' <- go ps' ts rest
949+ return $ (p, v') : ps''
950+ Just ty -> do
951+ v' <- check v ty
952+ ps'' <- go ps' (delete (p, ty) ts) r
953+ return $ (p, v') : ps''
954+ go _ _ _ = throwError $ mkErrorStack ("Object does not have type " ++ prettyPrintType (TypeApp tyObject row)) (Just (ValueError (ObjectLiteral ps)))
955+
956+-- |
957+-- Check the type of a function application, rethrowing errors to provide a better error message
958+--
959+checkFunctionApplication :: Value -> Type -> Value -> Maybe Type -> UnifyT Type Check (Type, Value)
960+checkFunctionApplication fn fnTy arg ret = rethrow (mkErrorStack errorMessage (Just (ValueError fn)) <>) $ checkFunctionApplication' fn fnTy arg ret
961+ where
962+ errorMessage = "Error applying function of type "
963+ ++ prettyPrintType fnTy
964+ ++ " to argument " ++ prettyPrintValue arg
965+
966+-- |
967+-- Check the type of a function application
968+--
969+checkFunctionApplication' :: Value -> Type -> Value -> Maybe Type -> UnifyT Type Check (Type, Value)
970+checkFunctionApplication' fn (TypeApp (TypeApp tyFunction' argTy) retTy) arg ret = do
971+ tyFunction' =?= tyFunction
972+ _ <- maybe (return Nothing) (subsumes Nothing retTy) ret
973+ subst <- unifyCurrentSubstitution <$> UnifyT get
974+ arg' <- check arg (subst $? argTy)
975+ return (retTy, App fn arg')
976+checkFunctionApplication' fn (ForAll ident ty _) arg ret = do
977+ replaced <- replaceVarWithUnknown ident ty
978+ checkFunctionApplication fn replaced arg ret
979+checkFunctionApplication' fn u@(TUnknown _) arg ret = do
980+ arg' <- do
981+ TypedValue _ arg' t <- infer arg
982+ (arg'', t') <- instantiatePolyTypeWithUnknowns arg' t
983+ return $ TypedValue True arg'' t'
984+ let ty = (\(TypedValue _ _ t) -> t) arg'
985+ ret' <- maybe fresh return ret
986+ u =?= function ty ret'
987+ return (ret', App fn arg')
988+checkFunctionApplication' fn (SaturatedTypeSynonym name tyArgs) arg ret = do
989+ ty <- introduceSkolemScope <=< expandTypeSynonym name $ tyArgs
990+ checkFunctionApplication fn ty arg ret
991+checkFunctionApplication' fn (ConstrainedType constraints fnTy) arg ret = do
992+ dicts <- getTypeClassDictionaries
993+ checkFunctionApplication' (foldl App fn (map (flip (TypeClassDictionary True) (Just dicts)) constraints)) fnTy arg ret
994+checkFunctionApplication' _ fnTy arg _ = throwError . strMsg $ "Cannot apply a function of type "
995+ ++ prettyPrintType fnTy
996+ ++ " to argument " ++ prettyPrintValue arg
997+
998+-- |
999+-- Check whether one type subsumes another, rethrowing errors to provide a better error message
1000+--
1001+subsumes :: Maybe Value -> Type -> Type -> UnifyT Type Check (Maybe Value)
1002+subsumes val ty1 ty2 = rethrow (mkErrorStack errorMessage (ValueError <$> val) <>) $ subsumes' val ty1 ty2
1003+ where
1004+ errorMessage = "Error checking that type "
1005+ ++ prettyPrintType ty1
1006+ ++ " subsumes type "
1007+ ++ prettyPrintType ty2
1008+
1009+-- |
1010+-- Check whether one type subsumes another
1011+--
1012+subsumes' :: Maybe Value -> Type -> Type -> UnifyT Type Check (Maybe Value)
1013+subsumes' val (ForAll ident ty1 _) ty2 = do
1014+ replaced <- replaceVarWithUnknown ident ty1
1015+ subsumes val replaced ty2
1016+subsumes' val ty1 (ForAll ident ty2 sco) =
1017+ case sco of
1018+ Just sco' -> do
1019+ sko <- newSkolemConstant
1020+ let sk = skolemize ident sko sco' ty2
1021+ subsumes val ty1 sk
1022+ Nothing -> throwError . strMsg $ "Skolem variable scope is unspecified"
1023+subsumes' val (TypeApp (TypeApp f1 arg1) ret1) (TypeApp (TypeApp f2 arg2) ret2) | f1 == tyFunction && f2 == tyFunction = do
1024+ _ <- subsumes Nothing arg2 arg1
1025+ _ <- subsumes Nothing ret1 ret2
1026+ return val
1027+subsumes' val (SaturatedTypeSynonym name tyArgs) ty2 = do
1028+ ty1 <- introduceSkolemScope <=< expandTypeSynonym name $ tyArgs
1029+ subsumes val ty1 ty2
1030+subsumes' val ty1 (SaturatedTypeSynonym name tyArgs) = do
1031+ ty2 <- introduceSkolemScope <=< expandTypeSynonym name $ tyArgs
1032+ subsumes val ty1 ty2
1033+subsumes' (Just val) (ConstrainedType constraints ty1) ty2 = do
1034+ dicts <- getTypeClassDictionaries
1035+ _ <- subsumes' Nothing ty1 ty2
1036+ return . Just $ foldl App val (map (flip (TypeClassDictionary True) (Just dicts)) constraints)
1037+subsumes' val (TypeApp f1 r1) (TypeApp f2 r2) | f1 == tyObject && f2 == tyObject = do
1038+ let
1039+ (ts1, r1') = rowToList r1
1040+ (ts2, r2') = rowToList r2
1041+ ts1' = sortBy (comparing fst) ts1
1042+ ts2' = sortBy (comparing fst) ts2
1043+ go ts1' ts2' r1' r2'
1044+ return val
1045+ where
1046+ go [] ts2 r1' r2' = r1' =?= rowFromList (ts2, r2')
1047+ go ts1 [] r1' r2' = r2' =?= rowFromList (ts1, r1')
1048+ go ((p1, ty1) : ts1) ((p2, ty2) : ts2) r1' r2'
1049+ | p1 == p2 = do _ <- subsumes Nothing ty1 ty2
1050+ go ts1 ts2 r1' r2'
1051+ | p1 < p2 = do rest <- fresh
1052+ r2' =?= RCons p1 ty1 rest
1053+ go ts1 ((p2, ty2) : ts2) r1' rest
1054+ | otherwise = do rest <- fresh
1055+ r1' =?= RCons p2 ty2 rest
1056+ go ((p1, ty1) : ts1) ts2 rest r2'
1057+subsumes' val ty1 ty2@(TypeApp obj _) | obj == tyObject = subsumes val ty2 ty1
1058+subsumes' val ty1 ty2 = do
1059+ ty1 =?= ty2
1060+ return val
1061+
1062+
1063+