git.iko.soy/unity8
on 4dd50c7 help sign in
unity8/qml/Shell.qml
699 lines 24 kB history raw
1/*
2 * Copyright (C) 2013-2015 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import QtQuick.Window 2.0
19import AccountsService 0.1
20import GSettings 1.0
21import Unity.Application 0.1
22import Ubuntu.Components 0.1
23import Ubuntu.Components.Popups 1.0
24import Ubuntu.Gestures 0.1
25import Ubuntu.Telephony 0.1 as Telephony
26import Unity.Connectivity 0.1
27import Unity.Launcher 0.1
28import GlobalShortcut 1.0 // has to be before Utils, because of WindowKeysFilter
29import Utils 0.1
30import Powerd 0.1
31import SessionBroadcast 0.1
32import "Greeter"
33import "Launcher"
34import "Panel"
35import "Components"
36import "Notifications"
37import "Stages"
38import "Tutorial"
39import "Wizard"
40import Unity.Notifications 1.0 as NotificationBackend
41import Unity.Session 0.1
42import Unity.DashCommunicator 0.1
43import Unity.Indicators 0.1 as Indicators
46Item {
47 id: shell
49 // to be set from outside
50 property int orientationAngle: 0
51 property int orientation
52 property Orientations orientations
53 property real nativeWidth
54 property real nativeHeight
55 property alias indicatorAreaShowProgress: panel.indicatorAreaShowProgress
56 property bool beingResized
57 property string usageScenario: "phone" // supported values: "phone", "tablet" or "desktop"
58 property string mode: "full-greeter"
59 function updateFocusedAppOrientation() {
60 applicationsDisplayLoader.item.updateFocusedAppOrientation();
61 }
62 function updateFocusedAppOrientationAnimated() {
63 applicationsDisplayLoader.item.updateFocusedAppOrientationAnimated();
64 }
66 // to be read from outside
67 readonly property int mainAppWindowOrientationAngle:
68 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainAppWindowOrientationAngle : 0
70 readonly property bool orientationChangesEnabled: panel.indicators.fullyClosed
71 && (applicationsDisplayLoader.item && applicationsDisplayLoader.item.orientationChangesEnabled)
72 && (!greeter || !greeter.animating)
74 readonly property bool showingGreeter: greeter && greeter.shown
76 property bool startingUp: true
77 Timer { id: finishStartUpTimer; interval: 500; onTriggered: startingUp = false }
79 property int supportedOrientations: {
80 if (startingUp) {
81 // Ensure we don't rotate during start up
82 return Qt.PrimaryOrientation;
83 } else if (greeter && greeter.shown) {
84 return Qt.PrimaryOrientation;
85 } else if (mainApp) {
86 return mainApp.supportedOrientations;
87 } else {
88 // we just don't care
89 return Qt.PortraitOrientation
90 | Qt.LandscapeOrientation
91 | Qt.InvertedPortraitOrientation
92 | Qt.InvertedLandscapeOrientation;
93 }
94 }
96 // For autopilot consumption
97 readonly property string focusedApplicationId: ApplicationManager.focusedApplicationId
99 // internal props from here onwards
100 readonly property var mainApp:
101 applicationsDisplayLoader.item ? applicationsDisplayLoader.item.mainApp : null
103 // Disable everything while greeter is waiting, so that the user can't swipe
104 // the greeter or launcher until we know whether the session is locked.
105 enabled: greeter && !greeter.waiting
107 property real edgeSize: units.gu(2)
108 property url defaultBackground: Qt.resolvedUrl(shell.width >= units.gu(60) ? "graphics/tablet_background.jpg" : "graphics/phone_background.jpg")
109 property url background: asImageTester.status == Image.Ready ? asImageTester.source
110 : gsImageTester.status == Image.Ready ? gsImageTester.source : defaultBackground
112 readonly property alias greeter: greeterLoader.item
114 function activateApplication(appId) {
115 if (ApplicationManager.findApplication(appId)) {
116 ApplicationManager.requestFocusApplication(appId);
117 } else {
118 var execFlags = shell.usageScenario === "phone" ? ApplicationManager.ForceMainStage
119 : ApplicationManager.NoFlag;
120 ApplicationManager.startApplication(appId, execFlags);
121 }
122 }
124 function startLockedApp(app) {
125 if (greeter.locked) {
126 greeter.lockedApp = app;
127 }
128 shell.activateApplication(app);
129 }
131 // This is a dummy image to detect if the custom AS set wallpaper loads successfully.
132 Image {
133 id: asImageTester
134 source: AccountsService.backgroundFile != undefined && AccountsService.backgroundFile.length > 0 ? AccountsService.backgroundFile : ""
135 height: 0
136 width: 0
137 sourceSize.height: 0
138 sourceSize.width: 0
139 }
141 GSettings {
142 id: backgroundSettings
143 schema.id: "org.gnome.desktop.background"
144 }
146 // This is a dummy image to detect if the custom GSettings set wallpaper loads successfully.
147 Image {
148 id: gsImageTester
149 source: backgroundSettings.pictureUri && backgroundSettings.pictureUri.length > 0 ? backgroundSettings.pictureUri : ""
150 height: 0
151 width: 0
152 sourceSize.height: 0
153 sourceSize.width: 0
154 }
156 Binding {
157 target: LauncherModel
158 property: "applicationManager"
159 value: ApplicationManager
160 }
162 Component.onCompleted: {
163 Theme.name = "Ubuntu.Components.Themes.SuruGradient"
164 if (ApplicationManager.count > 0) {
165 ApplicationManager.focusApplication(ApplicationManager.get(0).appId);
166 }
167 finishStartUpTimer.start();
168 }
170 LightDM{id: lightDM} // Provide backend access
171 VolumeControl {
172 id: volumeControl
173 indicators: panel.indicators
174 }
176 DashCommunicator {
177 id: dash
178 objectName: "dashCommunicator"
179 }
181 PhysicalKeysMapper {
182 id: physicalKeysMapper
183 objectName: "physicalKeysMapper"
185 onPowerKeyLongPressed: dialogs.showPowerDialog();
186 onVolumeDownTriggered: volumeControl.volumeDown();
187 onVolumeUpTriggered: volumeControl.volumeUp();
188 onScreenshotTriggered: screenGrabber.capture();
189 }
191 ScreenGrabber {
192 id: screenGrabber
193 z: dialogs.z + 10
194 }
196 GlobalShortcut {
197 // dummy shortcut to force creation of GlobalShortcutRegistry before WindowKeyFilter
198 }
200 WindowKeysFilter {
201 Keys.onPressed: physicalKeysMapper.onKeyPressed(event);
202 Keys.onReleased: physicalKeysMapper.onKeyReleased(event);
203 }
205 HomeKeyWatcher {
206 onActivated: { launcher.fadeOut(); shell.showHome(); }
207 }
209 Item {
210 id: stages
211 objectName: "stages"
212 width: parent.width
213 height: parent.height
215 Connections {
216 target: ApplicationManager
218 // This signal is also fired when we try to focus the current app
219 // again. We rely on this!
220 onFocusedApplicationIdChanged: {
221 var appId = ApplicationManager.focusedApplicationId;
223 if (tutorial.running && appId != "" && appId != "unity8-dash") {
224 // If this happens on first boot, we may be in edge
225 // tutorial or wizard while receiving a call. But a call
226 // is more important than wizard so just bail out of those.
227 tutorial.finish();
228 wizard.hide();
229 }
231 if (appId === "dialer-app" && callManager.hasCalls && greeter.locked) {
232 // If we are in the middle of a call, make dialer lockedApp and show it.
233 // This can happen if user backs out of dialer back to greeter, then
234 // launches dialer again.
235 greeter.lockedApp = appId;
236 }
237 greeter.notifyAppFocused(appId);
239 panel.indicators.hide();
240 }
242 onApplicationAdded: {
243 launcher.hide();
244 }
245 }
247 Loader {
248 id: applicationsDisplayLoader
249 objectName: "applicationsDisplayLoader"
250 anchors.fill: parent
252 // When we have a locked app, we only want to show that one app.
253 // FIXME: do this in a less traumatic way. We currently only allow
254 // locked apps in phone mode (see FIXME in Lockscreen component in
255 // this same file). When that changes, we need to do something
256 // nicer here. But this code is currently just to prevent a
257 // theoretical attack where user enters lockedApp mode, then makes
258 // the screen larger (maybe connects to monitor) and tries to enter
259 // tablet mode.
261 property string usageScenario: shell.usageScenario === "phone" || greeter.hasLockedApp
262 ? "phone"
263 : shell.usageScenario
264 source: {
265 if(shell.mode === "greeter") {
266 return "Stages/ShimStage.qml"
267 } else if (applicationsDisplayLoader.usageScenario === "phone") {
268 return "Stages/PhoneStage.qml";
269 } else if (applicationsDisplayLoader.usageScenario === "tablet") {
270 return "Stages/TabletStage.qml";
271 } else {
272 return "Stages/DesktopStage.qml";
273 }
274 }
276 property bool interactive: tutorial.spreadEnabled
277 && (!greeter || !greeter.shown)
278 && panel.indicators.fullyClosed
279 && launcher.progress == 0
280 && !notifications.useModal
282 onInteractiveChanged: { if (interactive) { focus = true; } }
284 Binding {
285 target: applicationsDisplayLoader.item
286 property: "objectName"
287 value: "stage"
288 }
289 Binding {
290 target: applicationsDisplayLoader.item
291 property: "dragAreaWidth"
292 value: shell.edgeSize
293 }
294 Binding {
295 target: applicationsDisplayLoader.item
296 property: "maximizedAppTopMargin"
297 // Not just using panel.panelHeight as that changes depending on the focused app.
298 value: panel.indicators.minimizedPanelHeight + units.dp(2) // dp(2) for orange line
299 }
300 Binding {
301 target: applicationsDisplayLoader.item
302 property: "interactive"
303 value: applicationsDisplayLoader.interactive
304 }
305 Binding {
306 target: applicationsDisplayLoader.item
307 property: "spreadEnabled"
308 value: tutorial.spreadEnabled && (!greeter || (!greeter.hasLockedApp && !greeter.shown))
309 }
310 Binding {
311 target: applicationsDisplayLoader.item
312 property: "inverseProgress"
313 value: greeter && greeter.locked ? 0 : launcher.progress
314 }
315 Binding {
316 target: applicationsDisplayLoader.item
317 property: "shellOrientationAngle"
318 value: shell.orientationAngle
319 }
320 Binding {
321 target: applicationsDisplayLoader.item
322 property: "shellOrientation"
323 value: shell.orientation
324 }
325 Binding {
326 target: applicationsDisplayLoader.item
327 property: "orientations"
328 value: shell.orientations
329 }
330 Binding {
331 target: applicationsDisplayLoader.item
332 property: "background"
333 value: shell.background
334 }
335 Binding {
336 target: applicationsDisplayLoader.item
337 property: "nativeWidth"
338 value: shell.nativeWidth
339 }
340 Binding {
341 target: applicationsDisplayLoader.item
342 property: "nativeHeight"
343 value: shell.nativeHeight
344 }
345 Binding {
346 target: applicationsDisplayLoader.item
347 property: "beingResized"
348 value: shell.beingResized
349 }
350 Binding {
351 target: applicationsDisplayLoader.item
352 property: "keepDashRunning"
353 value: launcher.shown || launcher.dashSwipe
354 }
355 Binding {
356 target: applicationsDisplayLoader.item
357 property: "suspended"
358 value: greeter.shown
359 }
360 Binding {
361 target: applicationsDisplayLoader.item
362 property: "altTabPressed"
363 value: physicalKeysMapper.altTabPressed
364 }
365 }
367 Tutorial {
368 id: tutorial
369 objectName: "tutorial"
370 anchors.fill: parent
372 // EdgeDragAreas don't work with mice. So to avoid trapping the user,
373 // we skip the tutorial on the Desktop to avoid using them. The
374 // Desktop doesn't use the same spread design anyway. The tutorial is
375 // all a bit of a placeholder on non-phone form factors right now.
376 // When the design team gives us more guidance, we can do something
377 // more clever here.
378 active: usageScenario != "desktop" && AccountsService.demoEdges
380 paused: lightDM.greeter.active
381 launcher: launcher
382 panel: panel
383 edgeSize: shell.edgeSize
385 onFinished: {
386 AccountsService.demoEdges = false;
387 active = false; // for immediate response / if AS is having problems
388 }
389 }
390 }
392 InputMethod {
393 id: inputMethod
394 objectName: "inputMethod"
395 anchors { fill: parent; topMargin: panel.panelHeight }
396 z: notifications.useModal || panel.indicators.shown || wizard.active ? overlay.z + 1 : overlay.z - 1
397 }
399 Connections {
400 target: SessionManager
401 onSessionStopping: {
402 if (!session.parentSession && !session.application) {
403 // nothing is using it. delete it right away
404 session.release();
405 }
406 }
407 }
409 Loader {
410 id: greeterLoader
411 anchors.fill: parent
412 anchors.topMargin: panel.panelHeight
413 sourceComponent: shell.mode != "shell" ? integratedGreeter :
414 Qt.createComponent(Qt.resolvedUrl("Greeter/ShimGreeter.qml"));
415 onLoaded: {
416 item.objectName = "greeter"
417 }
418 }
420 Component {
421 id: integratedGreeter
422 Greeter {
424 hides: [launcher, panel.indicators]
425 tabletMode: shell.usageScenario != "phone"
426 launcherOffset: launcher.progress
427 forcedUnlock: tutorial.running
428 background: shell.background
430 // avoid overlapping with Launcher's edge drag area
431 // FIXME: Fix TouchRegistry & friends and remove this workaround
432 // Issue involves launcher's DDA getting disabled on a long
433 // left-edge drag
434 dragHandleLeftMargin: launcher.available ? launcher.dragAreaWidth + 1 : 0
436 onSessionStarted: {
437 launcher.hide();
438 }
440 onTease: {
441 if (!tutorial.running) {
442 launcher.tease();
443 }
444 }
446 onEmergencyCall: startLockedApp("dialer-app")
447 }
448 }
450 Timer {
451 // See powerConnection for why this is useful
452 id: showGreeterDelayed
453 interval: 1
454 onTriggered: {
455 greeter.forceShow();
456 }
457 }
459 Connections {
460 id: callConnection
461 target: callManager
463 onHasCallsChanged: {
464 if (greeter.locked && callManager.hasCalls && greeter.lockedApp !== "dialer-app") {
465 // We just received an incoming call while locked. The
466 // indicator will have already launched dialer-app for us, but
467 // there is a race between "hasCalls" changing and the dialer
468 // starting up. So in case we lose that race, we'll start/
469 // focus the dialer ourselves here too. Even if the indicator
470 // didn't launch the dialer for some reason (or maybe a call
471 // started via some other means), if an active call is
472 // happening, we want to be in the dialer.
473 startLockedApp("dialer-app")
474 }
475 }
476 }
478 Connections {
479 id: powerConnection
480 target: Powerd
482 onStatusChanged: {
483 if (Powerd.status === Powerd.Off && reason !== Powerd.Proximity &&
484 !callManager.hasCalls && !tutorial.running) {
485 // We don't want to simply call greeter.showNow() here, because
486 // that will take too long. Qt will delay button event
487 // handling until the greeter is done loading and may think the
488 // user held down the power button the whole time, leading to a
489 // power dialog being shown. Instead, delay showing the
490 // greeter until we've finished handling the event. We could
491 // make the greeter load asynchronously instead, but that
492 // introduces a whole host of timing issues, especially with
493 // its animations. So this is simpler.
494 showGreeterDelayed.start();
495 }
496 }
497 }
499 function showHome() {
500 if (tutorial.running) {
501 return
502 }
504 greeter.notifyAboutToFocusApp("unity8-dash");
506 var animate = !lightDM.greeter.active && !stages.shown
507 dash.setCurrentScope(0, animate, false)
508 ApplicationManager.requestFocusApplication("unity8-dash")
509 }
511 function showDash() {
512 if (greeter.notifyShowingDashFromDrag()) {
513 launcher.fadeOut();
514 }
516 if (!greeter.locked && ApplicationManager.focusedApplicationId != "unity8-dash") {
517 ApplicationManager.requestFocusApplication("unity8-dash")
518 launcher.fadeOut();
519 }
520 }
522 Item {
523 id: overlay
524 z: 10
526 anchors.fill: parent
528 Panel {
529 id: panel
530 objectName: "panel"
531 anchors.fill: parent //because this draws indicator menus
532 indicators {
533 hides: [launcher]
534 available: tutorial.panelEnabled
535 && ((!greeter || !greeter.locked) || AccountsService.enableIndicatorsWhileLocked)
536 && (!greeter || !greeter.hasLockedApp)
537 contentEnabled: tutorial.panelContentEnabled
538 width: parent.width > units.gu(60) ? units.gu(40) : parent.width
540 minimizedPanelHeight: units.gu(3)
541 expandedPanelHeight: units.gu(7)
543 indicatorsModel: Indicators.IndicatorsModel {
544 // tablet and phone both use the same profile
545 profile: shell.usageScenario === "desktop" ? "desktop" : "phone"
546 Component.onCompleted: load();
547 }
548 }
550 callHint {
551 greeterShown: greeter.shown
552 }
554 property bool topmostApplicationIsFullscreen:
555 ApplicationManager.focusedApplicationId &&
556 ApplicationManager.findApplication(ApplicationManager.focusedApplicationId).fullscreen
558 fullscreenMode: (topmostApplicationIsFullscreen && !lightDM.greeter.active && launcher.progress == 0)
559 || greeter.hasLockedApp
560 }
562 Launcher {
563 id: launcher
564 objectName: "launcher"
566 readonly property bool dashSwipe: progress > 0
568 anchors.top: parent.top
569 anchors.topMargin: inverted ? 0 : panel.panelHeight
570 anchors.bottom: parent.bottom
571 width: parent.width
572 dragAreaWidth: shell.edgeSize
573 available: tutorial.launcherEnabled
574 && (!greeter.locked || AccountsService.enableLauncherWhileLocked)
575 && !greeter.hasLockedApp
576 inverted: shell.usageScenario !== "desktop"
577 shadeBackground: !tutorial.running
579 onShowDashHome: showHome()
580 onDash: showDash()
581 onDashSwipeChanged: {
582 if (dashSwipe) {
583 dash.setCurrentScope(0, false, true)
584 }
585 }
586 onLauncherApplicationSelected: {
587 if (!tutorial.running) {
588 greeter.notifyAboutToFocusApp(appId);
589 shell.activateApplication(appId)
590 }
591 }
592 onShownChanged: {
593 if (shown) {
594 panel.indicators.hide()
595 }
596 }
597 }
599 Wizard {
600 id: wizard
601 objectName: "wizard"
602 anchors.fill: parent
603 background: shell.background
605 function unlockWhenDoneWithWizard() {
606 if (!active) {
607 Connectivity.unlockAllModems();
608 }
609 }
611 Component.onCompleted: unlockWhenDoneWithWizard()
612 onActiveChanged: unlockWhenDoneWithWizard()
613 }
615 Rectangle {
616 id: modalNotificationBackground
618 visible: notifications.useModal
619 color: "#000000"
620 anchors.fill: parent
621 opacity: 0.9
623 MouseArea {
624 anchors.fill: parent
625 }
626 }
628 Notifications {
629 id: notifications
631 model: NotificationBackend.Model
632 margin: units.gu(1)
634 y: topmostIsFullscreen ? 0 : panel.panelHeight
635 height: parent.height - (topmostIsFullscreen ? 0 : panel.panelHeight)
637 states: [
638 State {
639 name: "narrow"
640 when: overlay.width <= units.gu(60)
641 AnchorChanges {
642 target: notifications
643 anchors.left: parent.left
644 anchors.right: parent.right
645 }
646 },
647 State {
648 name: "wide"
649 when: overlay.width > units.gu(60)
650 AnchorChanges {
651 target: notifications
652 anchors.left: undefined
653 anchors.right: parent.right
654 }
655 PropertyChanges { target: notifications; width: units.gu(38) }
656 }
657 ]
658 }
659 }
661 Dialogs {
662 id: dialogs
663 objectName: "dialogs"
664 anchors.fill: parent
665 z: overlay.z + 10
666 usageScenario: shell.usageScenario
667 onPowerOffClicked: {
668 shutdownFadeOutRectangle.enabled = true;
669 shutdownFadeOutRectangle.visible = true;
670 shutdownFadeOut.start();
671 }
672 }
674 Connections {
675 target: SessionBroadcast
676 onShowHome: showHome()
677 }
679 Rectangle {
680 id: shutdownFadeOutRectangle
681 z: screenGrabber.z + 10
682 enabled: false
683 visible: false
684 color: "black"
685 anchors.fill: parent
686 opacity: 0.0
687 NumberAnimation on opacity {
688 id: shutdownFadeOut
689 from: 0.0
690 to: 1.0
691 onStopped: {
692 if (shutdownFadeOutRectangle.enabled && shutdownFadeOutRectangle.visible) {
693 DBusUnitySessionService.shutdown();
694 }
695 }
696 }
697 }