git.iko.soy/typeable/cabal2nix
on v2.6 help sign in
typeable/cabal2nix/hackage2nix/Main.hs
204 lines 10 kB history raw
1{-# LANGUAGE OverloadedStrings #-}
2{-# LANGUAGE RecordWildCards #-}
4module Main ( main ) where
6import HackageGit
8import Control.Lens
9import Control.Monad
10import Control.Monad.Par.Combinator
11import Control.Monad.Par.IO
12import Control.Monad.Trans ( liftIO )
13import Data.List
14import Data.Map.Strict ( Map )
15import qualified Data.Map.Strict as Map
16import Data.Maybe
17import Data.Monoid
18import Data.Set ( Set )
19import qualified Data.Set as Set
20import Data.String
21import Distribution.Nixpkgs.Fetch
22import Distribution.Nixpkgs.Haskell as Derivation
23import Distribution.Nixpkgs.Haskell.Constraint
24import Distribution.Nixpkgs.Haskell.FromCabal
25import Distribution.Nixpkgs.Haskell.FromCabal.Configuration as Config
26import Distribution.Nixpkgs.Haskell.FromCabal.Flags
27import Distribution.Nixpkgs.Meta
28import Distribution.Nixpkgs.PackageMap
29import Distribution.Package
30import Distribution.PackageDescription hiding ( options, buildDepends, extraLibs, buildTools )
31import Distribution.System
32import Distribution.Text
33import Distribution.Version
34import Language.Nix
35import Options.Applicative
36import qualified Paths_cabal2nix as Main
37import System.FilePath
38import System.IO
39import Text.PrettyPrint.HughesPJClass hiding ( (<>) )
41type PackageSet = Map PackageName Version
42type PackageMultiSet = Map PackageName (Set Version)
44data CLI = CLI
45 { hackageRepository :: FilePath
46 , preferredVersionsFile :: Maybe FilePath
47 , nixpkgsRepository :: FilePath
48 , configFile :: FilePath
49 , targetPlatform :: Platform
50 }
51 deriving (Show)
53main :: IO ()
54main = do
55 let cliOptions :: Parser CLI
56 cliOptions = CLI
57 <$> strOption (long "hackage" <> help "path to Hackage git repository" <> value "hackage" <> showDefaultWith id <> metavar "PATH")
58 <*> optional (strOption (long "preferred-versions" <> help "path to Hackage preferred-versions file" <> value "hackage/preferred-versions" <> showDefault <> metavar "PATH"))
59 <*> strOption (long "nixpkgs" <> help "path to Nixpkgs repository" <> value "nixpkgs" <> showDefaultWith id <> metavar "PATH")
60 <*> strOption (long "config" <> help "path to configuration file inside of Nixpkgs" <> value "pkgs/development/haskell-modules/configuration-hackage2nix.yaml" <> showDefaultWith id <> metavar "PATH")
61 <*> option (fmap fromString str) (long "platform" <> help "target platform to generate package set for" <> value "x86_64-linux" <> showDefaultWith display <> metavar "PLATFORM")
63 pinfo :: ParserInfo CLI
64 pinfo = info
65 ( helper
66 <*> infoOption ("hackage2nix " ++ display Main.version) (long "version" <> help "Show version number")
67 <*> cliOptions
68 )
69 ( fullDesc
70 <> header "hackage2nix converts a Hackage database into a hackage-packages.nix file."
71 )
72 CLI {..} <- execParser pinfo
74 config <- readConfiguration (nixpkgsRepository </> configFile)
75 nixpkgs <- readNixpkgPackageMap nixpkgsRepository Nothing
76 preferredVersions <- readPreferredVersions (fromMaybe (hackageRepository </> "preferred-versions") preferredVersionsFile)
77 let fixup = Map.delete "acme-everything" -- TODO: https://github.com/NixOS/cabal2nix/issues/164
78 . Map.delete "som" -- TODO: https://github.com/NixOS/cabal2nix/issues/164
79 . Map.delete "type" -- TODO: https://github.com/NixOS/cabal2nix/issues/163
80 . Map.delete "control-invariants" -- TODO: depends on "assert"
81 . over (at ("hermes")) ((fmap (set (contains "1.3.4.3") False))) -- TODO: https://github.com/haskell/hackage-server/issues/436
82 . over (at ("gogol-admin-reports")) ((fmap (set (contains "0.2.0") False))) -- TODO: https://github.com/commercialhaskell/all-cabal-hashes/issues/11
83 . over (at ("wai-middleware-prometheus")) ((fmap (set (contains "0.2.0") False))) -- TODO: https://github.com/commercialhaskell/all-cabal-hashes/issues/15
84 hackage <- fixup <$> readHackage hackageRepository
85 let
86 hackagePackagesFile :: FilePath
87 hackagePackagesFile = nixpkgsRepository </> "pkgs/development/haskell-modules/hackage-packages.nix"
89 corePackageSet :: PackageSet
90 corePackageSet = Map.fromList [ (name, v) | PackageIdentifier name v <- Set.toList (Config.corePackages config) ]
92 latestVersionSet :: PackageSet
93 latestVersionSet = Map.map Set.findMax (Map.filter (not . Set.null) (Map.mapWithKey (enforcePreferredVersions preferredVersions) hackage))
95 defaultPackageOverridesSet :: PackageSet
96 defaultPackageOverridesSet = Map.fromList [ (name, resolveConstraint c hackage) | c@(Dependency name _) <- defaultPackageOverrides config ]
98 generatedDefaultPackageSet :: PackageSet
99 generatedDefaultPackageSet = (defaultPackageOverridesSet `Map.union` latestVersionSet) `Map.difference` corePackageSet
101 latestCorePackageSet :: PackageSet
102 latestCorePackageSet = latestVersionSet `Map.intersection` corePackageSet
104 latestOverridePackageSet :: PackageSet
105 latestOverridePackageSet = latestVersionSet `Map.intersection` defaultPackageOverridesSet
107 extraPackageSet :: PackageMultiSet
108 extraPackageSet = Map.unionsWith Set.union
109 [ Map.singleton name (Set.singleton (resolveConstraint c hackage)) | c@(Dependency name _) <- extraPackages config ]
111 db :: PackageMultiSet
112 db = Map.unionsWith Set.union [ Map.map Set.singleton generatedDefaultPackageSet
113 , Map.map Set.singleton latestCorePackageSet
114 , Map.map Set.singleton latestOverridePackageSet
115 , extraPackageSet
116 ]
118 haskellResolver :: Dependency -> Bool
119 haskellResolver (Dependency name vrange)
120 | Just v <- Map.lookup name corePackageSet = v `withinRange` vrange
121 | Just v <- Map.lookup name generatedDefaultPackageSet = v `withinRange` vrange
122 | otherwise = False
124 nixpkgsResolver :: Identifier -> Maybe Binding
125 nixpkgsResolver = resolve (Map.map (Set.map (over path ("pkgs":))) nixpkgs)
127 globalPackageMaintainers :: Map PackageName (Set Identifier)
128 globalPackageMaintainers = Map.unionsWith Set.union [ Map.singleton p (Set.singleton m) | (m,ps) <- Map.toList (packageMaintainers config), p <- Set.toList ps ]
130 pkgs <- runParIO $ flip parMapM (Map.toAscList db) $ \(name, vs) -> do
131 defs <- forM (Set.toAscList vs) $ \v -> liftIO $ do
132 let pkgId :: PackageIdentifier
133 pkgId = PackageIdentifier name v
135 (descr, cabalSHA256) <- readPackage hackageRepository pkgId
136 meta <- readPackageMeta hackageRepository pkgId
138 let isInDefaultPackageSet :: Bool
139 isInDefaultPackageSet = maybe False (== v) (Map.lookup name generatedDefaultPackageSet)
141 tarballSHA256 :: SHA256Hash
142 tarballSHA256 = fromMaybe (error (display pkgId ++ ": meta data has no hash for the tarball"))
143 (view (hashes . at "SHA256") meta)
145 flagAssignment :: FlagAssignment -- We don't use the flags from Stackage Nightly here, because
146 flagAssignment = configureCabalFlags pkgId -- they are chosen specifically for GHC 7.10.2.
148 attr :: String
149 attr = if isInDefaultPackageSet then unPackageName name else mangle pkgId
151 drv :: Derivation
152 drv = fromGenericPackageDescription haskellResolver nixpkgsResolver targetPlatform (compilerInfo config) flagAssignment [] descr
153 & src .~ DerivationSource "url" ("mirror://hackage/" ++ display pkgId ++ ".tar.gz") "" tarballSHA256
154 & editedCabalFile .~ cabalSHA256
155 & metaSection.hydraPlatforms %~ (`Set.difference` Map.findWithDefault Set.empty name (dontDistributePackages config))
156 & metaSection.maintainers .~ Map.findWithDefault Set.empty name globalPackageMaintainers
157 & metaSection.hydraPlatforms %~ (if isInDefaultPackageSet then id else const Set.empty)
159 overrides :: Doc
160 overrides = fcat $ punctuate space [ disp b <> semi | b <- Set.toList ((view (dependencies . each) drv) `Set.union` view extraFunctionArgs drv), not (isFromHackage b) ]
161 return $ render $ nest 2 $
162 hang (doubleQuotes (text attr) <+> equals <+> text "callPackage") 2 (parens (pPrint drv)) <+> (braces overrides <> semi)
164 return (intercalate "\n\n" defs)
166 withFile hackagePackagesFile WriteMode $ \h -> do
167 hPutStrLn h "/* hackage-packages.nix is an auto-generated file -- DO NOT EDIT! */"
168 hPutStrLn h ""
169 hPutStrLn h "{ pkgs, stdenv, callPackage }:"
170 hPutStrLn h ""
171 hPutStrLn h "self: {"
172 hPutStrLn h ""
173 mapM_ (\pkg -> hPutStrLn h pkg >> hPutStrLn h "") pkgs
174 hPutStrLn h "}"
176isFromHackage :: Binding -> Bool
177isFromHackage b = case view (reference . path) b of
178 ["self",_] -> True
179 _ -> False
181readPreferredVersions :: FilePath -> IO [Constraint]
182readPreferredVersions p = mapMaybe parsePreferredVersionsLine . lines <$> readFile p
184parsePreferredVersionsLine :: String -> Maybe Constraint
185parsePreferredVersionsLine [] = Nothing
186parsePreferredVersionsLine ('-':'-':_) = Nothing
187parsePreferredVersionsLine l = simpleParse l `mplus` error ("invalid preferred-versions line: " ++ show l)
189enforcePreferredVersions :: [Constraint] -> PackageName -> Set Version -> Set Version
190enforcePreferredVersions cs pkg = Set.filter (\v -> PackageIdentifier pkg v `satisfiesConstraints` cs)
192resolveConstraint :: Constraint -> Hackage -> Version
193resolveConstraint c = fromMaybe (error msg) . resolveConstraint' c
194 where msg = "constraint " ++ display c ++ " cannot be resolved in Hackage"
196resolveConstraint' :: Constraint -> Hackage -> Maybe Version
197resolveConstraint' (Dependency name vrange) hackage
198 | Just vset' <- Map.lookup name hackage
199 , vset <- Set.filter (`withinRange` vrange) vset'
200 , not (Set.null vset) = Just (Set.findMax vset)
201 | otherwise = Nothing
203mangle :: PackageIdentifier -> String
204mangle (PackageIdentifier name v) = unPackageName name ++ '_' : [ if c == '.' then '_' else c | c <- display v ]