git.iko.soy/streamly
on 08046ff help sign in
streamly/src/Streamly/Internal/Data/Fold/Step.hs
83 lines 2.4 kB history raw
1-- |
2-- Module : Streamly.Internal.Data.Fold.Step
3-- Copyright : (c) 2019 Composewell Technologies
4-- License : BSD3
5-- Maintainer : streamly@composewell.com
6-- Stability : experimental
7-- Portability : GHC
8--
9module Streamly.Internal.Data.Fold.Step
10 (
11 -- * Types
12 Step (..)
14 , mapMStep
15 , chainStepM
16 )
17where
19import Data.Bifunctor (Bifunctor(..))
20import Fusion.Plugin.Types (Fuse(..))
22------------------------------------------------------------------------------
23-- Step of a fold
24------------------------------------------------------------------------------
26-- The Step functor around b allows expressing early termination like a right
27-- fold. Traditional list right folds use function composition and laziness to
28-- terminate early whereas we use data constructors. It allows stream fusion in
29-- contrast to the foldr/build fusion when composing with functions.
31-- | Represents the result of the @step@ of a 'Fold'. 'Partial' returns an
32-- intermediate state of the fold, the fold step can be called again with the
33-- state or the driver can use @extract@ on the state to get the result out.
34-- 'Done' returns the final result and the fold cannot be driven further.
35--
36-- /Pre-release/
37--
38{-# ANN type Step Fuse #-}
39data Step s b
40 = Partial !s
41 | Done !b
43-- | 'first' maps over 'Partial' and 'second' maps over 'Done'.
44--
45instance Bifunctor Step where
46 {-# INLINE bimap #-}
47 bimap f _ (Partial a) = Partial (f a)
48 bimap _ g (Done b) = Done (g b)
50 {-# INLINE first #-}
51 first f (Partial a) = Partial (f a)
52 first _ (Done x) = Done x
54 {-# INLINE second #-}
55 second _ (Partial x) = Partial x
56 second f (Done a) = Done (f a)
58-- | 'fmap' maps over 'Done'.
59--
60-- @
61-- fmap = 'second'
62-- @
63--
64instance Functor (Step s) where
65 {-# INLINE fmap #-}
66 fmap = second
68-- | Map a monadic function over the result @b@ in @Step s b@.
69--
70-- /Internal/
71{-# INLINE mapMStep #-}
72mapMStep :: Applicative m => (a -> m b) -> Step s a -> m (Step s b)
73mapMStep f res =
74 case res of
75 Partial s -> pure $ Partial s
76 Done b -> Done <$> f b
78-- | If 'Partial' then map the state, if 'Done' then call the next step.
79{-# INLINE chainStepM #-}
80chainStepM :: Applicative m =>
81 (s1 -> m s2) -> (a -> m (Step s2 b)) -> Step s1 a -> m (Step s2 b)
82chainStepM f _ (Partial s) = Partial <$> f s
83chainStepM _ g (Done b) = g b