git.iko.soy/unity8
on 5bc8421 help sign in
unity8/Components/FilterGrid.qml
107 lines 4.0 kB history raw
1/*
2 * Copyright (C) 2013 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.0
18import Ubuntu.Components 0.1
19import Utils 0.1
20import "../Components"
22/*
23 A ResponsiveGridView that can optionally have the number of rows being displayed
24 reduced to collapsedRowCount, in which case a button saying "View all (123)"
25 will be shown at the bottom. If clicked, FilterGrid will them expand vertically
26 to display all rows.
27 */
28Item {
29 id: root
31 /* If true, the number of elements displayed will be limited by collapsedRowCount.
32 If false, all elements will be displayed, effectively looking the same as a regular
33 ResponsiveGridView. */
34 property bool filter: true
36 /* Whether, when collapsed, a button should be displayed enabling the user to expand
37 the grid to its full size. */
38 readonly property bool expandable: model.count > collapsedRowCount * iconTileGrid.columns
40 property var model: null
42 /* Maximum number of rows to be show when filter=true. */
43 property int collapsedRowCount: 2
44 readonly property int collapsedHeight: {
45 return iconTileGrid.contentHeightForRows(Math.min(collapsedRowCount, Math.ceil(model.count / columns)))
46 }
47 readonly property int uncollapsedHeight: {
48 return iconTileGrid.contentHeightForRows(Math.ceil(model.count / columns))
49 }
51 property alias minimumHorizontalSpacing: iconTileGrid.minimumHorizontalSpacing
52 property alias maximumNumberOfColumns: iconTileGrid.maximumNumberOfColumns
53 property alias columns: iconTileGrid.columns
54 property alias delegateWidth: iconTileGrid.delegateWidth
55 property alias delegateHeight: iconTileGrid.delegateHeight
56 property alias verticalSpacing: iconTileGrid.verticalSpacing
57 property alias delegate: iconTileGrid.delegate
58 property alias cellWidth: iconTileGrid.cellWidth
59 property alias cellHeight: iconTileGrid.cellHeight
60 readonly property alias flicking: iconTileGrid.flicking
61 readonly property alias moving: iconTileGrid.moving
62 readonly property alias pressDelay: iconTileGrid.pressDelay
64 height: !filterAnimation.running ? childrenRect.height : height
65 clip: filterAnimation.running
67 NumberAnimation {
68 property bool filterEndValue
69 id: filterAnimation
70 target: root
71 property: "height"
72 to: filterEndValue ? root.collapsedHeight : root.uncollapsedHeight
73 // Duration and easing here match the ListViewWithPageHeader::m_contentYAnimation
74 // otherwise since both animations can run at the same time you'll get
75 // some visual weirdness.
76 duration: 200
77 easing.type: Easing.InOutQuad
78 onStopped: {
79 root.filter = filterEndValue;
80 }
81 }
83 function startFilterAnimation(filter) {
84 filterAnimation.filterEndValue = filter
85 filterAnimation.start();
86 }
88 ResponsiveGridView {
89 id: iconTileGrid
91 anchors { left: parent.left; right: parent.right }
92 height: totalContentHeight
93 interactive: false
95 minimumHorizontalSpacing: units.gu(0.5)
96 maximumNumberOfColumns: 6
97 delegateWidth: units.gu(11)
98 delegateHeight: units.gu(9.5)
99 verticalSpacing: units.gu(2)
101 model: LimitProxyModel {
102 model: root.model
103 limit: (filter && !filterAnimation.running) ? collapsedRowCount * iconTileGrid.columns : -1
104 }
106 }