git.iko.soy/streamly
on fe33167 help sign in
streamly/src/Streamly/Internal/Network/Inet/TCP.hs
453 lines 15 kB history raw
1#include "inline.hs"
3-- |
4-- Module : Streamly.Internal.Network.Inet.TCP
5-- Copyright : (c) 2019 Composewell Technologies
6--
7-- License : BSD3
8-- Maintainer : streamly@composewell.com
9-- Stability : experimental
10-- Portability : GHC
11--
12-- Combinators to build Inet/TCP clients and servers.
14module Streamly.Internal.Network.Inet.TCP
15 (
16 -- * TCP Servers
17 -- ** Unfolds
18 acceptOnAddr
19 , acceptOnAddrWith
20 , acceptOnPort
21 , acceptOnPortWith
22 , acceptOnPortLocal
24 -- ** Streams
25 , connectionsOnAddr
26 , connectionsOnAddrWith
27 , connectionsOnPort
28 , connectionsOnLocalHost
30 -- * TCP clients
31 -- | IP Address based operations.
32 , connect
33 , withConnectionM
35 -- ** Unfolds
36 , usingConnection
37 , read
39 -- ** Streams
40 , withConnection
41 -- *** Source
42 , toBytes
43 -- , readUtf8
44 -- , readLines
45 -- , readFrames
46 -- , readByChunks
48 -- -- * Array Read
49 -- , readArrayUpto
50 -- , readArrayOf
52 -- , readChunksUpto
53 -- , readChunksOf
54 -- , readChunks
56 -- *** Sink
57 , write
58 -- , writeUtf8
59 -- , writeUtf8ByLines
60 -- , writeByFrames
61 , writeWithBufferOf
62 , fromBytes
63 , fromBytesWithBufferOf
65 -- -- * Array Write
66 -- , writeArray
67 , writeChunks
68 , fromChunks
70 -- ** Transformation
71 , transformBytesWith
72 {-
73 -- ** Sink Servers
75 -- These abstractions can be applied to any setting where we need to do a
76 -- sink processing of multiple streams e.g. output from multiple processes
77 -- or data coming from multiple files.
79 -- handle connections concurrently using a specified fold
80 -- , handleConnections
82 -- handle frames concurrently using a specified fold
83 , handleFrames
85 -- merge frames from all connection into a single stream. Frames can be
86 -- created by a specified fold.
87 , mergeFrames
89 -- * UDP Servers
90 , datagrams
91 , datagramsOn
92 -}
93 )
94where
96import Control.Exception (onException)
97import Control.Monad.Catch (MonadCatch, MonadMask, bracket)
98import Control.Monad.IO.Class (MonadIO(..))
99import Data.Word (Word8)
100import Network.Socket
101 (Socket, PortNumber, SocketOption(..), Family(..), SockAddr(..),
102 SocketType(..), defaultProtocol, maxListenQueue, tupleToHostAddress,
103 socket)
104import Prelude hiding (read)
106import Streamly.Prelude (MonadAsync)
107import Streamly.Internal.Data.Fold.Types (Fold(..))
108import Streamly.Internal.Data.SVar (fork)
109import Streamly.Internal.Data.Unfold.Types (Unfold(..))
110import Streamly.Internal.Network.Socket (SockSpec(..), accept, connections)
111import Streamly.Internal.Data.Stream.Serial (SerialT)
112import Streamly.Internal.Data.Array.Storable.Foreign.Types (Array(..), defaultChunkSize, writeNUnsafe)
113import Streamly.Internal.Data.Stream.StreamK.Type (IsStream)
115import qualified Control.Monad.Catch as MC
116import qualified Network.Socket as Net
118import qualified Streamly.Internal.Data.Unfold as UF
119import qualified Streamly.Internal.Data.Array.Storable.Foreign as A
120import qualified Streamly.Internal.Memory.ArrayStream as AS
121import qualified Streamly.Internal.Data.Fold.Types as FL
122import qualified Streamly.Prelude as S
123import qualified Streamly.Network.Socket as SK
124import qualified Streamly.Internal.Network.Socket as ISK
126-------------------------------------------------------------------------------
127-- Accept (unfolds)
128-------------------------------------------------------------------------------
130{-# INLINE acceptOnAddrWith #-}
131acceptOnAddrWith
132 :: MonadIO m
133 => [(SocketOption, Int)]
134 -> Unfold m ((Word8, Word8, Word8, Word8), PortNumber) Socket
135acceptOnAddrWith opts = UF.lmap f accept
136 where
137 f (addr, port) =
138 (maxListenQueue
139 , SockSpec
140 { sockFamily = AF_INET
141 , sockType = Stream
142 , sockProto = defaultProtocol -- TCP
143 , sockOpts = opts
144 }
145 , SockAddrInet port (tupleToHostAddress addr)
146 )
148-- | Unfold a tuple @(ipAddr, port)@ into a stream of connected TCP sockets.
149-- @ipAddr@ is the local IP address and @port@ is the local port on which
150-- connections are accepted.
151--
152-- @since 0.7.0
153{-# INLINE acceptOnAddr #-}
154acceptOnAddr
155 :: MonadIO m
156 => Unfold m ((Word8, Word8, Word8, Word8), PortNumber) Socket
157acceptOnAddr = acceptOnAddrWith []
159{-# INLINE acceptOnPortWith #-}
160acceptOnPortWith :: MonadIO m
161 => [(SocketOption, Int)]
162 -> Unfold m PortNumber Socket
163acceptOnPortWith opts = UF.supplyFirst (acceptOnAddrWith opts) (0,0,0,0)
165-- | Like 'acceptOnAddr' but binds on the IPv4 address @0.0.0.0@ i.e. on all
166-- IPv4 addresses/interfaces of the machine and listens for TCP connections on
167-- the specified port.
168--
169-- > acceptOnPort = UF.supplyFirst acceptOnAddr (0,0,0,0)
170--
171-- @since 0.7.0
172{-# INLINE acceptOnPort #-}
173acceptOnPort :: MonadIO m => Unfold m PortNumber Socket
174acceptOnPort = UF.supplyFirst acceptOnAddr (0,0,0,0)
176-- | Like 'acceptOnAddr' but binds on the localhost IPv4 address @127.0.0.1@.
177-- The server can only be accessed from the local host, it cannot be accessed
178-- from other hosts on the network.
179--
180-- > acceptOnPortLocal = UF.supplyFirst acceptOnAddr (127,0,0,1)
181--
182-- @since 0.7.0
183{-# INLINE acceptOnPortLocal #-}
184acceptOnPortLocal :: MonadIO m => Unfold m PortNumber Socket
185acceptOnPortLocal = UF.supplyFirst acceptOnAddr (127,0,0,1)
187-------------------------------------------------------------------------------
188-- Accept (streams)
189-------------------------------------------------------------------------------
191{-# INLINE connectionsOnAddrWith #-}
192connectionsOnAddrWith
193 :: MonadAsync m
194 => [(SocketOption, Int)]
195 -> (Word8, Word8, Word8, Word8)
196 -> PortNumber
197 -> SerialT m Socket
198connectionsOnAddrWith opts addr port =
199 connections maxListenQueue SockSpec
200 { sockFamily = AF_INET
201 , sockType = Stream
202 , sockProto = defaultProtocol
203 , sockOpts = opts
204 }
205 (SockAddrInet port (tupleToHostAddress addr))
207-- | Like 'connections' but binds on the specified IPv4 address of the machine
208-- and listens for TCP connections on the specified port.
209--
210-- /Internal/
211{-# INLINE connectionsOnAddr #-}
212connectionsOnAddr
213 :: MonadAsync m
214 => (Word8, Word8, Word8, Word8)
215 -> PortNumber
216 -> SerialT m Socket
217connectionsOnAddr = connectionsOnAddrWith []
219-- | Like 'connections' but binds on the IPv4 address @0.0.0.0@ i.e. on all
220-- IPv4 addresses/interfaces of the machine and listens for TCP connections on
221-- the specified port.
222--
223-- > connectionsOnPort = connectionsOnAddr (0,0,0,0)
224--
225-- /Internal/
226{-# INLINE connectionsOnPort #-}
227connectionsOnPort :: MonadAsync m => PortNumber -> SerialT m Socket
228connectionsOnPort = connectionsOnAddr (0,0,0,0)
230-- | Like 'connections' but binds on the localhost IPv4 address @127.0.0.1@.
231-- The server can only be accessed from the local host, it cannot be accessed
232-- from other hosts on the network.
233--
234-- > connectionsOnLocalHost = connectionsOnAddr (127,0,0,1)
235--
236-- /Internal/
237{-# INLINE connectionsOnLocalHost #-}
238connectionsOnLocalHost :: MonadAsync m => PortNumber -> SerialT m Socket
239connectionsOnLocalHost = connectionsOnAddr (127,0,0,1)
241-------------------------------------------------------------------------------
242-- TCP Clients
243-------------------------------------------------------------------------------
245-- | Connect to the specified IP address and port number. Returns a connected
246-- socket or throws an exception.
247--
248-- @since 0.7.0
249connect :: (Word8, Word8, Word8, Word8) -> PortNumber -> IO Socket
250connect addr port = do
251 sock <- socket AF_INET Stream defaultProtocol
252 Net.connect sock (SockAddrInet port (Net.tupleToHostAddress addr))
253 `onException` Net.close sock
254 return sock
256-- | Connect to a remote host using IP address and port and run the supplied
257-- action on the resulting socket. 'withConnectionM' makes sure that the
258-- socket is closed on normal termination or in case of an exception. If
259-- closing the socket raises an exception, then this exception will be raised
260-- by 'withConnectionM'.
261--
262-- /Internal/
263{-# INLINABLE withConnectionM #-}
264withConnectionM :: (MonadMask m, MonadIO m)
265 => (Word8, Word8, Word8, Word8) -> PortNumber -> (Socket -> m ()) -> m ()
266withConnectionM addr port =
267 bracket (liftIO $ connect addr port) (liftIO . Net.close)
269-------------------------------------------------------------------------------
270-- Connect (unfolds)
271-------------------------------------------------------------------------------
273-- | Transform an 'Unfold' from a 'Socket' to an unfold from a remote IP
274-- address and port. The resulting unfold opens a socket, uses it using the
275-- supplied unfold and then makes sure that the socket is closed on normal
276-- termination or in case of an exception. If closing the socket raises an
277-- exception, then this exception will be raised by 'usingConnection'.
278--
279-- /Internal/
280{-# INLINABLE usingConnection #-}
281usingConnection :: (MonadCatch m, MonadAsync m)
282 => Unfold m Socket a
283 -> Unfold m ((Word8, Word8, Word8, Word8), PortNumber) a
284usingConnection =
285 UF.bracket (\(addr, port) -> liftIO $ connect addr port)
286 (liftIO . Net.close)
288-------------------------------------------------------------------------------
289-- Connect (streams)
290-------------------------------------------------------------------------------
292-- | @'withConnection' addr port act@ opens a connection to the specified IPv4
293-- host address and port and passes the resulting socket handle to the
294-- computation @act@. The handle will be closed on exit from 'withConnection',
295-- whether by normal termination or by raising an exception. If closing the
296-- handle raises an exception, then this exception will be raised by
297-- 'withConnection' rather than any exception raised by 'act'.
298--
299-- /Internal/
300{-# INLINABLE withConnection #-}
301withConnection :: (IsStream t, MonadCatch m, MonadAsync m)
302 => (Word8, Word8, Word8, Word8) -> PortNumber -> (Socket -> t m a) -> t m a
303withConnection addr port =
304 S.bracket (liftIO $ connect addr port) (liftIO . Net.close)
306-------------------------------------------------------------------------------
307-- Read Addr to Stream
308-------------------------------------------------------------------------------
310-- | Read a stream from the supplied IPv4 host address and port number.
311--
312-- @since 0.7.0
313{-# INLINE read #-}
314read :: (MonadCatch m, MonadAsync m)
315 => Unfold m ((Word8, Word8, Word8, Word8), PortNumber) Word8
316read = UF.concat (usingConnection ISK.readChunks) A.read
318-- | Read a stream from the supplied IPv4 host address and port number.
319--
320-- @since 0.7.0
321{-# INLINE toBytes #-}
322toBytes :: (IsStream t, MonadCatch m, MonadAsync m)
323 => (Word8, Word8, Word8, Word8) -> PortNumber -> t m Word8
324toBytes addr port = AS.concat $ withConnection addr port ISK.toChunks
326-------------------------------------------------------------------------------
327-- Writing
328-------------------------------------------------------------------------------
330-- | Write a stream of arrays to the supplied IPv4 host address and port
331-- number.
332--
333-- @since 0.7.0
334{-# INLINE fromChunks #-}
335fromChunks
336 :: (MonadCatch m, MonadAsync m)
337 => (Word8, Word8, Word8, Word8)
338 -> PortNumber
339 -> SerialT m (Array Word8)
340 -> m ()
341fromChunks addr port xs =
342 S.drain $ withConnection addr port (\sk -> S.yieldM $ ISK.fromChunks sk xs)
344-- | Write a stream of arrays to the supplied IPv4 host address and port
345-- number.
346--
347-- @since 0.7.0
348{-# INLINE writeChunks #-}
349writeChunks
350 :: (MonadAsync m, MonadCatch m)
351 => (Word8, Word8, Word8, Word8)
352 -> PortNumber
353 -> Fold m (Array Word8) ()
354writeChunks addr port = Fold step initial extract
355 where
356 initial = do
357 skt <- liftIO (connect addr port)
358 fld <- FL.initialize (SK.writeChunks skt) `MC.onException` liftIO (Net.close skt)
359 return (fld, skt)
360 step (fld, skt) x = do
361 r <- FL.runStep fld x `MC.onException` liftIO (Net.close skt)
362 return (r, skt)
363 extract (Fold _ initial1 extract1, skt) = do
364 liftIO $ Net.close skt
365 initial1 >>= extract1
367-- | Like 'write' but provides control over the write buffer. Output will
368-- be written to the IO device as soon as we collect the specified number of
369-- input elements.
370--
371-- @since 0.7.0
372{-# INLINE fromBytesWithBufferOf #-}
373fromBytesWithBufferOf
374 :: (MonadCatch m, MonadAsync m)
375 => Int
376 -> (Word8, Word8, Word8, Word8)
377 -> PortNumber
378 -> SerialT m Word8
379 -> m ()
380fromBytesWithBufferOf n addr port m = fromChunks addr port $ AS.arraysOf n m
382-- | Like 'write' but provides control over the write buffer. Output will
383-- be written to the IO device as soon as we collect the specified number of
384-- input elements.
385--
386-- @since 0.7.0
387{-# INLINE writeWithBufferOf #-}
388writeWithBufferOf
389 :: (MonadAsync m, MonadCatch m)
390 => Int
391 -> (Word8, Word8, Word8, Word8)
392 -> PortNumber
393 -> Fold m Word8 ()
394writeWithBufferOf n addr port =
395 FL.lchunksOf n (writeNUnsafe n) (writeChunks addr port)
397-- | Write a stream to the supplied IPv4 host address and port number.
398--
399-- @since 0.7.0
400{-# INLINE fromBytes #-}
401fromBytes :: (MonadCatch m, MonadAsync m)
402 => (Word8, Word8, Word8, Word8) -> PortNumber -> SerialT m Word8 -> m ()
403fromBytes = fromBytesWithBufferOf defaultChunkSize
405-- | Write a stream to the supplied IPv4 host address and port number.
406--
407-- @since 0.7.0
408{-# INLINE write #-}
409write :: (MonadAsync m, MonadCatch m)
410 => (Word8, Word8, Word8, Word8) -> PortNumber -> Fold m Word8 ()
411write = writeWithBufferOf defaultChunkSize
413-------------------------------------------------------------------------------
414-- Transformations
415-------------------------------------------------------------------------------
417{-# INLINABLE withInputConnect #-}
418withInputConnect
419 :: (IsStream t, MonadCatch m, MonadAsync m)
420 => (Word8, Word8, Word8, Word8)
421 -> PortNumber
422 -> SerialT m Word8
423 -> (Socket -> t m a)
424 -> t m a
425withInputConnect addr port input f = S.bracket pre post handler
427 where
429 pre = do
430 sk <- liftIO $ connect addr port
431 tid <- fork (ISK.fromBytes sk input)
432 return (sk, tid)
434 handler (sk, _) = f sk
436 -- XXX kill the thread immediately?
437 post (sk, _) = liftIO $ Net.close sk
439-- | Send an input stream to a remote host and produce the output stream from
440-- the host. The server host just acts as a transformation function on the
441-- input stream. Both sending and receiving happen asynchronously.
442--
443-- /Internal/
444--
445{-# INLINABLE transformBytesWith #-}
446transformBytesWith
447 :: (IsStream t, MonadAsync m, MonadCatch m)
448 => (Word8, Word8, Word8, Word8)
449 -> PortNumber
450 -> SerialT m Word8
451 -> t m Word8
452transformBytesWith addr port input =
453 withInputConnect addr port input ISK.toBytes