git.iko.soy/streamly
on db030eb help sign in
streamly/src/Streamly/Internal/Network/Socket.hs
562 lines 19 kB history raw
1#include "inline.hs"
3-- |
4-- Module : Streamly.Internal.Network.Socket
5-- Copyright : (c) 2018 Composewell Technologies
6--
7-- License : BSD3
8-- Maintainer : streamly@composewell.com
9-- Stability : experimental
10-- Portability : GHC
11--
12module Streamly.Internal.Network.Socket
13 (
14 SockSpec (..)
15 -- * Use a socket
16 , forSocketM
17 , withSocket
19 -- * Accept connections
20 , accept
21 , acceptor
23 -- * Connect
24 , connect
25 , connectFrom
27 -- * Read from connection
28 , getChunk
30 -- ** Streams
31 , read
32 , readWith
33 , readChunks
34 , readChunksWith
36 -- ** Unfolds
37 , reader
38 , readerWith
39 , chunkReader
40 , chunkReaderWith
42 -- * Write to connection
43 , putChunk
45 -- ** Folds
46 , write
47 , writeWith
48 , writeChunks
49 , writeChunksWith
50 , writeMaybesWith
52 -- ** Stream writes
53 , putChunks
54 , putBytesWith
55 , putBytes
57 -- reading/writing datagrams
59 -- * Deprecated
60 , readWithBufferOf
61 , readChunksWithBufferOf
62 , writeWithBufferOf
63 , writeChunksWithBufferOf
64 )
65where
67import Control.Concurrent (threadWaitWrite, rtsSupportsBoundThreads)
68import Control.Exception (onException)
69import Control.Monad (forM_, when)
70import Control.Monad.Catch (MonadCatch, finally, MonadMask)
71import Control.Monad.IO.Class (MonadIO(..))
72import Data.Maybe (isNothing, fromJust)
73import Data.Word (Word8)
74import Foreign.Ptr (plusPtr, Ptr, castPtr)
75import Streamly.Internal.Data.Unboxed (Unboxed)
76import Network.Socket
77 (Socket, SocketOption(..), Family(..), SockAddr(..),
78 ProtocolNumber, withSocketsDo, SocketType(..), socket, bind,
79 setSocketOption, sendBuf, recvBuf)
80#if MIN_VERSION_network(3,1,0)
81import Network.Socket (withFdSocket)
82#else
83import Network.Socket (fdSocket)
84#endif
85import Prelude hiding (read)
87import qualified Network.Socket as Net
89import Streamly.Internal.Data.Array.Unboxed.Type (Array(..))
90import Streamly.Internal.Data.Array.Unboxed.Stream (lpackArraysChunksOf)
91import Streamly.Internal.Data.Fold (Fold)
92import Streamly.Internal.Data.Stream.Type (Stream)
93import Streamly.Internal.Data.Unfold.Type (Unfold(..))
94-- import Streamly.String (encodeUtf8, decodeUtf8, foldLines)
95import Streamly.Internal.System.IO (defaultChunkSize)
97import qualified Streamly.Data.Array.Unboxed as A (reader, length, writeN)
98import qualified Streamly.Data.Fold as FL
99import qualified Streamly.Internal.Data.Array.Unboxed.Type as A
100 (unsafeFreeze, asPtrUnsafe, byteLength, writeNUnsafe)
101import qualified Streamly.Internal.Data.Array.Unboxed.Mut as MArray
102 (Array(..), newPinnedBytes, asPtrUnsafe)
103import qualified Streamly.Internal.Data.Array.Unboxed.Stream as AS
104import qualified Streamly.Internal.Data.Stream as S
105import qualified Streamly.Internal.Data.Stream.StreamD.Type as D
106 (Stream(..), Step(..))
107import qualified Streamly.Data.Unfold as UF
108import qualified Streamly.Internal.Data.Unfold as UF (first, map)
109import qualified Streamly.Internal.Data.Stream.StreamK.Type as K (mkStream)
111-- $setup
112-- >>> :m
113-- >>> import Streamly.Internal.System.IO (defaultChunkSize)
114-- >>> import qualified Streamly.Internal.Network.Socket as Socket
116-- | @'forSocketM' action socket@ runs the monadic computation @action@ passing
117-- the socket handle to it. The handle will be closed on exit from
118-- 'forSocketM', whether by normal termination or by raising an exception. If
119-- closing the handle raises an exception, then this exception will be raised
120-- by 'forSocketM' rather than any exception raised by 'action'.
121--
122-- @since 0.8.0
123{-# INLINE forSocketM #-}
124forSocketM :: (MonadMask m, MonadIO m) => (Socket -> m ()) -> Socket -> m ()
125forSocketM f sk = finally (f sk) (liftIO (Net.close sk))
127-- | Like 'forSocketM' but runs a streaming computation instead of a monadic
128-- computation.
129--
130-- /Inhibits stream fusion/
131--
132-- /Internal/
133{-# INLINE withSocket #-}
134withSocket :: (MonadIO m, MonadCatch m) =>
135 Socket -> (Socket -> Stream m a) -> Stream m a
136withSocket sk f = S.finallyIO (Net.close sk) (f sk)
138-------------------------------------------------------------------------------
139-- Accept (Unfolds)
140-------------------------------------------------------------------------------
142-- XXX Protocol specific socket options should be separated from socket level
143-- options.
144--
145-- | Specify the socket protocol details.
146data SockSpec = SockSpec
147 {
148 sockFamily :: !Family
149 , sockType :: !SocketType
150 , sockProto :: !ProtocolNumber
151 , sockOpts :: ![(SocketOption, Int)]
152 }
154initListener :: Int -> SockSpec -> SockAddr -> IO Socket
155initListener listenQLen SockSpec{..} addr =
156 withSocketsDo $ do
157 sock <- socket sockFamily sockType sockProto
158 use sock `onException` Net.close sock
159 return sock
161 where
163 use sock = do
164 mapM_ (\(opt, val) -> setSocketOption sock opt val) sockOpts
165 bind sock addr
166 Net.listen sock listenQLen
168{-# INLINE listenTuples #-}
169listenTuples :: MonadIO m
170 => Unfold m (Int, SockSpec, SockAddr) (Socket, SockAddr)
171listenTuples = Unfold step inject
172 where
173 inject (listenQLen, spec, addr) =
174 liftIO $ initListener listenQLen spec addr
176 step listener = do
177 r <- liftIO (Net.accept listener `onException` Net.close listener)
178 return $ D.Yield r listener
180-- | Unfold a three tuple @(listenQLen, spec, addr)@ into a stream of connected
181-- protocol sockets corresponding to incoming connections. @listenQLen@ is the
182-- maximum number of pending connections in the backlog. @spec@ is the socket
183-- protocol and options specification and @addr@ is the protocol address where
184-- the server listens for incoming connections.
185--
186-- @since 0.9.0
187{-# INLINE acceptor #-}
188acceptor :: MonadIO m => Unfold m (Int, SockSpec, SockAddr) Socket
189acceptor = UF.map fst listenTuples
191{-# INLINE connectCommon #-}
192connectCommon :: SockSpec -> Maybe SockAddr -> SockAddr -> IO Socket
193connectCommon SockSpec{..} local remote = withSocketsDo $ do
194 sock <- socket sockFamily sockType sockProto
195 use sock `onException` Net.close sock
196 return sock
198 where
200 use sock = do
201 mapM_ (\(opt, val) -> setSocketOption sock opt val) sockOpts
202 forM_ local (bind sock)
203 Net.connect sock remote
205-- | Connect to a remote host using the given socket specification and remote
206-- address. Returns a connected socket or throws an exception.
207--
208-- /Pre-release/
209--
210{-# INLINE connect #-}
211connect :: SockSpec -> SockAddr -> IO Socket
212connect spec = connectCommon spec Nothing
214-- | Connect to a remote host using the given socket specification, a local
215-- address to bind to and a remote address to connect to. Returns a connected
216-- socket or throws an exception.
217--
218-- /Pre-release/
219--
220{-# INLINE connectFrom #-}
221connectFrom :: SockSpec -> SockAddr -> SockAddr -> IO Socket
222connectFrom spec local = connectCommon spec (Just local)
224-------------------------------------------------------------------------------
225-- Listen (Streams)
226-------------------------------------------------------------------------------
228{-# INLINE recvConnectionTuplesWith #-}
229recvConnectionTuplesWith :: MonadIO m
230 => Int -> SockSpec -> SockAddr -> Stream m (Socket, SockAddr)
231recvConnectionTuplesWith tcpListenQ spec addr = S.unfoldrM step Nothing
232 where
233 step Nothing = do
234 listener <- liftIO $ initListener tcpListenQ spec addr
235 r <- liftIO (Net.accept listener `onException` Net.close listener)
236 return $ Just (r, Just listener)
238 step (Just listener) = do
239 r <- liftIO (Net.accept listener `onException` Net.close listener)
240 return $ Just (r, Just listener)
242-- | Start a TCP stream server that listens for connections on the supplied
243-- server address specification (address family, local interface IP address and
244-- port). The server generates a stream of connected sockets. The first
245-- argument is the maximum number of pending connections in the backlog.
246--
247-- /Pre-release/
248{-# INLINE accept #-}
249accept :: MonadIO m => Int -> SockSpec -> SockAddr -> Stream m Socket
250accept tcpListenQ spec addr =
251 fst <$> recvConnectionTuplesWith tcpListenQ spec addr
253-------------------------------------------------------------------------------
254-- Array IO (Input)
255-------------------------------------------------------------------------------
257{-# INLINABLE readArrayUptoWith #-}
258readArrayUptoWith
259 :: (h -> Ptr Word8 -> Int -> IO Int)
260 -> Int
261 -> h
262 -> IO (Array Word8)
263readArrayUptoWith f size h = do
264 arr <- MArray.newPinnedBytes size
265 -- ptr <- mallocPlainForeignPtrAlignedBytes size (alignment (undefined :: Word8))
266 MArray.asPtrUnsafe arr $ \p -> do
267 n <- f h p size
268 let v = A.unsafeFreeze
269 $ arr { MArray.arrEnd = n, MArray.arrBound = size }
271 -- XXX shrink only if the diff is significant
272 -- A.shrinkToFit v
273 return v
275-- | Read a byte array from a file handle up to a maximum of the requested
276-- size. If no data is available on the handle it blocks until some data
277-- becomes available. If data is available then it immediately returns that
278-- data without blocking.
279--
280-- @since 0.9.0
281{-# INLINABLE getChunk #-}
282getChunk :: Int -> Socket -> IO (Array Word8)
283getChunk = readArrayUptoWith recvBuf
285-------------------------------------------------------------------------------
286-- Array IO (output)
287-------------------------------------------------------------------------------
289waitWhen0 :: Int -> Socket -> IO ()
290waitWhen0 0 s = when rtsSupportsBoundThreads $
291#if MIN_VERSION_network(3,1,0)
292 withFdSocket s $ \fd -> threadWaitWrite $ fromIntegral fd
293#elif MIN_VERSION_network(3,0,0)
294 fdSocket s >>= threadWaitWrite . fromIntegral
295#else
296 let fd = fdSocket s in threadWaitWrite $ fromIntegral fd
297#endif
298waitWhen0 _ _ = return ()
300sendAll :: Socket -> Ptr Word8 -> Int -> IO ()
301sendAll _ _ len | len <= 0 = return ()
302sendAll s p len = do
303 sent <- sendBuf s p len
304 waitWhen0 sent s
305 -- assert (sent <= len)
306 when (sent >= 0) $ sendAll s (p `plusPtr` sent) (len - sent)
308{-# INLINABLE writeArrayWith #-}
309writeArrayWith :: Unboxed a
310 => (h -> Ptr Word8 -> Int -> IO ())
311 -> h
312 -> Array a
313 -> IO ()
314writeArrayWith _ _ arr | A.length arr == 0 = return ()
315writeArrayWith f h arr = A.asPtrUnsafe arr $ \ptr -> f h (castPtr ptr) aLen
317 where
319 aLen = A.byteLength arr
321-- | Write an Array to a file handle.
322--
323-- @since 0.9.0
324{-# INLINABLE putChunk #-}
325putChunk :: Unboxed a => Socket -> Array a -> IO ()
326putChunk = writeArrayWith sendAll
328-------------------------------------------------------------------------------
329-- Stream of Arrays IO
330-------------------------------------------------------------------------------
332{-# INLINE _readChunksUptoWith #-}
333_readChunksUptoWith :: (MonadIO m)
334 => (Int -> h -> IO (Array Word8))
335 -> Int -> h -> Stream m (Array Word8)
336_readChunksUptoWith f size h = S.fromStreamK go
337 where
338 -- XXX use cons/nil instead
339 go = K.mkStream $ \_ yld _ stp -> do
340 arr <- liftIO $ f size h
341 if A.length arr == 0
342 then stp
343 else yld arr go
345-- | @readChunksWith bufsize socket@ reads a stream of arrays from @socket@.
346-- The maximum size of a single array is limited to @bufsize@.
347--
348-- /Pre-release/
349{-# INLINE_NORMAL readChunksWith #-}
350readChunksWith :: MonadIO m => Int -> Socket -> Stream m (Array Word8)
351-- readChunksWith = _readChunksUptoWith readChunk
352readChunksWith size h = S.fromStreamD (D.Stream step ())
353 where
354 {-# INLINE_LATE step #-}
355 step _ _ = do
356 arr <- liftIO $ getChunk size h
357 return $
358 case A.length arr of
359 0 -> D.Stop
360 _ -> D.Yield arr ()
362-- | Read a stream of byte arrays from a socket. The maximum size of a single
363-- array is limited to @defaultChunkSize@.
364--
365-- >>> readChunks = Socket.readChunksWith defaultChunkSize
366--
367-- /Pre-release/
368{-# INLINE readChunks #-}
369readChunks :: MonadIO m => Socket -> Stream m (Array Word8)
370readChunks = readChunksWith defaultChunkSize
372-- | Unfold the tuple @(bufsize, socket)@ into a stream of 'Word8' arrays.
373-- Read requests to the socket are performed using a buffer of size @bufsize@.
374-- The size of an array in the resulting stream is always less than or equal to
375-- @bufsize@.
376--
377-- @since 0.9.0
378{-# INLINE_NORMAL chunkReaderWith #-}
379chunkReaderWith :: MonadIO m => Unfold m (Int, Socket) (Array Word8)
380chunkReaderWith = Unfold step return
381 where
382 {-# INLINE_LATE step #-}
383 step (size, h) = do
384 arr <- liftIO $ getChunk size h
385 return $
386 case A.length arr of
387 0 -> D.Stop
388 _ -> D.Yield arr (size, h)
390-- | Same as 'chunkReaderWith'
391--
392-- @since 0.7.0
393{-# DEPRECATED readChunksWithBufferOf "Please use 'chunkReaderWith' instead" #-}
394{-# INLINE_NORMAL readChunksWithBufferOf #-}
395readChunksWithBufferOf :: MonadIO m => Unfold m (Int, Socket) (Array Word8)
396readChunksWithBufferOf = chunkReaderWith
398-- | Unfolds a socket into a stream of 'Word8' arrays. Requests to the socket
399-- are performed using a buffer of size
400-- 'Streamly.Internal.Data.Array.Unboxed.Type.defaultChunkSize'. The
401-- size of arrays in the resulting stream are therefore less than or equal to
402-- 'Streamly.Internal.Data.Array.Unboxed.Type.defaultChunkSize'.
403--
404-- @since 0.9.0
405{-# INLINE chunkReader #-}
406chunkReader :: MonadIO m => Unfold m Socket (Array Word8)
407chunkReader = UF.first defaultChunkSize chunkReaderWith
409-------------------------------------------------------------------------------
410-- Read File to Stream
411-------------------------------------------------------------------------------
413-- | Generate a byte stream from a socket using a buffer of the given size.
414--
415-- /Pre-release/
416{-# INLINE readWith #-}
417readWith :: MonadIO m => Int -> Socket -> Stream m Word8
418readWith size = AS.concat . readChunksWith size
420-- | Generate a byte stream from a socket.
421--
422-- >>> read = Socket.readWith defaultChunkSize
423--
424-- /Pre-release/
425{-# INLINE read #-}
426read :: MonadIO m => Socket -> Stream m Word8
427read = readWith defaultChunkSize
429-- | Unfolds the tuple @(bufsize, socket)@ into a byte stream, read requests
430-- to the socket are performed using buffers of @bufsize@.
431--
432-- @since 0.9.0
433{-# INLINE readerWith #-}
434readerWith :: MonadIO m => Unfold m (Int, Socket) Word8
435readerWith = UF.many A.reader chunkReaderWith
437-- | Same as 'readWith'
438--
439-- @since 0.7.0
440{-# DEPRECATED readWithBufferOf "Please use 'readerWith' instead" #-}
441{-# INLINE readWithBufferOf #-}
442readWithBufferOf :: MonadIO m => Unfold m (Int, Socket) Word8
443readWithBufferOf = readerWith
445-- | Unfolds a 'Socket' into a byte stream. IO requests to the socket are
446-- performed in sizes of
447-- 'Streamly.Internal.Data.Array.Unboxed.Type.defaultChunkSize'.
448--
449-- @since 0.9.0
450{-# INLINE reader #-}
451reader :: MonadIO m => Unfold m Socket Word8
452reader = UF.first defaultChunkSize readerWith
454-------------------------------------------------------------------------------
455-- Writing
456-------------------------------------------------------------------------------
458-- | Write a stream of arrays to a handle.
459--
460-- @since 0.7.0
461{-# INLINE putChunks #-}
462putChunks :: (MonadIO m, Unboxed a)
463 => Socket -> Stream m (Array a) -> m ()
464putChunks h = S.fold (FL.drainBy (liftIO . putChunk h))
466-- | Write a stream of arrays to a socket. Each array in the stream is written
467-- to the socket as a separate IO request.
468--
469-- @since 0.7.0
470{-# INLINE writeChunks #-}
471writeChunks :: (MonadIO m, Unboxed a) => Socket -> Fold m (Array a) ()
472writeChunks h = FL.drainBy (liftIO . putChunk h)
474-- | @writeChunksWith bufsize socket@ writes a stream of arrays to
475-- @socket@ after coalescing the adjacent arrays in chunks of @bufsize@.
476-- Multiple arrays are coalesed as long as the total size remains below the
477-- specified size. It never splits an array, if a single array is bigger than
478-- the specified size it emitted as it is.
479--
480-- @since 0.9.0
481{-# INLINE writeChunksWith #-}
482writeChunksWith :: (MonadIO m, Unboxed a)
483 => Int -> Socket -> Fold m (Array a) ()
484writeChunksWith n h = lpackArraysChunksOf n (writeChunks h)
486-- | Same as 'writeChunksWith'
487--
488-- @since 0.7.0
489{-# DEPRECATED writeChunksWithBufferOf "Please use 'writeChunksWith' instead" #-}
490{-# INLINE writeChunksWithBufferOf #-}
491writeChunksWithBufferOf :: (MonadIO m, Unboxed a)
492 => Int -> Socket -> Fold m (Array a) ()
493writeChunksWithBufferOf = writeChunksWith
495-- GHC buffer size dEFAULT_FD_BUFFER_SIZE=8192 bytes.
496--
497-- XXX test this
498-- Note that if you use a chunk size less than 8K (GHC's default buffer
499-- size) then you are advised to use 'NOBuffering' mode on the 'Handle' in case you
500-- do not want buffering to occur at GHC level as well. Same thing applies to
501-- writes as well.
503-- | Like 'write' but provides control over the write buffer. Output will
504-- be written to the IO device as soon as we collect the specified number of
505-- input elements.
506--
507-- @since 0.9.0
508{-# INLINE putBytesWith #-}
509putBytesWith :: MonadIO m => Int -> Socket -> Stream m Word8 -> m ()
510putBytesWith n h m = putChunks h $ AS.arraysOf n m
512-- | Write a byte stream to a socket. Accumulates the input in chunks of
513-- specified number of bytes before writing.
514--
515-- @since 0.9.0
516{-# INLINE writeWith #-}
517writeWith :: MonadIO m => Int -> Socket -> Fold m Word8 ()
518writeWith n h = FL.chunksOf n (A.writeNUnsafe n) (writeChunks h)
520-- | Same as 'writeWith'
521--
522-- @since 0.7.0
523{-# DEPRECATED writeWithBufferOf "Please use 'writeWith' instead" #-}
524{-# INLINE writeWithBufferOf #-}
525writeWithBufferOf :: MonadIO m => Int -> Socket -> Fold m Word8 ()
526writeWithBufferOf = writeWith
528-- | Write a stream of 'Maybe' values. Keep buffering the 'Just' values in an
529-- array. Write the array to the 'Handle' as soon as a 'Nothing' is encountered
530-- or the buffer size exceeds the specified limit.
531--
532-- /Pre-release/
533{-# INLINE writeMaybesWith #-}
534writeMaybesWith :: (MonadIO m )
535 => Int -> Socket -> Fold m (Maybe Word8) ()
536writeMaybesWith n h =
537 let writeNJusts = FL.lmap fromJust $ A.writeN n
538 writeOnNothing = FL.takeEndBy_ isNothing writeNJusts
539 in FL.many writeOnNothing (writeChunks h)
541-- > write = 'writeWith' defaultChunkSize
542--
543-- | Write a byte stream to a file handle. Combines the bytes in chunks of size
544-- up to 'defaultChunkSize' before writing. Note that the write behavior
545-- depends on the 'IOMode' and the current seek position of the handle.
546--
547-- @since 0.7.0
548{-# INLINE putBytes #-}
549putBytes :: MonadIO m => Socket -> Stream m Word8 -> m ()
550putBytes = putBytesWith defaultChunkSize
552-- | Write a byte stream to a socket. Accumulates the input in chunks of
553-- up to 'defaultChunkSize' bytes before writing.
554--
555-- @
556-- write = 'writeWith' 'defaultChunkSize'
557-- @
558--
559-- @since 0.7.0
560{-# INLINE write #-}
561write :: MonadIO m => Socket -> Fold m Word8 ()
562write = writeWith defaultChunkSize