git.iko.soy/typeable/cabal2nix
on aedba02 help sign in
typeable/cabal2nix/src/Language/Nix/Identifier.hs
66 lines 2.1 kB history raw
1{-# LANGUAGE DeriveGeneric #-}
2{-# LANGUAGE GeneralizedNewtypeDeriving #-}
4module Language.Nix.Identifier ( Identifier, ident, quote, needsQuoting ) where
6import Control.DeepSeq.Generics
7import Data.String
8import Distribution.Nixpkgs.Util.PrettyPrinting ( Pretty(..), text )
9import GHC.Generics ( Generic )
10import Internal.Lens
11import Text.Regex.Posix
13-- | Identifiers in Nix are essentially strings. Reasonable people restrict
14-- themselves to identifiers of the form @[a-zA-Z\_][a-zA-Z0-9\_\'\-]*@,
15-- because these don't need quoting. The @Identifier@ type is an instance of
16-- the 'IsString' class for convenience. The methods of the 'Pretty' class can
17-- be used to pretty-print an identifier with proper quoting.
18--
19-- >>> let i = Identifier "test" in (i, pPrint i)
20-- (Identifier "test",test)
21-- >>> let i = Identifier "foo.bar" in (i, pPrint i)
22-- (Identifier "foo.bar","foo.bar")
24newtype Identifier = Identifier String
25 deriving (Show, Eq, IsString, Generic)
27instance Default Identifier where def = Identifier ""
29instance Pretty Identifier where
30 pPrint i = text (i ^. ident . to quote)
32instance Ord Identifier where
33 compare (Identifier a) (Identifier b) = compare a b
35instance NFData Identifier where rnf = genericRnf
37-- | Checks whether a given string would need quoting when interpreted as an
38-- intentifier.
40needsQuoting :: String -> Bool
41needsQuoting str = not (str =~ grammar)
42 where grammar :: String -- TODO: should be a compiled regular expression
43 grammar = "^[a-zA-Z\\_][a-zA-Z0-9\\_\\'\\-]*$"
45-- | Lens that allows conversion from/to the standard 'String' type. The setter
46-- does not evaluate its input, so it's safe to use with 'undefined'.
47--
48-- >>> putStrLn $ Identifier "abc.def" ^. ident
49-- abc.def
50--
51-- >>> pPrint $ undefined & ident .~ "abcdef"
52-- abcdef
54ident :: Lens' Identifier String
55ident f (Identifier str) = Identifier `fmap` f str
57-- | Helper function to quote a given identifier string if necessary.
58--
59-- >>> putStrLn (quote "abc")
60-- abc
61--
62-- >>> putStrLn (quote "abc.def")
63-- "abc.def"
65quote :: String -> String
66quote s = if needsQuoting s then show s else s