git.iko.soy/unity8
on 7013f90 help sign in
unity8/tests/qmltests/Tutorial/tst_Tutorial.qml
829 lines 32 kB history raw
1/*
2 * Copyright (C) 2013-2016 Canonical, Ltd.
3 *
4 * This program is free software; you can redistribute it and/or modify
5 * it under the terms of the GNU General Public License as published by
6 * the Free Software Foundation; version 3.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 */
17import QtQuick 2.4
18import QtTest 1.0
19import AccountsService 0.1
20import LightDMController 0.1
21import LightDM.FullLightDM 0.1 as LightDM
22import Ubuntu.Components 1.3
23import Ubuntu.Components.ListItems 1.3
24import Ubuntu.Telephony 0.1 as Telephony
25import Unity.Application 0.1
26import Unity.Notifications 1.0
27import Unity.Test 0.1 as UT
28import Utils 0.1
30import "../../../qml"
31import "../../../qml/Components"
33Rectangle {
34 id: root
35 color: UbuntuColors.lightGrey
36 width: units.gu(100) + buttons.width
37 height: units.gu(71)
39 QtObject {
40 id: applicationArguments
42 function hasGeometry() {
43 return false;
44 }
46 function width() {
47 return 0;
48 }
50 function height() {
51 return 0;
52 }
53 }
55 Telephony.CallEntry {
56 id: phoneCall
57 phoneNumber: "+447812221111"
58 }
60 Component {
61 id: mockNotification
62 QtObject {}
63 }
65 ListModel {
66 id: mockNotificationsModel
68 function getRaw(id) {
69 return mockNotification.createObject(mockNotificationsModel)
70 }
71 }
73 function addNotification() {
74 var n = {
75 type: Notification.Confirmation,
76 hints: {},
77 summary: "",
78 body: "",
79 icon: "",
80 secondaryIcon: "",
81 actions: []
82 };
84 mockNotificationsModel.append(n);
85 }
87 Component.onCompleted: {
88 // must set the mock mode before loading the Shell
89 LightDMController.userMode = "single-pin";
90 shellLoader.active = true;
91 }
93 Item {
94 id: shellContainer
95 anchors.left: root.left
96 anchors.right: buttons.left
97 anchors.top: root.top
98 anchors.bottom: root.bottom
100 Loader {
101 id: shellLoader
103 active: false
104 anchors.horizontalCenter: parent.horizontalCenter
105 anchors.top: parent.top
106 anchors.bottom: parent.bottom
108 property int shellOrientation: Qt.PortraitOrientation
109 property int nativeOrientation: Qt.PortraitOrientation
110 property int primaryOrientation: Qt.PortraitOrientation
112 state: modeSelector.model[modeSelector.selectedIndex]
113 states: [
114 State {
115 name: "phone"
116 PropertyChanges {
117 target: shellLoader
118 width: units.gu(40)
119 }
120 },
121 State {
122 name: "tablet"
123 PropertyChanges {
124 target: shellLoader
125 width: units.gu(100)
126 shellOrientation: Qt.LandscapeOrientation
127 nativeOrientation: Qt.LandscapeOrientation
128 primaryOrientation: Qt.LandscapeOrientation
129 }
130 },
131 State {
132 name: "desktop"
133 PropertyChanges {
134 target: shellLoader
135 width: units.gu(100)
136 }
137 }
138 ]
140 property bool itemDestroyed: false
141 sourceComponent: Component {
142 Shell {
143 usageScenario: shellLoader.state
144 nativeWidth: width
145 nativeHeight: height
146 property string indicatorProfile: "phone"
147 orientation: shellLoader.shellOrientation
148 orientations: Orientations {
149 native_: shellLoader.nativeOrientation
150 primary: shellLoader.primaryOrientation
151 }
152 hasTouchscreen: true
154 Component.onDestruction: {
155 shellLoader.itemDestroyed = true;
156 }
157 }
158 }
159 }
160 }
162 Rectangle {
163 id: buttons
164 color: UbuntuColors.darkGrey
165 width: units.gu(30)
166 anchors.top: root.top
167 anchors.bottom: root.bottom
168 anchors.right: root.right
170 Column {
171 anchors { left: parent.left; right: parent.right; top: parent.top; margins: units.gu(1) }
172 spacing: units.gu(1)
173 Row {
174 anchors { left: parent.left; right: parent.right }
175 Button {
176 text: "Hide Greeter"
177 onClicked: {
178 if (shellLoader.status !== Loader.Ready)
179 return;
181 var greeter = testCase.findChild(shellLoader.item, "greeter");
182 if (greeter.shown) {
183 greeter.hide();
184 }
185 }
186 }
187 }
189 Row {
190 anchors { left: parent.left; right: parent.right }
191 Button {
192 text: "Restart Tutorial"
193 onClicked: {
194 if (shellLoader.status !== Loader.Ready)
195 return;
197 AccountsService.demoEdges = false;
198 AccountsService.demoEdgesCompleted = [];
199 AccountsService.demoEdges = true;
200 }
201 }
202 }
204 Row {
205 anchors { left: parent.left; right: parent.right }
206 CheckBox {
207 onCheckedChanged: {
208 if (checked) {
209 callManager.foregroundCall = phoneCall;
210 } else {
211 callManager.foregroundCall = null;
212 }
213 }
214 }
215 Label {
216 text: "Active Call"
217 anchors.verticalCenter: parent.verticalCenter
218 }
219 }
221 Row {
222 anchors { left: parent.left; right: parent.right }
223 CheckBox {
224 activeFocusOnPress: false
225 onCheckedChanged: {
226 var surface = topLevelSurfaceList.inputMethodSurface;
227 if (checked) {
228 surface.requestState(Mir.RestoredState);
229 } else {
230 surface.requestState(Mir.MinimizedState);
231 }
232 }
233 }
234 Label {
235 text: "Input Method"
236 anchors.verticalCenter: parent.verticalCenter
237 }
238 }
240 ItemSelector {
241 id: modeSelector
242 anchors { left: parent.left; right: parent.right }
243 activeFocusOnPress: false
244 text: "Mode"
245 model: ["phone", "tablet", "desktop"]
246 }
247 }
248 }
250 UT.StageTestCase {
251 id: testCase
252 name: "Tutorial"
253 when: windowShown
255 property Item shell: shellLoader.status === Loader.Ready ? shellLoader.item : null
256 property real halfWidth: shell ? shell.width / 2 : 0
257 property real halfHeight: shell ? shell.height / 2 : 0
259 onShellChanged: {
260 if (shell) {
261 topLevelSurfaceList = testCase.findInvisibleChild(shell, "topLevelSurfaceList");
262 } else {
263 topLevelSurfaceList = null;
264 }
265 }
267 function init() {
268 prepareShell();
270 var tutorialTop = findChild(shell, "tutorialTop");
271 var tutorialTopTimer = findInvisibleChild(tutorialTop, "tutorialTopTimer");
272 tutorialTopTimer.interval = 0;
273 tryCompare(tutorialTop, "opacity", 1);
274 }
276 function cleanup() {
277 resetLoader("phone");
278 }
280 function resetLoader(state) {
281 shellLoader.itemDestroyed = false;
283 shellLoader.active = false;
284 shellLoader.state = state;
286 tryCompare(shellLoader, "status", Loader.Null);
287 tryCompare(shellLoader, "item", null);
288 // Loader.status might be Loader.Null and Loader.item might be null but the Loader
289 // item might still be alive. So if we set Loader.active back to true
290 // again right now we will get the very same Shell instance back. So no reload
291 // actually took place. Likely because Loader waits until the next event loop
292 // iteration to do its work. So to ensure the reload, we will wait until the
293 // Shell instance gets destroyed.
294 tryCompare(shellLoader, "itemDestroyed", true);
296 // kill all (fake) running apps
297 killApps();
299 // reload our test subject to get it in a fresh state once again
300 shellLoader.active = true;
302 mockNotificationsModel.clear();
303 tryCompare(shellLoader, "status", Loader.Ready);
304 removeTimeConstraintsFromSwipeAreas(shellLoader.item);
305 }
307 function prepareShell() {
308 tryCompare(shell, "waitingOnGreeter", false); // reset by greeter when ready
310 WindowStateStorage.clear();
311 callManager.foregroundCall = null;
312 AccountsService.demoEdges = false;
313 AccountsService.demoEdgesCompleted = [];
314 AccountsService.demoEdges = true;
316 LightDM.Greeter.hideGreeter();
318 stage = findChild(shell, "stage"); // from StageTestCase
319 }
321 function loadShell(state) {
322 resetLoader(state);
323 prepareShell();
324 }
326 function ensureInputMethodSurface() {
327 var surfaceManager = findInvisibleChild(shell, "surfaceManager");
328 verify(surfaceManager);
329 surfaceManager.createInputMethodSurface();
331 tryCompareFunction(function() { return topLevelSurfaceList.inputMethodSurface !== null }, true);
332 }
334 function openTutorialLeft() {
335 var tutorialTopLoader = findChild(shell, "tutorialTopLoader");
336 var tutorialLeftLoader = findChild(shell, "tutorialLeftLoader");
337 var tutorialLeft = findInvisibleChild(tutorialLeftLoader, "tutorialLeft");
338 var tutorialLeftTimer = findInvisibleChild(tutorialLeft, "tutorialLeftTimer");
340 tutorialLeftTimer.interval = 1;
341 AccountsService.demoEdgesCompleted = ["top"];
343 tryCompare(tutorialTopLoader, "active", false);
344 tryCompare(tutorialLeft, "shown", true);
345 tryCompare(tutorialLeft, "opacity", 1);
346 }
348 function openTutorialLeftLong() {
349 var tutorialLeftLong = findChild(shell, "tutorialLeftLong");
350 var tutorialLeftLongTimer = findChild(tutorialLeftLong, "tutorialLeftLongTimer");
352 AccountsService.demoEdgesCompleted = ["top", "left"];
354 tutorialLeftLongTimer.interval = 1;
355 tryCompare(tutorialLeftLong, "shown", true);
356 tryCompare(tutorialLeftLong, "opacity", 1);
357 }
359 function openTutorialRight() {
360 var tutorialLeftLongLoader = findChild(shell, "tutorialLeftLongLoader");
361 var tutorialRight = findChild(shell, "tutorialRight");
362 var tutorialRightTimer = findChild(tutorialRight, "tutorialRightTimer");
364 AccountsService.demoEdgesCompleted = ["top", "left", "left-drawer"];
365 ApplicationManager.startApplication("facebook-webapp");
367 tryCompare(tutorialLeftLongLoader, "active", false);
368 tutorialRightTimer.interval = 1;
369 tryCompare(tutorialRight, "shown", true);
370 tryCompare(tutorialRight, "opacity", 1);
371 }
373 function longLeftSwipe() {
374 // Perform a long enough swipe to cause the Drawer to appear
375 var launcher = findChild(shell, "launcher");
376 var startX = launcher.dragAreaWidth/2;
377 var startY = launcher.height/2;
378 touchFlick(launcher,
379 startX, startY,
380 startX+units.gu(35), startY);
381 }
383 function test_tutorialLeftEdges() {
384 var tutorial = findChild(shell, "tutorial");
385 var tutorialLeft = findChild(tutorial, "tutorialLeft");
386 var launcher = findChild(shell, "launcher");
387 var stage = findChild(shell, "stage");
388 var panel = findChild(shell, "panel");
390 openTutorialLeft();
392 verify(tutorial.running);
393 verify(tutorial.launcherEnabled);
394 verify(!tutorial.spreadEnabled);
395 verify(!tutorial.panelEnabled);
396 verify(tutorialLeft.shown);
397 verify(launcher.available);
398 verify(!stage.spreadEnabled);
399 verify(!panel.indicators.available);
400 }
402 function test_tutorialLeftFinish() {
403 var tutorial = findChild(shell, "tutorial");
404 var tutorialLeftLoader = findChild(tutorial, "tutorialLeftLoader");
405 var launcher = findChild(shell, "launcher");
407 openTutorialLeft();
409 touchFlick(shell, 0, halfHeight, halfWidth, halfHeight);
411 tryCompare(tutorialLeftLoader, "shown", false);
412 tryCompare(AccountsService, "demoEdgesCompleted", ["top", "left"]);
413 tryCompare(launcher, "state", "visible");
414 }
416 function test_tutorialLeftShortDrag() {
417 // Here we want to test just barely pulling the launcher out and
418 // letting go (i.e. not triggering the "progress" property of
419 // Launcher).
420 var tutorialLeft = findChild(shell, "tutorialLeft");
421 var tutorialLeftLoader = findChild(shell, "tutorialLeftLoader");
422 var launcher = findChild(shell, "launcher");
424 openTutorialLeft();
426 // Confirm fade during drag
427 touchFlick(shell, 0, halfHeight, launcher.panelWidth * 0.4, halfHeight, true, false);
428 // compare opacity with a bound rather than hard 0.6 because progress doesn't
429 // always match the drag perfectly (takes a moment for drag to kick in)
430 tryCompareFunction(function() {
431 return tutorialLeft.opacity >= 0.6 && tutorialLeft.opacity < 0.8;
432 }, true);
433 touchFlick(shell, 0, halfHeight, launcher.panelWidth * 0.4, halfHeight, false, true);
436 // Make sure we don't do anything if we don't pull the launcher
437 // out much.
438 touchFlick(shell, 0, halfHeight, launcher.panelWidth * 0.4, halfHeight);
439 tryCompare(launcher, "state", ""); // should remain hidden
440 tryCompare(tutorialLeftLoader, "shown", true); // and we should still be on left
443 // Now drag out but not past launcher itself
444 touchFlick(shell, 0, halfHeight, launcher.panelWidth * 0.9, halfHeight);
446 tryCompare(tutorialLeftLoader, "shown", false);
447 tryCompare(AccountsService, "demoEdgesCompleted", ["top", "left"]);
448 tryCompare(launcher, "state", "visible");
449 }
451 function test_tutorialLeftLongFinish() {
452 var tutorialLeftLongLoader = findChild(shell, "tutorialLeftLongLoader");
453 openTutorialLeftLong();
455 tryCompare(tutorialLeftLongLoader, "shown", true);
457 touchFlick(shell, 0, halfHeight, shell.width, halfHeight);
459 tryCompare(tutorialLeftLongLoader, "shown", false);
460 tryCompare(AccountsService, "demoEdgesCompleted", ["top", "left", "left-drawer"]);
461 }
463 function test_tutorialLeftAutoSkipped() {
464 // Test that we skip the tutorial if user uses left edge themselves
465 var launcher = findChild(shell, "launcher");
467 AccountsService.demoEdgesCompleted = ["top"]
468 var tutorialLeft = findChild(shell, "tutorialLeft");
469 launcher.show();
470 tryCompare(tutorialLeft, "visible", false);
471 compare(AccountsService.demoEdgesCompleted, ["top"]);
473 touchFlick(shell, 0, halfHeight, halfWidth, halfHeight);
474 tryCompare(AccountsService, "demoEdgesCompleted", ["top", "left"]);
475 }
477 function test_tutorialLongLeftSwipeDisabled() {
478 // Test that a long left swipe is disabled until we get to or pass
479 // the long left tutorial.
480 var tutorial = findChild(shell, "tutorial");
481 var launcher = findChild(shell, "launcher");
482 var drawer = findChild(launcher, "drawer");
484 // Waiting for top tutorial, the Launcher should be unavailable
485 longLeftSwipe();
486 tryCompare(launcher, "state", "");
488 // Swipe the left edge far enough to open the Drawer. Only the
489 // Launcher should appear.
490 openTutorialLeft();
491 longLeftSwipe();
492 tryCompare(launcher, "state", "visible");
494 // Once the Drawer tutorial is open, the Drawer should appear on
495 // a long swipe.
496 openTutorialLeftLong();
497 longLeftSwipe();
498 tryCompare(launcher, "state", "drawer");
499 launcher.hide();
501 // That should continue after the Tutorial is no more
502 AccountsService.demoEdges = false;
503 tryCompare(tutorial, "running", false);
504 longLeftSwipe();
505 tryCompare(launcher, "state", "drawer");
506 }
508 function test_tutorialTopEdges() {
509 var tutorial = findChild(shell, "tutorial");
510 var tutorialTop = findChild(tutorial, "tutorialTop");
511 var launcher = findChild(shell, "launcher");
512 var stage = findChild(shell, "stage");
513 var panel = findChild(shell, "panel");
515 tryCompare(tutorial, "running", true);
516 verify(!tutorial.launcherEnabled);
517 verify(!tutorial.spreadEnabled);
518 verify(tutorial.panelEnabled);
519 verify(tutorialTop.shown);
520 verify(!launcher.available);
521 verify(!stage.spreadEnabled);
522 verify(panel.indicators.available);
523 }
525 function test_tutorialTopFinish() {
526 var tutorial = findChild(shell, "tutorial");
527 var tutorialTopLoader = findChild(tutorial, "tutorialTopLoader");
528 var panel = findChild(shell, "panel");
530 touchFlick(shell, halfWidth, 0, halfWidth, shell.height);
532 tryCompare(tutorialTopLoader, "shown", false);
533 tryCompare(AccountsService, "demoEdgesCompleted", ["top"]);
534 tryCompare(panel.indicators, "fullyOpened", true);
535 }
537 function test_tutorialTopShortDrag() {
538 var tutorial = findChild(shell, "tutorial");
539 var tutorialTop = findChild(tutorial, "tutorialTop");
540 var panel = findChild(shell, "panel");
542 touchFlick(shell, halfWidth, 0, halfWidth, shell.height * 0.4, true, false);
543 // compare opacity with a bound rather than hard 0.6 because progress doesn't
544 // always match the drag perfectly (takes a moment for drag to kick in)
545 tryCompareFunction(function() {
546 return tutorialTop.opacity >= 0.5 && tutorialTop.opacity < 0.7;
547 }, true);
548 touchFlick(shell, halfWidth, 0, halfWidth, shell.height * 0.4, false, true);
550 compare(tutorialTop.shown, true);
551 }
553 function test_tutorialRightEdges() {
554 var tutorial = findChild(shell, "tutorial");
555 var tutorialRight = findChild(tutorial, "tutorialRight");
556 var launcher = findChild(shell, "launcher");
557 var stage = findChild(shell, "stage");
558 var panel = findChild(shell, "panel");
560 openTutorialRight();
562 tryCompare(tutorial, "running", true);
563 verify(!tutorial.launcherEnabled);
564 verify(tutorial.spreadEnabled);
565 verify(!tutorial.panelEnabled);
566 verify(tutorialRight.shown);
567 verify(!launcher.available);
568 verify(stage.spreadEnabled);
569 verify(!panel.indicators.available);
570 }
572 function test_tutorialRightFinish() {
573 openTutorialRight();
574 touchFlick(shell, shell.width, halfHeight, 0, halfHeight);
576 tryCompare(AccountsService, "demoEdgesCompleted", ["top", "left", "left-drawer", "right"]);
577 tryCompare(AccountsService, "demoEdges", false);
578 }
580 function test_tutorialRightShortDrag() {
581 var tutorial = findChild(shell, "tutorial");
582 var tutorialRight = findChild(tutorial, "tutorialRight");
583 var stage = findChild(shell, "stage");
585 openTutorialRight();
586 touchFlick(shell, shell.width, halfHeight, shell.width * 0.8, halfHeight, true, false);
587 // compare opacity with a bound rather than hard 0.6 because progress doesn't
588 // always match the drag perfectly (takes a moment for drag to kick in)
589 verify(function() {
590 return tutorialRight.opacity >= 0.6 && tutorialRight.opacity < 0.8;
591 });
592 touchFlick(shell, shell.width, halfHeight, shell.width * 0.8, halfHeight, false, true);
594 compare(tutorialRight.shown, true);
595 }
597 function test_tutorialRightDelay() {
598 // Test that if we exit the top tutorial, we don't immediately
599 // jump into right tutorial.
600 var tutorialRightLoader = findChild(shell, "tutorialRightLoader");
601 var tutorialRightTimer = findInvisibleChild(tutorialRightLoader, "tutorialRightTimer");
603 ApplicationManager.startApplication("gallery-app");
604 tryCompare(ApplicationManager, "count", 1);
606 AccountsService.demoEdgesCompleted = ["top", "left", "left-drawer"];
607 verify(tutorialRightTimer.running);
608 verify(!tutorialRightLoader.shown);
609 tutorialRightTimer.interval = 1;
610 tryCompare(tutorialRightLoader, "shown", true);
611 }
613 function test_tutorialRightAutoSkipped() {
614 // Test that we skip the tutorial if user uses right edge themselves
616 var tutorialLeftLongLoader = findChild(shell, "tutorialLeftLongLoader");
617 var tutorialRight = findChild(shell, "tutorialRight");
618 var tutorialRightTimer = findChild(tutorialRight, "tutorialRightTimer");
620 tutorialRightTimer.interval = 9999999;
622 ApplicationManager.startApplication("facebook-webapp");
623 tryCompare(ApplicationManager, "count", 1);
625 AccountsService.demoEdgesCompleted = ["top", "left", "left-drawer"];
626 tryCompare(tutorialLeftLongLoader, "skipped", true);
627 verify(tutorialRightTimer.running);
628 tryCompare(tutorialRight, "isReady", true);
630 // If the app isn't fully started, it may interrupt our attempt to swipe
631 wait(1000);
633 touchFlick(shell, shell.width, halfHeight, 0, halfHeight);
634 tryCompare(AccountsService, "demoEdgesCompleted", ["top", "left", "left-drawer", "right"]);
635 }
637 function test_activeCallInterruptsTutorial() {
638 var tutorialLeft = findChild(shell, "tutorialLeft");
639 openTutorialLeft();
641 callManager.foregroundCall = phoneCall;
642 verify(!tutorialLeft.shown);
643 verify(tutorialLeft.paused);
644 tryCompare(tutorialLeft, "visible", false);
646 callManager.foregroundCall = null;
647 tryCompare(tutorialLeft, "shown", true);
648 verify(!tutorialLeft.paused);
649 }
651 function test_greeterInterruptsTutorial() {
652 var tutorialTop = findChild(shell, "tutorialTop");
653 verify(tutorialTop.shown);
654 verify(!tutorialTop.paused);
656 LightDM.Greeter.showGreeter();
657 verify(!tutorialTop.shown);
658 verify(tutorialTop.paused);
659 tryCompare(tutorialTop, "visible", false);
661 LightDM.Greeter.hideGreeter();
662 tryCompare(tutorialTop, "shown", true);
663 verify(!tutorialTop.paused);
664 }
666 function test_interruptionChecksReadyStateWhenDone() {
667 // If we're done with an interruption (like active call), make sure
668 // that we don't blindly resume the tutorial -- our trigger
669 // conditions still need to be met. For example, there need to be
670 // enough apps open for the right edge tutorial.
672 openTutorialRight();
674 var tutorialRight = findChild(shell, "tutorialRight");
675 verify(tutorialRight.isReady);
676 verify(tutorialRight.shown);
677 verify(!tutorialRight.paused);
679 callManager.foregroundCall = phoneCall;
680 killApps();
681 callManager.foregroundCall = null;
683 verify(!tutorialRight.isReady);
684 verify(!tutorialRight.shown);
685 verify(!tutorialRight.paused);
686 compare(AccountsService.demoEdgesCompleted, ["top", "left", "left-drawer"]);
687 }
689 function test_desktopOnlyShowsTutorialRight() {
690 loadShell("desktop");
692 var tutorialLeftLoader = findChild(shell, "tutorialLeftLoader");
693 var tutorialTopLoader = findChild(shell, "tutorialTopLoader");
694 var tutorialLeftLongLoader = findChild(shell, "tutorialLeftLongLoader");
695 var tutorialRightLoader = findChild(shell, "tutorialRightLoader");
696 verify(!tutorialLeftLoader.active);
697 verify(!tutorialTopLoader.active);
698 verify(!tutorialLeftLongLoader.active);
699 verify(tutorialRightLoader.active);
700 compare(AccountsService.demoEdgesCompleted, []);
702 var tutorialRightTimer = findInvisibleChild(tutorialRightLoader, "tutorialRightTimer");
703 tutorialRightTimer.interval = 1;
705 ApplicationManager.startApplication("facebook-webapp");
706 tryCompare(tutorialRightLoader.item, "isReady", true);
708 tryCompare(tutorialRightLoader, "shown", true);
709 }
711 function test_desktopTutorialRightFinish() {
712 loadShell("desktop");
714 var tutorialRightLoader = findChild(shell, "tutorialRightLoader");
715 var tutorialRightTimer = findInvisibleChild(tutorialRightLoader, "tutorialRightTimer");
716 tutorialRightTimer.interval = 1;
717 ApplicationManager.startApplication("facebook-webapp");
718 tryCompare(tutorialRightLoader, "shown", true);
720 var cursor = findChild(shell, "cursor");
721 mouseMove(shell, shell.width, shell.height / 2);
722 cursor.pushedRightBoundary(units.gu(8), 0);
723 tryCompare(tutorialRightLoader, "shown", false);
725 tryCompare(AccountsService, "demoEdges", false);
726 }
728 function test_oskDoesNotHideTutorial() {
729 var tutorialTopLoader = findChild(shell, "tutorialTopLoader");
730 verify(tutorialTopLoader.shown);
732 ensureInputMethodSurface();
733 var surface = topLevelSurfaceList.inputMethodSurface;
734 surface.requestState(Mir.RestoredState);
736 var inputMethod = findInvisibleChild(shell, "inputMethod");
737 tryCompare(inputMethod, "visible", true);
739 verify(tutorialTopLoader.shown);
740 }
742 function test_oskDelaysTutorial() {
743 var tutorial = findChild(shell, "tutorial");
744 verify(!tutorial.delayed);
746 ensureInputMethodSurface();
747 topLevelSurfaceList.inputMethodSurface.requestState(Mir.RestoredState);
749 tryCompare(tutorial, "delayed", true);
750 }
752 function test_notificationDelaysTutorial() {
753 var tutorial = findChild(shell, "tutorial");
754 verify(!tutorial.delayed);
756 var notifications = findChild(shell, "notificationList");
757 notifications.model = mockNotificationsModel;
758 addNotification(); // placeholder
759 addNotification();
761 tryCompare(tutorial, "delayed", true);
762 }
764 function test_dialogDelaysTutorial() {
765 var tutorial = findChild(shell, "tutorial");
766 verify(!tutorial.delayed);
768 var dialogs = findChild(shell, "dialogs");
769 dialogs.showPowerDialog();
771 verify(tutorial.delayed);
772 }
774 function test_delayedTutorial() {
775 var launcher = findChild(shell, "launcher");
776 var tutorial = findChild(shell, "tutorial");
777 var tutorialLeft = findChild(tutorial, "tutorialLeft");
778 var tutorialLeftTimer = findChild(tutorial, "tutorialLeftTimer");
779 // Since we'll be using the Launcher and Drawer, the left tutorial
780 // will be skipped entirely and we'll show the left long one.
781 var tutorialLeftLong = findChild(tutorial, "tutorialLeftLong");
782 var tutorialLeftLongTimer = findChild(tutorialLeftLong, "tutorialLeftLongTimer");
784 // Don't need these to start before we're ready
785 tutorialLeftTimer.interval = 999999;
786 tutorialLeftLongTimer.interval = 1;
788 // Get left tutorial ready to be skipped
789 AccountsService.demoEdgesCompleted = ["top"];
790 tryCompare(tutorialLeft, "isReady", true);
791 tryCompare(tutorialLeftTimer, "running", true);
793 // Confirm that we become unready when delayed, but timer still goes
794 tutorial.delayed = true;
795 tryCompare(tutorialLeft, "isReady", false);
796 tryCompare(tutorialLeftTimer, "running", true);
798 // Confirm that we don't open the tutorial when delayed
799 tutorialLeftTimer.interval = 1;
800 wait(500);
801 verify(!tutorialLeft.shown);
803 // Confirm the Launcher and Drawer can be opened when delayed
804 tryCompare(tutorial, "launcherEnabled", true);
805 tryCompare(tutorial, "launcherLongSwipeEnabled", true);
806 longLeftSwipe();
807 tryCompare(launcher, "state", "drawer");
808 launcher.hide();
810 // Confirm we go back to normal when undelayed
811 tutorial.delayed = false;
812 tryCompare(tutorialLeftLong, "shown", true);
813 }
815 function test_accountsServiceSettings() {
816 var tutorial = findChild(shell, "tutorial");
817 var tutorialTopLoader = findChild(tutorial, "tutorialTopLoader");
818 verify(tutorialTopLoader.shown);
820 AccountsService.demoEdges = false;
821 verify(findChild(tutorial, "tutorialTopLoader", 1) == null);
823 AccountsService.demoEdges = true;
824 tutorialTopLoader = findChild(shell, "tutorialTopLoader");
825 var tutorialTopTimer = findChild(tutorialTopLoader, "tutorialTopTimer");
826 verify(tutorialTopTimer.running);
827 }
828 }