git.iko.soy/unity8
on 31bb5ed help sign in
unity8/Launcher/LauncherDelegate.qml
214 lines 7.6 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import Ubuntu.Components 0.1
20Item {
21 id: root
23 property string iconName
24 property int count: -1
25 property int progress: -1
26 property bool highlighted: false
27 property bool itemFocused: false
28 property real maxAngle: 0
29 property bool inverted: false
31 readonly property int effectiveHeight: Math.cos(angle * Math.PI / 180) * itemHeight
32 readonly property real foldedHeight: Math.cos(maxAngle * Math.PI / 180) * itemHeight
34 property int itemWidth
35 property int itemHeight
36 // The angle used for rotating
37 property real angle: 0
38 // This is the offset that keeps the items inside the panel
39 property real offset: 0
40 property real itemOpacity: 1
41 property real brightness: 0
43 onIconNameChanged: shaderEffectSource.scheduleUpdate();
44 onCountChanged: shaderEffectSource.scheduleUpdate();
45 onProgressChanged: shaderEffectSource.scheduleUpdate();
46 onHighlightedChanged: shaderEffectSource.scheduleUpdate();
47 onItemFocusedChanged: shaderEffectSource.scheduleUpdate();
49 Item {
50 id: iconItem
51 width: parent.itemWidth + units.gu(1)
52 height: parent.itemHeight + units.gu(1)
53 anchors.centerIn: parent
55 UbuntuShape {
56 id: iconShape
57 anchors.fill: parent
58 anchors.margins: units.gu(1)
59 radius: "medium"
61 image: Image {
62 id: iconImage
63 sourceSize.width: iconShape.width
64 sourceSize.height: iconShape.height
65 source: root.iconName
66 }
67 }
69 BorderImage {
70 id: overlayHighlight
71 anchors.centerIn: iconItem
72 rotation: inverted ? 180 : 0
73 source: root.highlighted ? "graphics/selected.sci" : "graphics/non-selected.sci"
74 width: root.itemWidth + units.gu(0.5)
75 height: root.itemHeight + units.gu(0.5)
76 }
78 BorderImage {
79 objectName: "countEmblem"
80 anchors {
81 right: parent.right
82 top: parent.top
83 margins: units.dp(3)
84 }
85 width: Math.min(root.itemWidth, Math.max(units.gu(3), countLabel.implicitWidth + units.gu(2.5)))
86 height: units.gu(3)
87 source: "graphics/notification.sci"
88 visible: root.count > 0
90 Label {
91 id: countLabel
92 text: root.count
93 anchors.centerIn: parent
94 width: root.itemWidth - units.gu(1)
95 horizontalAlignment: Text.AlignHCenter
96 elide: Text.ElideRight
97 color: "white"
98 fontSize: "small"
99 font.bold: true
100 }
101 }
103 BorderImage {
104 id: progressOverlay
105 objectName: "progressOverlay"
106 anchors {
107 left: iconItem.left
108 right: iconItem.right
109 bottom: iconItem.bottom
110 leftMargin: units.gu(1)
111 rightMargin: units.gu(1)
112 bottomMargin: units.gu(1)
113 }
114 height: units.gu(1.5)
115 visible: root.progress > -1
116 source: "graphics/progressbar-trough.sci"
118 // For fill calculation we need to remove the 2 units of border defined in .sci file
119 property int adjustedWidth: width - units.gu(2)
121 Item {
122 anchors {
123 left: parent.left
124 top: parent.top
125 bottom: parent.bottom
126 }
127 width: Math.min(100, root.progress) / 100 * parent.adjustedWidth + units.gu(1)
128 clip: true
130 BorderImage {
131 anchors {
132 left: parent.left
133 top: parent.top
134 bottom: parent.bottom
135 }
136 width: progressOverlay.width
137 source: "graphics/progressbar-fill.sci"
138 }
139 }
140 }
141 Image {
142 objectName: "focusedHighlight"
143 anchors {
144 right: parent.right
145 verticalCenter: parent.verticalCenter
146 }
147 visible: root.itemFocused
148 source: "graphics/focused_app_arrow.png"
149 }
150 }
152 ShaderEffect {
153 id: transformEffect
154 anchors.centerIn: parent
155 anchors.verticalCenterOffset: root.offset
156 width: iconItem.width
157 height: iconItem.height
158 property real itemOpacity: root.itemOpacity
159 property real brightness: Math.max(-1, root.brightness)
160 property real angle: root.angle
161 rotation: root.inverted ? 180 : 0
163 property variant source: ShaderEffectSource {
164 id: shaderEffectSource
165 sourceItem: iconItem
166 hideSource: true
167 live: false
168 }
170 transform: [
171 // Rotating 3 times at top/bottom because that increases the perspective.
172 // This is a hack, but as QML does not support real 3D coordinates
173 // getting a higher perspective can only be done by a hack. This is the most
174 // readable/understandable one I could come up with.
175 Rotation {
176 axis { x: 1; y: 0; z: 0 }
177 origin { x: iconItem.width / 2; y: angle > 0 ? 0 : iconItem.height; z: 0 }
178 angle: root.angle * 0.7
179 },
180 Rotation {
181 axis { x: 1; y: 0; z: 0 }
182 origin { x: iconItem.width / 2; y: angle > 0 ? 0 : iconItem.height; z: 0 }
183 angle: root.angle * 0.7
184 },
185 Rotation {
186 axis { x: 1; y: 0; z: 0 }
187 origin { x: iconItem.width / 2; y: angle > 0 ? 0 : iconItem.height; z: 0 }
188 angle: root.angle * 0.7
189 },
190 // Because rotating it 3 times moves it more to the front/back, i.e. it gets
191 // bigger/smaller and we need a scale to compensate that again.
192 Scale {
193 xScale: 1 - (Math.abs(angle) / 500)
194 yScale: 1 - (Math.abs(angle) / 500)
195 origin { x: iconItem.width / 2; y: iconItem.height / 2}
196 }
197 ]
199 // Using a fragment shader instead of QML's opacity and BrightnessContrast
200 // to be able to do both in one step which gives quite some better performance
201 fragmentShader: "
202 varying highp vec2 qt_TexCoord0;
203 uniform sampler2D source;
204 uniform lowp float brightness;
205 uniform lowp float itemOpacity;
206 void main(void)
207 {
208 highp vec4 sourceColor = texture2D(source, qt_TexCoord0);
209 sourceColor.rgb = mix(sourceColor.rgb, vec3(step(0.0, brightness)), abs(brightness));
210 sourceColor *= itemOpacity;
211 gl_FragColor = sourceColor;
212 }"
213 }