git.iko.soy/unity8
on 26850f2 help sign in
unity8/qml/Notifications/NotificationMenuItemFactory.qml
229 lines 7.7 kB history raw
1/*
2 * Copyright 2013-2016 Canonical Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU Lesser General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU Lesser General Public License for more details.
12 *
13 * You should have received a copy of the GNU Lesser General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import Ubuntu.Components 1.3
19import QMenuModel 0.1
20import "../Components"
22Loader {
23 id: menuFactory
25 property QtObject menuModel: null
26 property QtObject menuData: null
27 property int menuIndex : -1
28 property int maxHeight
29 readonly property bool fullscreen: menuData.type === "com.canonical.snapdecision.pinlock"
30 property url background: ""
32 signal accepted()
34 property var _map: {
35 "com.canonical.snapdecision.textfield": textfield,
36 "com.canonical.snapdecision.pinlock" : pinLock,
37 }
39 sourceComponent: {
40 if (menuData.type !== undefined) {
41 var component = _map[menuData.type];
42 if (component !== undefined) {
43 if (component === pinLock && shell.hasLockedApp) {
44 // In case we are in emergency mode, just skip this unlock.
45 // Happens with two locked SIMs but the user clicks
46 // Emergency Call on the first unlock dialog.
47 // TODO: if we ever allow showing the indicators in
48 // emergency mode, we'll need to differentiate between
49 // user-initiated ones which we *do* want to show and the
50 // dialogs that appear on boot, which we don't. But for
51 // now we can get away with skipping all such dialogs.
52 menuModel.activate(menuIndex, false);
53 return null;
54 }
55 return component;
56 }
57 }
58 }
60 function getExtendedProperty(object, propertyName, defaultValue) {
61 if (object && object.hasOwnProperty(propertyName)) {
62 return object[propertyName];
63 }
64 return defaultValue;
65 }
67 Component {
68 id: textfield
70 Column {
71 spacing: notification.margins
73 anchors {
74 left: parent.left
75 right: parent.right
76 margins: spacing
77 }
79 Component.onCompleted: {
80 menuModel.loadExtendedAttributes(menuIndex, {"x-echo-mode-password": "bool"});
81 checkBox.checked = menuData.ext.xEchoModePassword ? false : true
82 checkBoxRow.visible = menuData.ext.xEchoModePassword
83 }
85 Label {
86 text: menuData.label
87 color: theme.palette.normal.backgroundSecondaryText
88 }
90 TextField {
91 // TODO using Qt.ImhNoPredictiveText here until lp #1291575 is fixed for ubuntu-ui-toolkit
92 inputMethodHints: Qt.ImhNoAutoUppercase | Qt.ImhNoPredictiveText
93 anchors {
94 left: parent.left
95 right: parent.right
96 }
97 echoMode: checkBox.checked ? TextInput.Normal : TextInput.Password
98 height: units.gu(5)
99 Component.onCompleted: {
100 forceActiveFocus();
101 }
102 onTextChanged: {
103 menuModel.changeState(menuIndex, text);
104 }
105 onAccepted: {
106 menuFactory.accepted()
107 }
108 }
110 Row {
111 id: checkBoxRow
113 spacing: notification.margins
115 CheckBox {
116 id: checkBox
118 checked: false
119 activeFocusOnPress: false
120 }
122 Label {
123 anchors.verticalCenter: checkBox.verticalCenter
124 text: i18n.tr("Show password")
125 color: theme.palette.normal.backgroundSecondaryText
127 MouseArea {
128 anchors.fill: parent
129 onClicked: { checkBox.checked = !checkBox.checked }
130 }
131 }
132 }
133 }
134 }
136 Component {
137 id: pinLock
139 Lockscreen {
140 anchors {
141 left: parent.left
142 right: parent.right
143 }
144 height: menuFactory.maxHeight
145 infoText: notification.summary
146 errorText: errorAction.valid ? errorAction.state : ""
147 retryText: notification.body
148 background: menuFactory.background
150 onEntered: {
151 menuModel.changeState(menuIndex, passphrase);
152 clear(false);
153 }
155 onCancel: {
156 menuModel.activate(menuIndex, false);
157 }
159 onEmergencyCall: {
160 shell.startLockedApp("dialer-app");
161 menuModel.activate(menuIndex, false);
162 }
164 property var extendedData: menuData && menuData.ext || undefined
166 property var pinMinMaxAction : UnityMenuAction {
167 model: menuModel
168 index: menuIndex
169 name: getExtendedProperty(extendedData, "xCanonicalPinMinMax", "")
171 onStateChanged: {
172 var min = pinMinMaxAction.state[0];
173 var max = pinMinMaxAction.state[1];
175 if (min === 0) min = -1;
176 if (max === 0) max = -1;
178 minPinLength = min
179 maxPinLength = max
180 }
181 }
183 property var popupAction: UnityMenuAction {
184 model: menuModel
185 index: menuIndex
186 name: getExtendedProperty(extendedData, "xCanonicalPinPopup", "")
187 onStateChanged: {
188 if (state !== "")
189 showInfoPopup("", state);
190 }
191 }
192 onInfoPopupConfirmed: {
193 popupAction.activate();
194 }
196 Timer {
197 id: errorTimer
198 interval: 4000;
199 running: false;
200 repeat: false
201 onTriggered: {
202 errorAction.activate();
203 }
204 }
205 property var errorAction: UnityMenuAction {
206 model: menuModel
207 index: menuIndex
208 name: getExtendedProperty(extendedData, "xCanonicalPinError", "")
209 onStateChanged: {
210 errorText = state;
211 if (state !== "") {
212 clear(true);
213 errorTimer.running = true;
214 }
215 }
216 }
218 function loadAttributes() {
219 if (!menuModel || menuIndex == -1) return;
220 menuModel.loadExtendedAttributes(menuIndex, {'x-canonical-pin-min-max': 'string',
221 'x-canonical-pin-popup': 'string',
222 'x-canonical-pin-error': 'string'});
223 }
224 Component.onCompleted: {
225 loadAttributes();
226 }
227 }
228 }